app.psgi

   1 #!/usr/bin/perl -w
   2 use v5.14;
   3
   4 use Apache2::Authen::Passphrase qw/pwcheck/;
   5 use Apache2::AuthzCaps qw/hascaps/;
   6 use Gruntmaster::Data;
   7 use Plack::App::Gruntmaster;
   8 use Plack::Builder;
   9 use Plack::Request;
  10 use Digest::SHA qw/sha256/;
  11 use Log::Log4perl;
  12
  13 use constant ACCESSLOG_FORMAT => '%{X-Forwarded-For}i|%h %u "%r" %>s %b "%{Referer}i" "%{User-agent}i"';
  14 use constant CONTENT_SECURITY_POLICY => q,default-src 'none'; script-src 'self' www.google-analytics.com; style-src 'self'; img-src 'self'; connect-src 'self',;
  15
  16 $Apache2::AuthzCaps::rootdir = $Apache2::Authen::Passphrase::rootdir;
  17 my $word = qr,(\w+),a;
  18 my $db = Gruntmaster::Data->connect('dbi:Pg:');
  19
  20 sub debug {
  21         local $Log::Log4perl::caller_depth = $Log::Log4perl::caller_depth + 1;
  22         $_[0]->{'psgix.logger'}->({qw/level debug message/ => $_[1]})
  23 }
  24
  25 sub some_auth_required {
  26         my $r = Plack::Request->new($_[0]);
  27         return 1 if $_[0]->{'gruntmaster.reqadmin'} || $r->path eq '/action/passwd' || $r->path =~ m,/pb/$word/submit$,;
  28         return 1 if $r->path =~ m,^/ct/$word/pb/$word, && time < $db->contest($1)->stop;
  29         ''
  30 }
  31
  32 sub admin_required {
  33         local $_ = $_[0];
  34         return $db->problem($1)->owner if m,^/pb/$word, && $db->problem($1)->private;
  35         return $db->job    ($1)->owner if m,^/log/(?:job|src)/$word, && $db->job($1)->private;
  36         return $db->contest($1)->owner if m,^/ct/$word/(?:pb|log), && time < $db->contest($1)->start;
  37         return $db->job    ($2)->owner if m,^/ct/$word/log/(?:job|src)/$word, && time < $db->contest($1)->stop;
  38         ''
  39 }
  40
  41 sub require_admin {
  42         my $app = $_[0];
  43         sub {
  44                 local *__ANON__ = "require_admin_middleware";
  45                 my $env = $_[0];
  46                 my $r = Plack::Request->new($env);
  47                 $env->{'gruntmaster.reqadmin'} = admin_required $r->path;
  48                 $app->($env)
  49         }
  50 }
  51
  52 my %authen_cache;
  53
  54 sub authenticate {
  55         my ($user, $pass, $env) = @_;
  56         my $cache_key = sha256 "$user:$pass";
  57         my $time = $authen_cache{$cache_key} // 0;
  58         if ($time >= time - 300) {
  59                 return 1;
  60         } else {
  61                 delete $authen_cache{$cache_key};
  62         }
  63
  64         return unless eval {
  65                 pwcheck $user, $pass;
  66                 1
  67         };
  68         $authen_cache{$cache_key} = time;
  69
  70         return if $env->{'gruntmaster.reqadmin'} && $env->{'gruntmaster.reqadmin'} ne $user && !hascaps $user, 'gmadm';
  71         1
  72 }
  73
  74 Log::Log4perl->init('log.conf');
  75 my $access_logger = Log::Log4perl->get_logger('access');
  76
  77 builder {
  78         enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }};
  79         enable 'AccessLog', format => ACCESSLOG_FORMAT, logger => sub { $access_logger->info(@_) };
  80         enable 'ContentLength';
  81         enable Header => set => ['Content-Security-Policy', CONTENT_SECURITY_POLICY];
  82         enable_if { $_[0]->{PATH_INFO} =~ qr,^/static/,} Header => set => ['Cache-Control', 'public, max-age=604800'];
  83         enable 'Static', path => qr,^/static/,;
  84         enable 'Log4perl', category => 'plack';
  85         enable \&require_admin;
  86         enable_if \&some_auth_required, 'Auth::Basic', authenticator => \&authenticate, realm => 'Gruntmaster 6000';
  87         enable sub { my $app = $_[0]; sub { $_[0]->{'gruntmaster.dbic'} = $db; $app->($_[0]) } };
  88         Plack::App::Gruntmaster->to_app
  89 }