configure.ac

   1 m4_define([VERSION_H],m4_esyscmd([cat version.h]))
   2 changequote({{,}})dnl
   3 m4_define({{XX_VERSION}},m4_bregexp(VERSION_H,{{^const.*"\(.+\)";}},{{\1}}))
   4 changequote([,])dnl
   5
   6 AC_INIT([fdkaac], [XX_VERSION], [honeycomb77@gmail.com])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_MACRO_DIR([m4])
   9
  10 AM_INIT_AUTOMAKE
  11
  12 AC_PROG_CC
  13 AM_PROG_CC_C_O
  14
  15 AC_CHECK_HEADERS([sys/time.h])
  16 AC_CHECK_HEADERS([libcharset.h langinfo.h endian.h byteswap.h])
  17 AC_CHECK_HEADERS([fdk-aac/aacenc_lib.h], ,
  18                  AC_MSG_ERROR([libfdk-aac is required]))
  19
  20 AC_C_INLINE
  21 AC_C_BIGENDIAN
  22 AC_TYPE_INT16_T
  23 AC_TYPE_INT32_T
  24 AC_TYPE_INT64_T
  25 AC_TYPE_INT8_T
  26 AC_TYPE_SIZE_T
  27 AC_TYPE_UINT16_T
  28 AC_TYPE_UINT32_T
  29 AC_TYPE_UINT64_T
  30 AC_TYPE_UINT8_T
  31 AC_CHECK_TYPES([ptrdiff_t])
  32
  33 AC_SYS_LARGEFILE
  34 AC_CHECK_TYPES([struct __timeb64],[],[],[[#include <sys/timeb.h>]])
  35 AC_FUNC_FSEEKO
  36 AC_CHECK_FUNCS([sigaction gettimeofday nl_langinfo _vscprintf fseeko64])
  37 AC_CHECK_FUNC(getopt_long)
  38 AM_CONDITIONAL([FDK_NO_GETOPT_LONG],[test "$ac_cv_func_getopt_long" != "yes"])
  39 AC_SEARCH_LIBS([aacEncOpen],[fdk-aac],[],[],[])
  40
  41 CHARSET_LIB=
  42 AC_CHECK_LIB([iconv], [locale_charset],
  43        [CHARSET_LIB=-liconv],
  44        [AC_CHECK_LIB([charset], [locale_charset], [CHARSET_LIB=-lcharset])])
  45 AC_SUBST([CHARSET_LIB])
  46
  47 AC_CANONICAL_HOST
  48
  49 X_PLATFORM=posix
  50 case ${host} in
  51 *-*-mingw*)
  52     X_PLATFORM=win32
  53     ;;
  54 *)
  55     AM_ICONV
  56 esac
  57 AM_CONDITIONAL([FDK_PLATFORM_POSIX],[test "$X_PLATFORM" = "posix"])
  58 AM_CONDITIONAL([FDK_PLATFORM_WIN32],[test "$X_PLATFORM" = "win32"])
  59
  60 AC_CONFIG_FILES([Makefile])
  61
  62 AC_OUTPUT