| 1 | package App::MusicExpo; |
| 2 | use v5.14; |
| 3 | use strict; |
| 4 | use warnings; |
| 5 | |
| 6 | our $VERSION = '0.003003'; |
| 7 | |
| 8 | use Audio::FLAC::Header qw//; |
| 9 | use HTML::Template::Compiled qw//; |
| 10 | use Memoize qw/memoize/; |
| 11 | use MP3::Tag qw//; |
| 12 | use Ogg::Vorbis::Header::PurePerl; |
| 13 | use MP4::Info qw/get_mp4tag get_mp4info/; |
| 14 | |
| 15 | use DB_File qw//; |
| 16 | use File::Basename qw/fileparse/; |
| 17 | use Fcntl qw/O_RDWR O_CREAT/; |
| 18 | use Getopt::Long; |
| 19 | use JSON::MaybeXS; |
| 20 | use Storable qw/thaw freeze/; |
| 21 | |
| 22 | ################################################## |
| 23 | |
| 24 | my $default_template; |
| 25 | |
| 26 | our $prefix='/music/'; |
| 27 | our $cache=''; |
| 28 | our $template=''; |
| 29 | |
| 30 | GetOptions ( |
| 31 | "template:s" => \$template, |
| 32 | "prefix:s" => \$prefix, |
| 33 | "cache:s" => \$cache, |
| 34 | ); |
| 35 | |
| 36 | |
| 37 | sub fix{ |
| 38 | my $copy = $_[0]; |
| 39 | utf8::decode($copy); |
| 40 | $copy |
| 41 | } |
| 42 | |
| 43 | sub flacinfo{ |
| 44 | my $file=$_[0]; |
| 45 | my $flac=Audio::FLAC::Header->new($file); |
| 46 | $file = scalar fileparse $file; |
| 47 | |
| 48 | freeze +{ |
| 49 | format => 'FLAC', |
| 50 | title => fix ($flac->tags('TITLE') // '?'), |
| 51 | artist => fix ($flac->tags('ARTIST') // '?'), |
| 52 | year => fix ($flac->tags('DATE') // '?'), |
| 53 | album => fix ($flac->tags('ALBUM') // '?'), |
| 54 | tracknumber => fix ($flac->tags('TRACKNUMBER') // '?'), |
| 55 | tracktotal => fix ($flac->tags('TRACKTOTAL') // '?'), |
| 56 | genre => fix ($flac->tags('GENRE') // '?'), |
| 57 | file => $file, |
| 58 | } |
| 59 | } |
| 60 | |
| 61 | sub mp3info{ |
| 62 | my $file=$_[0]; |
| 63 | my $mp3=MP3::Tag->new($file); |
| 64 | $file = scalar fileparse $file; |
| 65 | |
| 66 | freeze +{ |
| 67 | format => 'MP3', |
| 68 | title => fix ($mp3->title || '?'), |
| 69 | artist => fix ($mp3->artist || '?'), |
| 70 | year => fix ($mp3->year || '?'), |
| 71 | album => fix ($mp3->album || '?'), |
| 72 | tracknumber => fix ($mp3->track1 || '?'), |
| 73 | tracktotal => fix ($mp3->track2 || '?'), |
| 74 | genre => fix ($mp3->genre) || '?', |
| 75 | file => $file, |
| 76 | } |
| 77 | } |
| 78 | |
| 79 | sub vorbisinfo{ |
| 80 | my $file=$_[0]; |
| 81 | my $ogg=Ogg::Vorbis::Header::PurePerl->new($file); |
| 82 | $file = scalar fileparse $file; |
| 83 | |
| 84 | freeze +{ |
| 85 | format => 'Vorbis', |
| 86 | title => fix($ogg->comment('TITLE') || '?'), |
| 87 | artist => fix ($ogg->comment('artist') || '?'), |
| 88 | year => fix ($ogg->comment('DATE') || '?'), |
| 89 | album => fix ($ogg->comment('ALBUM') || '?'), |
| 90 | tracknumber => fix ($ogg->comment('TRACKNUMBER') || '?'), |
| 91 | tracktotal => fix ($ogg->comment('TRACKTOTAL') || '?'), |
| 92 | genre => fix ($ogg->comment('GENRE')) || '?', |
| 93 | file => $file, |
| 94 | } |
| 95 | } |
| 96 | |
| 97 | sub mp4_format ($){ |
| 98 | my $encoding = $_[0]; |
| 99 | return 'AAC' if $encoding eq 'mp4a'; |
| 100 | return 'ALAC' if $encoding eq 'alac'; |
| 101 | "MP4-$encoding" |
| 102 | } |
| 103 | |
| 104 | sub mp4info{ |
| 105 | my $file=$_[0]; |
| 106 | my %tag = %{get_mp4tag $file}; |
| 107 | my %info = %{get_mp4info $file}; |
| 108 | $file = scalar fileparse $file; |
| 109 | |
| 110 | freeze +{ |
| 111 | format => mp4_format $info{ENCODING}, |
| 112 | title => $tag{TITLE} || '?', |
| 113 | artist => $tag{ARTIST} || '?', |
| 114 | year => $tag{YEAR} || '?', |
| 115 | album => $tag{ALBUM} || '?', |
| 116 | tracknumber => $tag{TRACKNUM} || '?', |
| 117 | tracktotal => ($tag{TRKN} ? $tag{TRKN}->[1] : undef) || '?', |
| 118 | genre => $tag{GENRE} || '?', |
| 119 | file => $file, |
| 120 | }; |
| 121 | } |
| 122 | |
| 123 | sub normalizer{ |
| 124 | "$_[0]|".(stat $_[0])[9] |
| 125 | } |
| 126 | |
| 127 | sub run { |
| 128 | if ($cache) { |
| 129 | tie my %cache, 'DB_File', $cache, O_RDWR|O_CREAT, 0644; |
| 130 | memoize $_, NORMALIZER => \&normalizer, LIST_CACHE => 'MERGE', SCALAR_CACHE => [HASH => \%cache] for qw/flacinfo mp3info vorbisinfo mp4info/; |
| 131 | } |
| 132 | |
| 133 | my %files; |
| 134 | for my $file (@ARGV) { |
| 135 | my $info; |
| 136 | $info = thaw flacinfo $file if $file =~ /\.flac$/i; |
| 137 | $info = thaw mp3info $file if $file =~ /\.mp3$/i; |
| 138 | $info = thaw vorbisinfo $file if $file =~ /\.og(?:g|a)$/i; |
| 139 | $info = thaw mp4info $file if $file =~ /\.mp4|\.aac|\.m4a$/i; |
| 140 | next unless defined $info; |
| 141 | my $basename = fileparse $file, '.flac', '.mp3', '.ogg', '.oga', '.mp4', '.aac', '.m4a'; |
| 142 | $files{$basename} //= []; |
| 143 | push $files{$basename}, $info; |
| 144 | } |
| 145 | |
| 146 | my $ht=HTML::Template::Compiled->new( |
| 147 | default_escape => 'HTML', |
| 148 | global_vars => 2, |
| 149 | $template eq '' ? (scalarref => \$default_template) : (filename => $template), |
| 150 | ); |
| 151 | |
| 152 | my @files; |
| 153 | for (values %files) { |
| 154 | my @versions = @$_; |
| 155 | my %entry = (%{$versions[0]}, formats => []); |
| 156 | push $entry{formats}, {format => $_->{format}, file => $_->{file}} for @versions; |
| 157 | push @files, \%entry |
| 158 | } |
| 159 | |
| 160 | my $json = JSON::MaybeXS->new(canonical => 1)->encode({files => \@files, prefix => $prefix}); |
| 161 | $json =~ s/</</g; |
| 162 | $json =~ s/>/>/g; |
| 163 | $ht->param(files=>[sort { $a->{title} cmp $b->{title} } @files], prefix => $prefix, json => $json); |
| 164 | print $ht->output; |
| 165 | } |
| 166 | |
| 167 | $default_template = <<'HTML'; |
| 168 | <!DOCTYPE html> |
| 169 | <title>Music</title> |
| 170 | <meta charset="utf-8"> |
| 171 | <link rel="stylesheet" href="/music.css"> |
| 172 | |
| 173 | <table border> |
| 174 | <thead> |
| 175 | <tr><th>Title<th>Artist<th>Album<th>Genre<th>Track<th>Year<th>Type |
| 176 | <tbody><tmpl_loop files> |
| 177 | <tr><td><tmpl_var title><td><tmpl_var artist><td><tmpl_var album><td><tmpl_var genre><td><tmpl_var tracknumber>/<tmpl_var tracktotal><td><tmpl_var year><td><tmpl_loop formats><a href="<tmpl_var ...prefix><tmpl_var ESCAPE=URL file>"><tmpl_var format></a> </tmpl_loop></tmpl_loop> |
| 178 | </table> |
| 179 | |
| 180 | <pre id="json" style="display: none"><tmpl_var ESCAPE=0 json></pre> |
| 181 | HTML |
| 182 | |
| 183 | 1; |
| 184 | |
| 185 | __END__ |
| 186 | |
| 187 | =encoding utf-8 |
| 188 | |
| 189 | =head1 NAME |
| 190 | |
| 191 | App::MusicExpo - script which generates a HTML table of music tags |
| 192 | |
| 193 | =head1 SYNOPSIS |
| 194 | |
| 195 | use App::MusicExpo; |
| 196 | App::MusicExpo->run; |
| 197 | |
| 198 | =head1 DESCRIPTION |
| 199 | |
| 200 | App::MusicExpo creates a HTML table from a list of songs. |
| 201 | |
| 202 | The default template looks like: |
| 203 | |
| 204 | | Title | Artist | Album | Genre | Track | Year | Type | |
| 205 | |---------+---------+-----------------+---------+-------+------+------| |
| 206 | | Cellule | Silence | L'autre endroit | Electro | 01/09 | 2005 | FLAC | |
| 207 | |
| 208 | where the type is a download link. If you have multiple files with the same |
| 209 | basename (such as C<cellule.flac> and C<cellule.ogg>), they will be treated |
| 210 | as two versions of the same file, so a row will be created with two download |
| 211 | links, one for each format. |
| 212 | |
| 213 | =head1 OPTIONS |
| 214 | |
| 215 | =over |
| 216 | |
| 217 | =item B<--template> I<template> |
| 218 | |
| 219 | Path to the HTML::Template::Compiled template used for generating the music table. If '' (empty), uses the default format. Is empty by default. |
| 220 | |
| 221 | =item B<--prefix> I<prefix> |
| 222 | |
| 223 | Prefix for download links. Defaults to '/music/'. |
| 224 | |
| 225 | =item B<--cache> I<filename> |
| 226 | |
| 227 | Path to the cache file. Created if it does not exist. If '' (empty), disables caching. Is empty by default. |
| 228 | |
| 229 | =back |
| 230 | |
| 231 | =head1 AUTHOR |
| 232 | |
| 233 | Marius Gavrilescu, E<lt>marius@ieval.roE<gt> |
| 234 | |
| 235 | =head1 COPYRIGHT AND LICENSE |
| 236 | |
| 237 | Copyright (C) 2013-2014 by Marius Gavrilescu |
| 238 | |
| 239 | This library is free software; you can redistribute it and/or modify |
| 240 | it under the same terms as Perl itself, either Perl version 5.14.2 or, |
| 241 | at your option, any later version of Perl 5 you may have available. |