Convert snapshot to CSV for faster tests and a smaller dist

[convert-color-husl.git] / t / Convert-Color-HUSL.t

#!/usr/bin/perl
use 5.014000;
use warnings;

use Convert::Color::RGB8;
use JSON::PP qw/decode_json/;
use Test::More tests => 5 * 4096;

use constant EPSILON => $ENV{RELEASE_TESTING} ? 1e-11 : 2e-4;
my @spaces = qw/XYZ LUV LCh HUSL HUSLp/;

sub isf {
	my ($x, $y, $name) = @_;
	ok !grep({ abs ($_ - shift @$y) > EPSILON } @$x), $name;
}

if ($ENV{RELEASE_TESTING}) {
	require JSON::MaybeXS;
	open my $fh, '<', 't/snapshot-rev4.json';
	my $snapshot = join '', <$fh>;

	my %tests = %{JSON::MaybeXS::decode_json $snapshot};

	for my $color (sort keys %tests) {
		my $col = Convert::Color::RGB8->new(substr $color, 1);
		isf $col->convert_to(lc), $tests{$color}{lc()}, "convert $color to $_" for @spaces;
	}
} else {
	open my $fh, '<', 't/snapshot-rev4.csv';
	<$fh>;

	while (<$fh>) {
		my ($color, @good) = split ',';
		my $col = Convert::Color::RGB8->new($color);
		isf $col->convert_to(lc), \@good, "convert $color to $_" for @spaces
	}
}