Several cleanups

[yule.git] / lisp_processor.v

`include "gc.v"
`include "eval.v"
`include "reader.v"
`include "uart.v"
`include "writer.v"

`define GCOP_NOP      4'd0
`define GCOP_CDR      4'd1
`define GCOP_CAR      4'd2
`define GCOP_CDRQ     4'd3
`define GCOP_CARQ     4'd4
`define GCOP_CARR     4'd5
`define GCOP_CDRRX    4'd6
`define GCOP_CARRX    4'd7
`define GCOP_CDRQX    4'd8
`define GCOP_CONS     4'd9
`define GCOP_XCONS    4'd10
`define GCOP_RPLACDR  4'd11
`define GCOP_LDQ      4'd12
`define GCOP_RDQ      4'd13
`define GCOP_RDQA     4'd14
`define GCOP_RDQCDRRX 4'd15

`define STATE_READ  3'b100
`define STATE_RUN   3'b010
`define STATE_WRITE 3'b001

`ifdef SIM
 `define START_STATE `STATE_RUN
`else
 `define START_STATE `STATE_READ
`endif

`ifdef SIM
 `define UART_DIVIDE 1
`else
 `define UART_DIVIDE 625
`endif

module cpu (input clk, output [4:0] led, output uart_tx, input uart_rx);
   reg [3:0] state = `START_STATE;

   wire 	 is_reading = state == `STATE_READ;
   wire 	 is_running = state == `STATE_RUN;
   wire 	 is_writing = state == `STATE_WRITE;

   wire reset = !is_running;
   reg 	counter = 0;

   wire gc_clock_enable   = is_running;
   wire eval_clock_enable = step_eval & is_running;
   wire reader_clock_enable = is_reading;
   wire writer_clock_enable = is_writing;

   always @ (posedge clk)
	 counter <= counter + 1;

   wire [12:0] P;
   wire [15:0] E1;
   wire [15:0] E2;
   wire [3:0] gcop;
   wire [5:0] gostate;
   wire [5:0] eostate;
   wire 	  conn_ea;
   wire 	  conn_et;

   wire 	  step_eval;

   wire        gc_ram_we;
   wire [12:0] gc_ram_addr;
   wire [15:0] gc_ram_di;

   wire        reader_ram_we;
   wire [12:0] reader_ram_addr;
   wire [15:0] reader_ram_di;

   wire [12:0] writer_ram_addr;

   wire        ram_we = reader_clock_enable ? reader_ram_we : gc_ram_we;
   wire [12:0] ram_addr = reader_clock_enable ? reader_ram_addr : writer_clock_enable ? writer_ram_addr : gc_ram_addr;
   wire [15:0] ram_di = reader_clock_enable ? reader_ram_di : gc_ram_di;
   wire [15:0] ram_do;

   wire 	   reader_finished;
   wire		   writer_finished;

   GCRAM gcram (.clk(clk), .we(ram_we), .addr(ram_addr), .di(ram_di), .do(ram_do));

   GC gc (.clk(clk), .rst(reset), .clk_enable(gc_clock_enable), .Ein(E1), .Eout(E2), .gcop(gcop), .ostate(gostate), .step_eval(step_eval), .conn_ea(conn_ea), .conn_et(conn_et), .ram_we(gc_ram_we), .ram_addr(gc_ram_addr), .ram_di(gc_ram_di), .ram_do(ram_do), .Pout(P));

   EVAL eval (.clk(clk), .rst(reset), .clk_enable(eval_clock_enable), .Ein(E2), .Eout(E1), .gcop(gcop), .ostate(eostate), .conn_ea(conn_ea), .conn_et(conn_et));

   READER reader (.clk(clk), .clk_enable(reader_clock_enable), .rx_byte(uart_rx_byte), .rx_signal(uart_rx_signal), .finished(reader_finished), .ram_we(reader_ram_we), .ram_addr(reader_ram_addr), .ram_di(reader_ram_di));

   WRITER writer (.clk(clk), .clk_enable(writer_clock_enable), .tx_byte(uart_tx_byte), .tx_signal(uart_tx_signal), .tx_busy(uart_is_transmitting), .finished(writer_finished), .ram_addr(writer_ram_addr), .ram_do(ram_do), .P(P));

   // UART outputs
   wire       uart_rx_signal;
   wire [7:0] uart_rx_byte;
   wire       uart_is_receiving;
   wire       uart_is_transmitting;
   wire       uart_rx_error;

   // UART logic
   wire 	  uart_tx_signal;
   wire [7:0] uart_tx_byte;

   always @ (posedge clk) begin
	  if(is_writing & writer_finished)
		state <= `STATE_READ;

	  if(is_reading & reader_finished)
		state <= `STATE_RUN;

	  if(is_running & eostate == 5'd7)
		state <= `STATE_WRITE;
   end

   // 4800 baud uart
   uart #(.CLOCK_DIVIDE(`UART_DIVIDE)) uart (.clk(clk), .rx(uart_rx), .tx(uart_tx), .transmit(uart_tx_signal), .tx_byte(uart_tx_byte), .received(uart_rx_signal), .rx_byte(uart_rx_byte), .is_receiving(uart_is_receiving), .is_transmitting(uart_is_transmitting), .recv_error (uart_rx_error));

   // Assign the outputs
   assign led[0] = is_reading;
   assign led[1] = uart_is_receiving;
   assign led[2] = is_writing;
   assign led[3] = uart_is_transmitting;
   assign led[4] = is_running;
endmodule