Do not handle static files (nginx does this already)

[gruntmaster-page.git] / app.psgi

#!/usr/bin/perl -w
use v5.14;
no if $] >= 5.017011, warnings => 'experimental::smartmatch';

use Gruntmaster::Data;
use Plack::App::Gruntmaster;
use Plack::Builder;
use Plack::Util;
use Log::Log4perl;

use constant AUTH_TIMEOUT => 5 * 60;

sub CONTENT_SECURITY_POLICY () {
	my $csp = <<CSP;
default-src 'none'
connect-src 'self'
form-action 'self'
frame-ancestors 'none'
img-src 'self' https://static.mindcoding.ro
referrer origin-when-cross-origin
script-src https://static.mindcoding.ro/static/js.js
style-src https://static.mindcoding.ro/static/css/
CSP
	chomp $csp;
	$csp =~ s/\n/; /gr;
}

my $db;

sub add_database {
	my $app = $_[0];
	sub {
		my ($env) = @_;
		$db //= Gruntmaster::Data->connect($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');
		$env->{'gruntmaster.dbic'} = $db;
		$app->($env)
	}
}

sub add_headers {
	my $app = $_[0];
	sub {
		my $resp = $app->($_[0]);
		my $hdrs = Plack::Util::headers($resp->[1]);
		$hdrs->set('Content-Security-Policy', CONTENT_SECURITY_POLICY);
		$hdrs->set('Link', '<https://static.mindcoding.ro/static/slate.css>; rel=stylesheet') if $hdrs->get('Content-Type') =~ m,^text/html,;
		$resp->[1] = $hdrs->headers;
		$resp;
	}
}

Log::Log4perl->init_once('log.conf');
$ENV{DBIC_NULLABLE_KEY_NOWARN} = 1;

builder {
	enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }};
	enable 'ContentLength';
	enable \&add_headers;
	enable 'Log4perl', category => 'plack';
	enable \&add_database;
	enable '+Plack::App::Gruntmaster::Auth',
	  dbi_connect => [$ENV{GRUNTMASTER_DSN} // 'dbi:Pg:', '', ''],
	  realm       => 'Gruntmaster 6000',
	  mail_from   => $ENV{GRUNTMASTER_RESET_FROM};
	Plack::App::Gruntmaster->run_if_script
}