[gruntmaster-page.git] / lib / Plack / App / Gruntmaster / HTML.pm

package Plack::App::Gruntmaster::HTML;
use v5.14;
use parent qw/Exporter/;
our @EXPORT = qw/render render_article/;

use File::Slurp qw/read_file/;
use HTML::Element::Library;
use HTML::TreeBuilder;
use POSIX qw//;
use Data::Dumper qw/Dumper/;
use Sort::ByExample
  sorter => {-as => 'ct_sort', example => [qw/Running Pending Finished/], xform => sub {$_->{status}}};

my $optional_end_tags = {%HTML::Tagset::optionalEndTag, tr => 1, td => 1, th => 1};

sub ftime ($)   { POSIX::strftime '%c', localtime shift }
sub literal ($) {
	my ($html) = @_;
	return '' unless $html;
	my $b = HTML::TreeBuilder->new;
	$b->ignore_unknown(0);
	$b->parse($html);
	HTML::Element::Library::super_literal $b->guts->as_HTML(undef, undef, $optional_end_tags);
}

sub HTML::Element::edit_href {
	my ($self, $sub) = @_;
	local $_ = $self->attr('href');
	$sub->();
	$self->attr(href => $_);
}

sub HTML::Element::iter3 {
	my ($self, $data, $code) = @_;
	my $orig = $self;
	my $prev = $orig;
	for my $el (@$data) {
		my $current = $orig->clone;
		$code->($el, $current);
		$prev->postinsert($current);
		$prev = $current;
	}
	$orig->detach;
}

sub HTML::Element::fid    { shift->look_down(id    => shift) }
sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }

sub HTML::Element::namedlink {
	my ($self, $id, $name) = @_;
	$name = $id unless $name && $name =~ /[[:graph:]]/;
	$self = $self->find('a');
	$self->edit_href(sub {s/id/$id/});
	$self->replace_content($name);
}

my %page_cache;
for (<tmpl/*>) {
	my ($tmpl, $lang) = m,tmpl/(\w+)\.(\w+),;
	my $builder = HTML::TreeBuilder->new;
	$builder->ignore_unknown(0);
	$page_cache{$tmpl, $lang} = $builder->parse_file($_);
}

sub render {
	my ($tmpl, $lang, %args) = @_;
	$lang //= 'en';
	my $meat = _render($tmpl, $lang, %args);
	my $html = _render('skel', $lang, %args, meat => $meat);
	if ($tmpl eq 'pb_entry') { # Move sidebar to correct position
		my $builder = HTML::TreeBuilder->new;
		$builder->ignore_unknown(0);
		my $tree = $builder->parse_content($html);
		$tree->fid('content')->postinsert($tree->fid('sidebar'));
		$html = $tree->as_HTML(undef, undef, $optional_end_tags)
	}
	$html
}

sub render_article {
	my ($art, $lang, %args) = @_;
	$lang //= 'en';
	my $title = read_file "a/$art.$lang.title";
	chomp $title;
	my $meat  = read_file "a/$art.$lang", binmode => ':utf8';
	_render('skel', $lang, title => $title , meat => $meat, %args)
}

sub _render {
	my ($tmpl, $lang, %args) = @_;
	my $tree = $page_cache{$tmpl, $lang}->clone or die "No such template/language combination: $tmpl/$lang\n";
	$tree = $tree->guts unless $tmpl eq 'skel';
	$tree->defmap(smap => \%args);
	my $process = __PACKAGE__->can("process_$tmpl");
	$process->($tree, %args) if $process;
	$_->attr('smap', undef) for $tree->look_down(sub {$_[0]->attr('smap')});
	$tree->as_HTML(undef, undef, $optional_end_tags);
}

sub process_skel {
	my ($tree, %args) = @_;
	$tree->content_handler(
		title   =>         $args{title},
		content => literal $args{meat});
}

sub process_us_entry {
	my ($tree, %args) = @_;
	$tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
	$tree->fid('track_user')->attr('data-user', $args{id});
	my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
	my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};

	my $pbiter = sub {
		my ($data, $li) = @_;
		$li->find('a')->namedlink($data);
	};
	$tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
	$tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
	$tree->fid('solved_count')->replace_content(scalar @solved);
	$tree->fid('attempted_count')->replace_content(scalar @attempted);

	my $ctiter = sub {
		my ($data, $td) = @_;
		$td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
		$td->fclass('score')->replace_content($data->{score});
		$td->fclass('rank')->replace_content($data->{rank});
	};
	$tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
}

sub process_us {
	my ($tree, %args) = @_;
	my $iter = sub {
		my ($data, $tr) = @_;
		$tr->fclass('user')->namedlink($data->{id}, $data->{name});
		$tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
	};
	$tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
}

sub process_ct_entry {
	my ($tree, %args) = @_;
	$_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
	$tree->fid('editorial')->detach unless $args{finished};
	$tree->fid('links')->detach unless $args{started};
	my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
	$tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
	$tree->content_handler(
		start       => ftime   $args{start},
		stop        => ftime   $args{stop},
		status      => $status,
		description => literal $args{description});
	$tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
}

sub process_ct {
	my ($tree, %args) = @_;
	my $iter = sub {
		my ($data, $tr) = @_;
		$data->{$_} = ftime $data->{$_} for qw/start stop/;
		$tr->hashmap(class => $data, [qw/name owner/]);
		$tr->fclass('name')->namedlink($data->{id}, $data->{name});
		$tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
	};
	$_->{status} = $_->{finished} ? 'Finished' : $_->{started} ? 'Running' : 'Pending' for @{$args{ct}};
	$tree->find('tbody')->find('tr')->iter3([ct_sort @{$args{ct}}], $iter);
}

sub process_pb_entry {
	my ($tree, %args) = @_;
	$tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
	$tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
	$tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
	$tree->content_handler(
		statement => literal $args{statement},
		level     => ucfirst $args{level},
		author    =>         $args{author},
		owner     =>         $args{owner_name} || $args{owner});
	if ($args{limits}) {
		my @limits = (@{$args{limits}}, {format => 'Other', timeout => $args{timeout} });
		@limits = map { sprintf '%s (%s)', @{$_}{qw/timeout format/} } @limits;
		$tree->look_down(smap => 'timeout')->replace_content(join ', ', @limits);
	}
	if ($args{contest_stop}) {
		$tree->fid('solution')->detach;
		$tree->fid('solution_modal')->detach;
		$tree->fid('score')->replace_content($args{value});
		$tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
	} else {
		$tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
		$tree->fid('solution')->detach unless $args{solution};
		$_->detach for $tree->fclass('rc'); # requires contest
		$tree->fid('solution_modal')->replace_content(literal $args{solution});
	}

	$tree->look_down(name => 'problem')->attr(value => $args{id});
	my $contest = $tree->look_down(name => 'contest');
	$contest->attr(value => $args{args}{contest}) if $args{args}{contest};
	$contest->detach unless $args{args}{contest}
}

sub process_sol {
	my ($tree, %args) = @_;
	$tree->content_handler(solution => literal $args{solution});
}

sub process_pb {
	my ($tree, %args) = @_;
	my $iter = sub {
		my ($data, $tr) = @_;
		$tr->set_child_content(class => 'author', $data->{author});
		$tr->set_child_content(class => 'value', $data->{value}) if $args{args}{contest};
		$tr->fclass('value')->detach unless $args{args}{contest};
		$tr->set_child_content(class => 'level', ucfirst $data->{level});
		$tr->fclass('name')->namedlink($data->{id}, $data->{name});
		$tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
		$tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
		$tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{args}{contest};
	};

	$tree->find('thead')->fclass('value')->detach unless $args{args}{contest};

	$tree->find('tbody')->find('tr')->iter3([sort { $a->{value} <=> $b->{value} } @{$args{pb}}], $iter);
	$tree->fid('open-alert')->detach unless $args{args}{contest};
}

sub process_log_entry {
	my ($tree, %args) = @_;
	$tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
	$tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
	$tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
	if ($args{contest}) {
		$tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
		$tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
	} else {
		$tree->fid('contest')->left->detach;
		$tree->fid('contest')->detach;
	}

	$args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
	my $iter = sub {
		my ($data, $tr) = @_;
		$data->{time} = sprintf '%.4fs', $data->{time};
		$tr->defmap(class => $data);
		$tr->fclass('result_text')->attr(class => "r$data->{result}")
	};
	$tree->fclass('result_text')->replace_content($args{result_text});
	$tree->fclass('result_text')->attr(class => "r$args{result}");
	$args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
	$tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
}

sub process_log {
	my ($tree, %args) = @_;
	my $iter = sub {
		my ($data, $tr) = @_;
		$tr->fclass('id')->namedlink($data->{id});
		$tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
		$tr->fclass('problem')->find('a')->edit_href(sub{$_ .= '?contest='.$data->{contest}}) if $data->{contest};
		$tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
		$tr->fclass('contest')->replace_content('None') unless $data->{contest};
		$tr->fclass('date')->replace_content(ftime $data->{date});
		$tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, Plack::App::Gruntmaster::FORMAT_EXTENSION()->{$data->{format}});
		$tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
		$tr->fclass('result_text')->replace_content($data->{result_text});
		$tr->fclass('result_text')->attr(class => "r$data->{result}");
		$tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
	};
	$tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
	$args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
	$args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
	for my $cls (qw/next previous/) {
		my $elem = $tree->fclass($cls);
		next unless $elem;
		delete $args{args}{page};
		my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
		$elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
	}
	$tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
}

sub process_st {
	my ($tree, %args) = @_;
	$args{problems} //= [];
	my $pbiter = sub {
		my ($data, $th) = @_;
		$th->attr(class => undef);
		$th->namedlink(@$data);
		$th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
	};
	$tree->fclass('problem')->iter3($args{problems}, $pbiter);
	my $iter = sub {
		my ($st, $tr) = @_;
		$tr->set_child_content(class => 'rank', $st->{rank});
		$tr->set_child_content(class => 'score', $st->{score});
		$tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
		my $pbscore = $tr->fclass('pbscore');
		$pbscore->iter($pbscore => @{$st->{scores}});
	};
	$tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
}

sub process_ed {
	my ($tree, %args) = @_;
	$tree->content_handler(editorial => literal $args{editorial});
	my $iter = sub {
		my ($data, $div) = @_;
		$div->set_child_content(class => 'value', $data->{value});
		$div->set_child_content(class => 'solution', literal $data->{solution});
		$div->fclass('problem')->namedlink($data->{id}, $data->{name});
	};
	my @pb = sort { $a->{value} <=> $b->{value} } @{$args{pb}};
	$tree->fclass('well')->iter3(\@pb, $iter);
}

1;
__END__
Commit	Line	Data
	1	package Plack::App::Gruntmaster::HTML;
	2	use v5.14;
	3	use parent qw/Exporter/;
	4	our @EXPORT = qw/render render_article/;
	5
	6	use File::Slurp qw/read_file/;
	7	use HTML::Element::Library;
	8	use HTML::TreeBuilder;
	9	use POSIX qw//;
	10	use Data::Dumper qw/Dumper/;
	11	use Sort::ByExample
	12	sorter => {-as => 'ct_sort', example => [qw/Running Pending Finished/], xform => sub {$_->{status}}};
	13
	14	my $optional_end_tags = {%HTML::Tagset::optionalEndTag, tr => 1, td => 1, th => 1};
	15
	16	sub ftime ($) { POSIX::strftime '%c', localtime shift }
	17	sub literal ($) {
	18	my ($html) = @_;
	19	return '' unless $html;
	20	my $b = HTML::TreeBuilder->new;
	21	$b->ignore_unknown(0);
	22	$b->parse($html);
	23	HTML::Element::Library::super_literal $b->guts->as_HTML(undef, undef, $optional_end_tags);
	24	}
	25
	26	sub HTML::Element::edit_href {
	27	my ($self, $sub) = @_;
	28	local $_ = $self->attr('href');
	29	$sub->();
	30	$self->attr(href => $_);
	31	}
	32
	33	sub HTML::Element::iter3 {
	34	my ($self, $data, $code) = @_;
	35	my $orig = $self;
	36	my $prev = $orig;
	37	for my $el (@$data) {
	38	my $current = $orig->clone;
	39	$code->($el, $current);
	40	$prev->postinsert($current);
	41	$prev = $current;
	42	}
	43	$orig->detach;
	44	}
	45
	46	sub HTML::Element::fid { shift->look_down(id => shift) }
	47	sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
	48
	49	sub HTML::Element::namedlink {
	50	my ($self, $id, $name) = @_;
	51	$name = $id unless $name && $name =~ /[[:graph:]]/;
	52	$self = $self->find('a');
	53	$self->edit_href(sub {s/id/$id/});
	54	$self->replace_content($name);
	55	}
	56
	57	my %page_cache;
	58	for (<tmpl/*>) {
	59	my ($tmpl, $lang) = m,tmpl/(\w+)\.(\w+),;
	60	my $builder = HTML::TreeBuilder->new;
	61	$builder->ignore_unknown(0);
	62	$page_cache{$tmpl, $lang} = $builder->parse_file($_);
	63	}
	64
	65	sub render {
	66	my ($tmpl, $lang, %args) = @_;
	67	$lang //= 'en';
	68	my $meat = _render($tmpl, $lang, %args);
	69	my $html = _render('skel', $lang, %args, meat => $meat);
	70	if ($tmpl eq 'pb_entry') { # Move sidebar to correct position
	71	my $builder = HTML::TreeBuilder->new;
	72	$builder->ignore_unknown(0);
	73	my $tree = $builder->parse_content($html);
	74	$tree->fid('content')->postinsert($tree->fid('sidebar'));
	75	$html = $tree->as_HTML(undef, undef, $optional_end_tags)
	76	}
	77	$html
	78	}
	79
	80	sub render_article {
	81	my ($art, $lang, %args) = @_;
	82	$lang //= 'en';
	83	my $title = read_file "a/$art.$lang.title";
	84	chomp $title;
	85	my $meat = read_file "a/$art.$lang", binmode => ':utf8';
	86	_render('skel', $lang, title => $title , meat => $meat, %args)
	87	}
	88
	89	sub _render {
	90	my ($tmpl, $lang, %args) = @_;
	91	my $tree = $page_cache{$tmpl, $lang}->clone or die "No such template/language combination: $tmpl/$lang\n";
	92	$tree = $tree->guts unless $tmpl eq 'skel';
	93	$tree->defmap(smap => \%args);
	94	my $process = __PACKAGE__->can("process_$tmpl");
	95	$process->($tree, %args) if $process;
	96	$_->attr('smap', undef) for $tree->look_down(sub {$_[0]->attr('smap')});
	97	$tree->as_HTML(undef, undef, $optional_end_tags);
	98	}
	99
	100	sub process_skel {
	101	my ($tree, %args) = @_;
	102	$tree->content_handler(
	103	title => $args{title},
	104	content => literal $args{meat});
	105	}
	106
	107	sub process_us_entry {
	108	my ($tree, %args) = @_;
	109	$tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
	110	$tree->fid('track_user')->attr('data-user', $args{id});
	111	my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
	112	my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
	113
	114	my $pbiter = sub {
	115	my ($data, $li) = @_;
	116	$li->find('a')->namedlink($data);
	117	};
	118	$tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
	119	$tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
	120	$tree->fid('solved_count')->replace_content(scalar @solved);
	121	$tree->fid('attempted_count')->replace_content(scalar @attempted);
	122
	123	my $ctiter = sub {
	124	my ($data, $td) = @_;
	125	$td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
	126	$td->fclass('score')->replace_content($data->{score});
	127	$td->fclass('rank')->replace_content($data->{rank});
	128	};
	129	$tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
	130	}
	131
	132	sub process_us {
	133	my ($tree, %args) = @_;
	134	my $iter = sub {
	135	my ($data, $tr) = @_;
	136	$tr->fclass('user')->namedlink($data->{id}, $data->{name});
	137	$tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
	138	};
	139	$tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
	140	}
	141
	142	sub process_ct_entry {
	143	my ($tree, %args) = @_;
	144	$_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
	145	$tree->fid('editorial')->detach unless $args{finished};
	146	$tree->fid('links')->detach unless $args{started};
	147	my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
	148	$tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
	149	$tree->content_handler(
	150	start => ftime $args{start},
	151	stop => ftime $args{stop},
	152	status => $status,
	153	description => literal $args{description});
	154	$tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
	155	}
	156
	157	sub process_ct {
	158	my ($tree, %args) = @_;
	159	my $iter = sub {
	160	my ($data, $tr) = @_;
	161	$data->{$_} = ftime $data->{$_} for qw/start stop/;
	162	$tr->hashmap(class => $data, [qw/name owner/]);
	163	$tr->fclass('name')->namedlink($data->{id}, $data->{name});
	164	$tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
	165	};
	166	$_->{status} = $_->{finished} ? 'Finished' : $_->{started} ? 'Running' : 'Pending' for @{$args{ct}};
	167	$tree->find('tbody')->find('tr')->iter3([ct_sort @{$args{ct}}], $iter);
	168	}
	169
	170	sub process_pb_entry {
	171	my ($tree, %args) = @_;
	172	$tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
	173	$tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
	174	$tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
	175	$tree->content_handler(
	176	statement => literal $args{statement},
	177	level => ucfirst $args{level},
	178	author => $args{author},
	179	owner => $args{owner_name} \|\| $args{owner});
	180	if ($args{limits}) {
	181	my @limits = (@{$args{limits}}, {format => 'Other', timeout => $args{timeout} });
	182	@limits = map { sprintf '%s (%s)', @{$_}{qw/timeout format/} } @limits;
	183	$tree->look_down(smap => 'timeout')->replace_content(join ', ', @limits);
	184	}
	185	if ($args{contest_stop}) {
	186	$tree->fid('solution')->detach;
	187	$tree->fid('solution_modal')->detach;
	188	$tree->fid('score')->replace_content($args{value});
	189	$tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
	190	} else {
	191	$tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
	192	$tree->fid('solution')->detach unless $args{solution};
	193	$_->detach for $tree->fclass('rc'); # requires contest
	194	$tree->fid('solution_modal')->replace_content(literal $args{solution});
	195	}
	196
	197	$tree->look_down(name => 'problem')->attr(value => $args{id});
	198	my $contest = $tree->look_down(name => 'contest');
	199	$contest->attr(value => $args{args}{contest}) if $args{args}{contest};
	200	$contest->detach unless $args{args}{contest}
	201	}
	202
	203	sub process_sol {
	204	my ($tree, %args) = @_;
	205	$tree->content_handler(solution => literal $args{solution});
	206	}
	207
	208	sub process_pb {
	209	my ($tree, %args) = @_;
	210	my $iter = sub {
	211	my ($data, $tr) = @_;
	212	$tr->set_child_content(class => 'author', $data->{author});
	213	$tr->set_child_content(class => 'value', $data->{value}) if $args{args}{contest};
	214	$tr->fclass('value')->detach unless $args{args}{contest};
	215	$tr->set_child_content(class => 'level', ucfirst $data->{level});
	216	$tr->fclass('name')->namedlink($data->{id}, $data->{name});
	217	$tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
	218	$tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
	219	$tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{args}{contest};
	220	};
	221
	222	$tree->find('thead')->fclass('value')->detach unless $args{args}{contest};
	223
	224	$tree->find('tbody')->find('tr')->iter3([sort { $a->{value} <=> $b->{value} } @{$args{pb}}], $iter);
	225	$tree->fid('open-alert')->detach unless $args{args}{contest};
	226	}
	227
	228	sub process_log_entry {
	229	my ($tree, %args) = @_;
	230	$tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
	231	$tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
	232	$tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
	233	if ($args{contest}) {
	234	$tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
	235	$tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
	236	} else {
	237	$tree->fid('contest')->left->detach;
	238	$tree->fid('contest')->detach;
	239	}
	240
	241	$args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
	242	my $iter = sub {
	243	my ($data, $tr) = @_;
	244	$data->{time} = sprintf '%.4fs', $data->{time};
	245	$tr->defmap(class => $data);
	246	$tr->fclass('result_text')->attr(class => "r$data->{result}")
	247	};
	248	$tree->fclass('result_text')->replace_content($args{result_text});
	249	$tree->fclass('result_text')->attr(class => "r$args{result}");
	250	$args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
	251	$tree->fid('no_results')->detach if $tree->fid('results') \|\| $tree->fid('errors');
	252	}
	253
	254	sub process_log {
	255	my ($tree, %args) = @_;
	256	my $iter = sub {
	257	my ($data, $tr) = @_;
	258	$tr->fclass('id')->namedlink($data->{id});
	259	$tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
	260	$tr->fclass('problem')->find('a')->edit_href(sub{$_ .= '?contest='.$data->{contest}}) if $data->{contest};
	261	$tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
	262	$tr->fclass('contest')->replace_content('None') unless $data->{contest};
	263	$tr->fclass('date')->replace_content(ftime $data->{date});
	264	$tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, Plack::App::Gruntmaster::FORMAT_EXTENSION()->{$data->{format}});
	265	$tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
	266	$tr->fclass('result_text')->replace_content($data->{result_text});
	267	$tr->fclass('result_text')->attr(class => "r$data->{result}");
	268	$tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
	269	};
	270	$tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
	271	$args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
	272	$args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
	273	for my $cls (qw/next previous/) {
	274	my $elem = $tree->fclass($cls);
	275	next unless $elem;
	276	delete $args{args}{page};
	277	my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
	278	$elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
	279	}
	280	$tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
	281	}
	282
	283	sub process_st {
	284	my ($tree, %args) = @_;
	285	$args{problems} //= [];
	286	my $pbiter = sub {
	287	my ($data, $th) = @_;
	288	$th->attr(class => undef);
	289	$th->namedlink(@$data);
	290	$th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
	291	};
	292	$tree->fclass('problem')->iter3($args{problems}, $pbiter);
	293	my $iter = sub {
	294	my ($st, $tr) = @_;
	295	$tr->set_child_content(class => 'rank', $st->{rank});
	296	$tr->set_child_content(class => 'score', $st->{score});
	297	$tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
	298	my $pbscore = $tr->fclass('pbscore');
	299	$pbscore->iter($pbscore => @{$st->{scores}});
	300	};
	301	$tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
	302	}
	303
	304	sub process_ed {
	305	my ($tree, %args) = @_;
	306	$tree->content_handler(editorial => literal $args{editorial});
	307	my $iter = sub {
	308	my ($data, $div) = @_;
	309	$div->set_child_content(class => 'value', $data->{value});
	310	$div->set_child_content(class => 'solution', literal $data->{solution});
	311	$div->fclass('problem')->namedlink($data->{id}, $data->{name});
	312	};
	313	my @pb = sort { $a->{value} <=> $b->{value} } @{$args{pb}};
	314	$tree->fclass('well')->iter3(\@pb, $iter);
	315	}
	316
	317	1;
	318	__END__