app.psgi

   1 #!/usr/bin/perl -w
   2 use v5.14;
   3 no if $] >= 5.017011, warnings => 'experimental::smartmatch';
   4
   5 use Apache2::Authen::Passphrase qw/pwcheck/;
   6 use Apache2::AuthzCaps qw/hascaps/;
   7 use Gruntmaster::Data;
   8 use Plack::App::Gruntmaster;
   9 use Plack::Builder;
  10 use Plack::Request;
  11 use Digest::SHA qw/sha256/;
  12 use Log::Log4perl;
  13
  14 use constant ACCESSLOG_FORMAT => '%{X-Forwarded-For}i|%h %u "%r" %>s %b "%{Referer}i" "%{User-agent}i"';
  15 use constant CONTENT_SECURITY_POLICY => q,default-src 'none'; script-src 'self' www.google-analytics.com; style-src 'self'; img-src 'self' www.google-analytics.com; connect-src 'self',;
  16
  17 $Apache2::AuthzCaps::rootdir = $Apache2::Authen::Passphrase::rootdir;
  18 my $word   = qr,(\w+),a;
  19 my $number = qr,(\d+),a;
  20 my $db = Gruntmaster::Data->connect('dbi:Pg:');
  21
  22 sub debug {
  23         local $Log::Log4perl::caller_depth = $Log::Log4perl::caller_depth + 1;
  24         $_[0]->{'psgix.logger'}->({qw/level debug message/ => $_[1]})
  25 }
  26
  27 sub some_auth_required {
  28         my $r = Plack::Request->new($_[0]);
  29         return 1 if $_[0]->{'gruntmaster.reqadmin'} || $r->path eq '/action/passwd' || $r->path eq '/submit';
  30         return 1 if $r->path =~ m,^/pb/$word, && $_[0]->{'gruntmaster.contest'} && time < $db->contest($_[0]->{'gruntmaster.contest'})->stop;
  31         ''
  32 }
  33
  34 sub is_problem_private {
  35         my $pb = $_[0];
  36         return 1 if $db->problem($pb)->private;
  37         my $prv = 0;
  38         for my $cp ($db->problem($pb)->contest_problems) {
  39                 $prv = 1;
  40                 return '' if $cp->contest->start <= time;
  41         }
  42
  43         $prv
  44 }
  45
  46 sub is_problem_in_contest {
  47         my ($pb, $ct) = @_;
  48         return 1 if $db->contest_problems->find($ct, $pb);
  49         return '' if defined $ct;
  50         for my $cp ($db->problem($pb)->contest_problems) {
  51                 return 1 if $cp->contest->stop <= time;
  52         }
  53         ''
  54 }
  55
  56 sub admin_required {
  57         local $_ = $_[0];
  58         my $env = $_[1];
  59         return $db->contest($env->{'gruntmaster.contest'})->owner->id if $env->{'gruntmaster.contest'} && $db->contest($env->{'gruntmaster.contest'})->start > time;
  60         return $db->problem($1)->owner->id if m,^/pb/$word, && (is_problem_private $1 || !is_problem_in_contest $1, $env->{'gruntmaster.contest'} ) || $env->{'gruntmaster.problem'} && (is_problem_private $env->{'gruntmaster.problem'} || !is_problem_in_contest $env->{'gruntmaster.problem'}, $env->{'gruntmaster.contest'});
  61         return $db->job    ($1)->owner->id if m,^/log/(?:src/)?$number, && ($db->job($1)->private || is_problem_private $db->job($1)->problem->id || $db->job($1)->contest && $db->job($1)->contest->stop > time);
  62         ''
  63 }
  64
  65 sub require_admin {
  66         my $app = $_[0];
  67         sub {
  68                 local *__ANON__ = "require_admin_middleware";
  69                 my $env = $_[0];
  70                 my $r = Plack::Request->new($env);
  71                 $env->{'gruntmaster.reqadmin'} = admin_required $r->path, $env;
  72                 $app->($env)
  73         }
  74 }
  75
  76 sub mangle_request {
  77         my $app = $_[0];
  78         sub {
  79                 local *__ANON__ = 'mangle_request_middleware';
  80                 my $env = $_[0];
  81                 my ($number, $word) = (qr,(\d+),a, qr,(\w+),a);
  82                 for ($env->{PATH_INFO}) {
  83                         $env->{'gruntmaster.page'}    = $1 if s,/page/$number$,/,;
  84                         $env->{'gruntmaster.contest'} = $1 if s,^/ct/$word/,/,;
  85                         $env->{'gruntmaster.problem'} = $1 if s,^/pb/$word/,/,;
  86                         $env->{'gruntmaster.user'}    = $1 if s,^/us/$word/,/,;
  87                         $env->{'gruntmaster.page'}  //= -1 if m,^/log/$,;
  88                 }
  89                 $app->($env);
  90         }
  91 }
  92
  93 my %authen_cache;
  94
  95 sub authenticate {
  96         my ($user, $pass, $env) = @_;
  97         my $cache_key = sha256 "$user:$pass";
  98         my $time = $authen_cache{$cache_key} // 0;
  99         if ($time >= time - 300) {
 100                 return 1;
 101         } else {
 102                 delete $authen_cache{$cache_key};
 103         }
 104
 105         return unless eval {
 106                 pwcheck $user, $pass;
 107                 1
 108         };
 109         $authen_cache{$cache_key} = time;
 110
 111         return if $env->{'gruntmaster.reqadmin'} && $env->{'gruntmaster.reqadmin'} ne $user && !hascaps $user, 'gmadm';
 112         1
 113 }
 114
 115 Log::Log4perl->init('log.conf');
 116 my $access_logger = Log::Log4perl->get_logger('access');
 117 $ENV{DBIC_NULLABLE_KEY_NOWARN} = 1;
 118
 119 builder {
 120         enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }};
 121         enable 'AccessLog', format => ACCESSLOG_FORMAT, logger => sub { $access_logger->info(@_) };
 122         enable 'ContentLength';
 123         enable Header => set => ['Content-Security-Policy', CONTENT_SECURITY_POLICY];
 124         enable_if { $_[0]->{PATH_INFO} =~ qr,^/static/,} Header => set => ['Cache-Control', 'public, max-age=604800'];
 125         enable 'Static', path => qr,^/static/,;
 126         enable 'Log4perl', category => 'plack';
 127         enable \&mangle_request;
 128         enable \&require_admin;
 129         enable_if \&some_auth_required, 'Auth::Basic', authenticator => \&authenticate, realm => 'Gruntmaster 6000';
 130         enable sub { my $app = $_[0]; sub { $_[0]->{'gruntmaster.dbic'} = $db; $app->($_[0]) } };
 131         Plack::App::Gruntmaster->to_app
 132 }