app.psgi

   1 #!/usr/bin/perl -w
   2 use v5.14;
   3
   4 use Apache2::Authen::Passphrase qw/pwcheck/;
   5 use Apache2::AuthzCaps qw/hascaps/;
   6 use Gruntmaster::Data;
   7 use Plack::App::Gruntmaster;
   8 use Plack::Builder;
   9 use Plack::Request;
  10 use Digest::SHA qw/sha256/;
  11 use Log::Log4perl;
  12
  13 use constant ACCESSLOG_FORMAT => '%{X-Forwarded-For}i|%h %u "%r" %>s %b "%{Referer}i" "%{User-agent}i"';
  14 use constant CONTENT_SECURITY_POLICY => q,default-src 'none'; script-src 'self' www.google-analytics.com; style-src 'self'; img-src 'self' www.google-analytics.com; connect-src 'self',;
  15
  16 $Apache2::AuthzCaps::rootdir = $Apache2::Authen::Passphrase::rootdir;
  17 my $word = qr,(\w+),a;
  18
  19 sub debug {
  20         local $Log::Log4perl::caller_depth = $Log::Log4perl::caller_depth + 1;
  21         $_[0]->{'psgix.logger'}->({qw/level debug message/ => $_[1]})
  22 }
  23
  24 sub some_auth_required {
  25         my $r = Plack::Request->new($_[0]);
  26         return 1 if $_[0]->{'gruntmaster.reqadmin'} || $r->path eq '/action/passwd' || $r->path =~ m,/pb/$word/submit$,;
  27         0
  28 }
  29
  30 sub admin_required {
  31         local $_ = $_[0];
  32         return 1 if m,^/pb/$word, && problem_private $1;
  33         return 1 if m,^/log/(?:job|src)/$word, && job_private $1;
  34         return 1 if m,^/ct/$word/(?:pb|log), && time < contest_start $1;
  35         return 1 if m,^/ct/$word/log/src, && time < contest_end $1;
  36         0
  37 }
  38
  39 sub require_admin {
  40         my $app = $_[0];
  41         sub {
  42                 *__ANON__ = "require_admin_middleware";
  43                 my $env = $_[0];
  44                 my $r = Plack::Request->new($env);
  45                 $env->{'gruntmaster.reqadmin'} = 1 if admin_required $r->path;
  46                 $app->($env)
  47         }
  48 }
  49
  50 my %authen_cache;
  51
  52 sub authenticate {
  53         my ($user, $pass, $env) = @_;
  54         my $cache_key = sha256 "$user:$pass";
  55         my $time = $authen_cache{$cache_key} // 0;
  56         if ($time >= time - 300) {
  57                 return 1;
  58         } else {
  59                 delete $authen_cache{$cache_key};
  60         }
  61
  62         return unless eval {
  63                 pwcheck $user, $pass;
  64                 1
  65         };
  66         $authen_cache{$cache_key} = time;
  67
  68         return if $env->{'gruntmaster.reqadmin'} && !hascaps $user, 'gmadm';
  69         1
  70 }
  71
  72 Log::Log4perl->init('log.conf');
  73 my $access_logger = Log::Log4perl->get_logger('access');
  74
  75 builder {
  76         enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }};
  77         enable 'AccessLog', format => ACCESSLOG_FORMAT, logger => sub { $access_logger->info(@_) };
  78         enable 'ContentLength';
  79         enable Header => set => ['Content-Security-Policy', CONTENT_SECURITY_POLICY];
  80         enable_if { $_[0]->{PATH_INFO} =~ qr,^/static/,} Header => set => ['Cache-Control', 'public, max-age=604800'];
  81         enable 'Static', path => qr,^/static/,;
  82         enable 'Log4perl', category => 'plack';
  83         enable \&require_admin;
  84         enable_if \&some_auth_required, 'Auth::Basic', authenticator => \&authenticate, realm => 'Gruntmaster 6000';
  85         Plack::App::Gruntmaster->to_app
  86 }