lib/Gruntmaster/Page/Generic.pm

   1 package Gruntmaster::Page::Generic;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6 our $VERSION = '5999.000_001';
   7
   8 use Gruntmaster::Page::Base;
   9 use JSON qw/encode_json decode_json/;
  10 use Plack::Request;
  11 use Sub::Name qw/subname/;
  12
  13 use constant PAGE_SIZE => 10;
  14
  15 sub putsym {
  16         my ($key, $value) = @_;
  17         no strict 'refs';
  18         subname $key => $value if ref $value eq 'CODE';
  19         *{"$key"} = $value;
  20 }
  21
  22 sub makepkg {
  23         my ($pkg, $id, $title) = @_;
  24         my $fn = $pkg =~ s,::,/,gr;
  25         return if $INC{"$fn.pm"};
  26         $INC{"$fn.pm"} = 1;
  27         Gruntmaster::Page::Base->import_to($pkg, $id, $title);
  28         1
  29 }
  30
  31 sub list {
  32         my ($thing, $lang, $env) = @_;
  33         my %thing = %$thing;
  34         my %params;
  35         #debug $env => "Contest is $ct";
  36         $thing{makers} //= sub { db(shift)->resultset($thing{rsname}) };
  37         my $rs = $thing{makers}->($env);
  38         $rs = $rs->search(undef, {order_by => 'me.id'}) unless $rs->is_ordered;
  39         if (my $page = $env->{'gruntmaster.page'}) {
  40                 my $pages = int ($rs->count / PAGE_SIZE);
  41                 $pages = 1 if $pages < 1;
  42                 $page = $pages if $page == -1;
  43                 @params{'page', 'pages'} = ($page, $pages);
  44                 $rs = $rs->search(undef, {offset => ($page - 1) * PAGE_SIZE, ($page == $pages ? () : (rows => PAGE_SIZE))});
  45         }
  46         $rs = $rs->search(undef, {
  47                 exists $thing{prefetch} ? (prefetch => $thing{prefetch}) : (),
  48                 exists $thing{columns} ? (columns => $thing{columns}) : (),
  49         });
  50         my @thing = map +{rs => $_, $_->get_columns}, $rs->all;
  51         @thing = map  { $thing{mangle}->($env); $_ } @thing if exists $thing{mangle};
  52         @thing = grep { $thing{choose}->() } @thing if exists $thing{choose};
  53         @thing = sort { $thing{sortby}->() } @thing if exists $thing{sortby};
  54         $thing{group} //= sub { $thing{id} };
  55         for (@thing) {
  56                 my $group = $thing{group}->();
  57                 $params{$group} //= [];
  58                 push $params{$group}, $_
  59         }
  60         wantarray ? %params : \%params
  61 }
  62
  63 sub entry {
  64         my ($thing, $lang, $env, $id) = @_;
  65         my %thing = %$thing;
  66         debug $env => "Rsname is $thing{rsname} and id is $id";
  67         my %params = map {+ rs => $_, $_->get_columns } db($env)->resultset($thing{rsname})->find($id);
  68         local $_ = \%params;
  69         $thing{mangle}->($env) if exists $thing{mangle};
  70         wantarray ? %params : \%params
  71 }
  72
  73 sub headers ($) { ['Content-Type' => 'application/json', 'Cache-Control' => 'max-age=' . $_[0]->max_age] }
  74
  75 sub create_thing {
  76         my %thing = @_;
  77         my $ucid = ucfirst $thing{id};
  78         my $pkg = "Gruntmaster::Page::$ucid";
  79
  80         putsym "${pkg}::_generate", sub { $_[1]->param(list \%thing, @_[2..$#_]) } if makepkg $pkg, @thing{qw/id title/};
  81         putsym "${pkg}::Entry::_generate",  sub { $_[1]->param(entry \%thing, @_[2..$#_]) } if makepkg "${pkg}::Entry", "$thing{id}_entry", $thing{entry_title} // '<tmpl_var name>';
  82         putsym "${pkg}::Read::generate", sub { [200, headers shift, [encode_json list \%thing, @_]] } if makepkg "${pkg}::Read";
  83         putsym "${pkg}::Entry::Read::generate", sub { [200, headers shift, [encode_json entry \%thing, @_]] } if makepkg "${pkg}::Entry::Read";
  84 }
  85
  86 sub params;
  87 sub makers (&);
  88 sub choose (&);
  89 sub sortby (&);
  90 sub group  (&);
  91 sub mangle (&);
  92 sub prefetch;
  93 sub columns;
  94
  95 sub thing (&){
  96         my %thing;
  97         no strict 'refs';
  98         local *{"params"} = sub { @thing{qw/id rsname title entry_title/} = @_ };
  99         local *{"choose"} = sub { $thing{choose} = shift };
 100         local *{"sortby"} = sub { $thing{sortby} = shift };
 101         local *{"mangle"} = sub { $thing{mangle} = shift };
 102         local *{"group"} = sub { $thing{group} = shift };
 103         local *{"makers"} = sub { $thing{makers} = shift };
 104         local *{"prefetch"} = sub { $thing{prefetch} = \@_ };
 105         local *{"columns"} = sub { $thing{columns} = \@_ };
 106         use strict 'refs';
 107
 108         shift->();
 109         create_thing %thing
 110 }
 111
 112 ##################################################
 113
 114 thing {
 115         params qw/us User Users/;
 116         choose { $_->{name} =~ /\w/ };
 117         sortby { lc $a->{name} cmp lc $b->{name} };
 118 };
 119
 120 thing {
 121         params qw/pb Problem Problems/;
 122         prefetch 'owner';
 123         makers {
 124                 my $env = $_[0];
 125                 my $db = db $env;
 126                 return $db->problems->search({owner => $env->{'gruntmaster.user'}}) if exists $env->{'gruntmaster.user'};
 127                 return $db->problems->search({'contest_problems.contest' => $env->{'gruntmaster.contest'}}, {join => 'contest_problems'}) if exists $env->{'gruntmaster.contest'};
 128                 $db->problems->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1});
 129         };
 130         sortby { $a->{name} cmp $b->{name}};
 131         group { $_->{level} };
 132         mangle {
 133                 my $env = shift;
 134                 $_->{owner_name} = $_->{rs}->owner->name;
 135                 $_->{cansubmit} = $env->{'gruntmaster.contest'} ? time < db($env)->contest($env->{'gruntmaster.contest'})->stop : 1;
 136                 eval {
 137                         db($env)->open->create({
 138                                 contest => $env->{'gruntmaster.contest'},
 139                                 problem => $_->{id},
 140                                 owner   => $env->{REMOTE_USER},
 141                         })
 142                 } if $env->{'gruntmaster.contest'} && time >= db($env)->contest($env->{'gruntmaster.contest'})->start;
 143         };
 144 };
 145
 146 thing {
 147         params qw/ct Contest Contests/;
 148         prefetch 'owner';
 149         sortby { $b->{start} <=> $a->{start} };
 150         group { time < $_->{start} ? 'pending' : time > $_->{stop} ? 'finished' : 'running' };
 151         mangle { $_->{started} = time >= $_->{start}; $_->{owner_name} =  $_->{rs}->owner->name };
 152 };
 153
 154 thing {
 155         params qw/log Job/, 'Job log', 'Job <tmpl_var id>';
 156         prefetch 'owner', 'problem';
 157         makers {
 158                 my $env = $_[0];
 159                 my $db = db $env;
 160                 return $db->jobs->search({'me.owner' => $env->{'gruntmaster.user'}}) if exists $env->{'gruntmaster.user'};
 161                 return $db->jobs->search({problem => $env->{'gruntmaster.problem'}}) if exists $env->{'gruntmaster.problem'};
 162                 $db->jobs->search({contest => $env->{'gruntmaster.contest'}})
 163         };
 164         sortby { $b->{id} <=> $a->{id}};
 165         mangle {
 166                 my $env = shift;
 167                 $_->{results} &&= decode_json $_->{results};
 168                 $_->{owner_name} = $_->{rs}->owner->name;
 169                 $_->{problem_name} = $_->{rs}->problem->name;
 170                 $_->{size} = length $_->{source};
 171                 delete $_->{source};
 172                 $_->{pageprefix} = $env->{'gruntmaster.page'} == -1 ? 'page/' : '';
 173         }
 174 };
 175
 176 putsym 'Gruntmaster::Page::Pb::Entry::vary',    sub { 'Authorization' };
 177 putsym 'Gruntmaster::Page::Pb::Entry::max_age', sub { 600 };
 178 putsym 'Gruntmaster::Page::Log::max_age', sub { 10 };
 179
 180 1