lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Element::Library;
   8 use HTML::TreeBuilder;
   9 use POSIX qw//;
  10 use Data::Dumper qw/Dumper/;
  11
  12 my $optional_end_tags = {%HTML::Tagset::optionalEndTag, tr => 1, td => 1, th => 1};
  13
  14 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  15 sub literal ($) {
  16         my ($html) = @_;
  17         return unless $html;
  18         my $b = HTML::TreeBuilder->new;
  19         $b->ignore_unknown(0);
  20         $b->parse($html);
  21         HTML::Element::Library::super_literal $b->guts->as_HTML(undef, undef, $optional_end_tags);
  22 }
  23
  24 sub HTML::Element::edit_href {
  25         my ($self, $sub) = @_;
  26         local $_ = $self->attr('href');
  27         $sub->();
  28         $self->attr(href => $_);
  29 }
  30
  31 sub HTML::Element::iter3 {
  32         my ($self, $data, $code) = @_;
  33         my $orig = $self;
  34         my $prev = $orig;
  35         for my $el (@$data) {
  36                 my $current = $orig->clone;
  37                 $code->($el, $current);
  38                 $prev->postinsert($current);
  39                 $prev = $current;
  40         }
  41         $orig->detach;
  42 }
  43
  44 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  45 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  46
  47 sub HTML::Element::namedlink {
  48         my ($self, $id, $name) = @_;
  49         $name = $id unless $name =~ /[[:graph:]]/;
  50         $self = $self->find('a');
  51         $self->edit_href(sub {s/id/$id/});
  52         $self->replace_content($name);
  53 }
  54
  55 my %page_cache;
  56 for (<tmpl/*>) {
  57         my ($tmpl, $lang) = m,tmpl/(\w+)\.(\w+),;
  58         my $builder = HTML::TreeBuilder->new;
  59         $builder->ignore_unknown(0);
  60         $page_cache{$tmpl, $lang} = $builder->parse_file($_);
  61 }
  62
  63 sub render {
  64         my ($tmpl, $lang, %args) = @_;
  65         $lang //= 'en';
  66         my $meat = _render($tmpl, $lang, %args);
  67         _render('skel', $lang, %args, meat => $meat)
  68 }
  69
  70 sub render_article {
  71         my ($art, $lang, %args) = @_;
  72         $lang //= 'en';
  73         my $title = read_file "a/$art.$lang.title";
  74         chomp $title;
  75         my $meat  = read_file "a/$art.$lang";
  76         _render('skel', $lang, title => $title , meat => $meat, %args)
  77 }
  78
  79 sub _render {
  80         my ($tmpl, $lang, %args) = @_;
  81         my $tree = $page_cache{$tmpl, $lang}->clone or die "No such template/language combination: $tmpl/$lang\n";
  82         $tree = $tree->guts unless $tmpl eq 'skel';
  83         $tree->defmap(smap => \%args);
  84         my $process = __PACKAGE__->can("process_$tmpl");
  85         $process->($tree, %args) if $process;
  86         $_->detach for $tree->look_down(static => $args{static} ? 'no' : 'yes');
  87         $_->attr('static', undef) for $tree->look_down(sub {$_[0]->attr('static')});
  88         $_->attr('smap', undef) for $tree->look_down(sub {$_[0]->attr('smap')});
  89         $tree->as_HTML(undef, undef, $optional_end_tags);
  90 }
  91
  92 sub process_skel {
  93         my ($tree, %args) = @_;
  94         $tree->content_handler(
  95                 title   =>         $args{title},
  96                 content => literal $args{meat});
  97 }
  98
  99 sub process_us_entry {
 100         my ($tree, %args) = @_;
 101         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
 102         $tree->fid('track_user')->attr('data-user', $args{id});
 103         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
 104         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
 105
 106         my $pbiter = sub {
 107                 my ($data, $li) = @_;
 108                 $li->find('a')->namedlink($data);
 109         };
 110         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
 111         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
 112         $tree->fid('solved_count')->replace_content(scalar @solved);
 113         $tree->fid('attempted_count')->replace_content(scalar @attempted);
 114
 115         my $ctiter = sub {
 116                 my ($data, $td) = @_;
 117                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
 118                 $td->fclass('score')->replace_content($data->{score});
 119                 $td->fclass('rank')->replace_content($data->{rank});
 120         };
 121         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 122 }
 123
 124 sub process_us {
 125         my ($tree, %args) = @_;
 126         my $iter = sub {
 127                 my ($data, $tr) = @_;
 128                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 129                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 130         };
 131         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 132 }
 133
 134 sub process_ct_entry {
 135         my ($tree, %args) = @_;
 136         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 137         $tree->fid('editorial')->detach unless $args{finished};
 138         $tree->fid('links')->detach unless $args{started};
 139         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 140         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 141         $tree->content_handler(
 142                 start       => ftime   $args{start},
 143                 stop        => ftime   $args{stop},
 144                 status      => $status,
 145                 description => literal $args{description});
 146         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 147 }
 148
 149 sub process_ct {
 150         my ($tree, %args) = @_;
 151         my $iter = sub {
 152                 my ($data, $tr) = @_;
 153                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 154                 $tr->hashmap(class => $data, [qw/name owner/]);
 155                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 156                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 157         };
 158         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 159 }
 160
 161 sub process_pb_entry {
 162         my ($tree, %args) = @_;
 163         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 164         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 165         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 166         $tree->content_handler(
 167                 statement => literal $args{statement},
 168                 level     => ucfirst $args{level},
 169                 author    =>         $args{author},
 170                 owner     =>         $args{owner_name} || $args{owner});
 171         if ($args{limits}) {
 172                 my @limits = (@{$args{limits}}, {format => 'Other', timeout => $args{timeout} });
 173                 @limits = map { sprintf '%s (%s)', @{$_}{qw/timeout format/} } @limits;
 174                 $tree->look_down(smap => 'timeout')->replace_content(join ', ', @limits);
 175         }
 176         if ($args{contest_stop}) {
 177                 $tree->fid('solution')->detach;
 178                 $tree->fid('solution_modal')->detach;
 179                 my $score = $tree->fid('score');
 180                 $score->attr('data-start' => $args{open_time});
 181                 $score->attr('data-stop'  => $args{contest_stop});
 182                 $score->attr('data-value'  => $args{value});
 183                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 184         } else {
 185                 $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 186                 $tree->fid('solution')->detach unless $args{solution};
 187                 $_->detach for $tree->fclass('rc'); # requires contest
 188                 $tree->fid('solution_modal')->fclass('modal-body')->replace_content(literal $args{solution});
 189         }
 190         if ($args{cansubmit}) {
 191                 $tree->fid('nosubmit')->detach;
 192                 $tree->look_down(name => 'problem')->attr(value => $args{id});
 193                 my $contest = $tree->look_down(name => 'contest');
 194                 $contest->attr(value => $args{args}{contest}) if $args{args}{contest};
 195                 $contest->detach unless $args{args}{contest}
 196         } else {
 197                 $tree->fid('nosubmit')->find('a')->edit_href(sub{s/id/$args{id}/});
 198                 $tree->fid('submit')->detach
 199         }
 200 }
 201
 202 sub process_sol {
 203         my ($tree, %args) = @_;
 204         $tree->content_handler(solution => literal $args{solution});
 205 }
 206
 207 sub process_pb {
 208         my ($tree, %args) = @_;
 209         my $titer = sub {
 210                 my ($data, $tr) = @_;
 211                 $tr->set_child_content(class => 'author', $data->{author});
 212                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 213                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 214                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 215                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{contest};
 216         };
 217         my $iter = sub {
 218                 my ($data, $div) = @_;
 219                 $div->attr(id => $data);
 220                 $div->find('h2')->replace_content(ucfirst $data);
 221                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 222         };
 223         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 224         $tree->fid('open-alert')->detach unless $args{contest};
 225 }
 226
 227 sub process_log_entry {
 228         my ($tree, %args) = @_;
 229         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 230         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 231         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 232         if ($args{contest}) {
 233                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 234                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 235         } else {
 236                 $tree->fid('contest')->left->detach;
 237                 $tree->fid('contest')->detach;
 238         }
 239
 240         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 241         my $iter = sub {
 242                 my ($data, $tr) = @_;
 243                 $data->{time} = sprintf '%.4fs', $data->{time};
 244                 $tr->defmap(class => $data);
 245                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 246         };
 247         $tree->fclass('result_text')->replace_content($args{result_text});
 248         $tree->fclass('result_text')->attr(class => "r$args{result}");
 249         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 250         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 251 }
 252
 253 sub process_log {
 254         my ($tree, %args) = @_;
 255         my $iter = sub {
 256                 my ($data, $tr) = @_;
 257                 $tr->fclass('id')->namedlink($data->{id});
 258                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 259                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
 260                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 261                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 262                 $tr->fclass('date')->replace_content(ftime $data->{date});
 263                 $tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, Plack::App::Gruntmaster::FORMAT_EXTENSION()->{$data->{format}});
 264                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 265                 $tr->fclass('result_text')->replace_content($data->{result_text});
 266                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 267                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 268         };
 269         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 270         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 271         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 272         for my $cls (qw/next previous/) {
 273                 my $elem = $tree->fclass($cls);
 274                 next unless $elem;
 275                 delete $args{args}{page};
 276                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 277                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 278         }
 279         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 280
 281         my @detach;
 282         push @detach, $args{args}{$_} ? $tree->fclass($_) : () for qw/problem contest owner/;
 283         $_->detach for @detach;
 284 }
 285
 286 sub process_st {
 287         my ($tree, %args) = @_;
 288         $args{problems} //= [];
 289         my $pbiter = sub {
 290                 my ($data, $th) = @_;
 291                 $th->attr(class => undef);
 292                 $th->namedlink(@$data);
 293                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 294         };
 295         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 296         my $iter = sub {
 297                 my ($st, $tr) = @_;
 298                 $tr->set_child_content(class => 'rank', $st->{rank});
 299                 $tr->set_child_content(class => 'score', $st->{score});
 300                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 301                 my $pbscore = $tr->fclass('pbscore');
 302                 $pbscore->iter($pbscore => @{$st->{scores}});
 303         };
 304         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 305 }
 306
 307 sub process_ed {
 308         my ($tree, %args) = @_;
 309         $tree->content_handler(editorial => literal $args{editorial});
 310         my $iter = sub {
 311                 my ($data, $div) = @_;
 312                 $div->set_child_content(class => 'value', $data->{value});
 313                 $div->set_child_content(class => 'solution', literal $data->{solution});
 314                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 315         };
 316         my @pb = map { @{$args{$_} // []} } qw/beginner easy medium hard/;
 317         $tree->fclass('well')->iter3(\@pb, $iter);
 318 }
 319
 320 1;
 321 __END__