lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Element::Library;
   8 use HTML::TreeBuilder;
   9 use POSIX qw//;
  10 use Data::Dumper qw/Dumper/;
  11
  12 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  13 sub literal ($) { HTML::Element::Library::super_literal shift // '' }
  14
  15 sub HTML::Element::edit_href {
  16         my ($self, $sub) = @_;
  17         local $_ = $self->attr('href');
  18         $sub->();
  19         $self->attr(href => $_);
  20 }
  21
  22 sub HTML::Element::iter3 {
  23         my ($self, $data, $code) = @_;
  24         my $orig = $self;
  25         my $prev = $orig;
  26         for my $el (@$data) {
  27                 my $current = $orig->clone;
  28                 $code->($el, $current);
  29                 $prev->postinsert($current);
  30                 $prev = $current;
  31         }
  32         $orig->detach;
  33 }
  34
  35 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  36 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  37
  38 sub HTML::Element::namedlink {
  39         my ($self, $id, $name) = @_;
  40         $name = $id unless $name =~ /[[:graph:]]/;
  41         $self = $self->find('a');
  42         $self->edit_href(sub {s/id/$id/});
  43         $self->replace_content($name);
  44 }
  45
  46 my %page_cache;
  47 for (<tmpl/*>) {
  48         my ($tmpl, $lang) = m,tmpl/(\w+)\.(\w+),;
  49         my $builder = HTML::TreeBuilder->new;
  50         $builder->ignore_unknown(0);
  51         $page_cache{$tmpl, $lang} = $builder->parse_file($_);
  52 }
  53
  54 sub render {
  55         my ($tmpl, $lang, %args) = @_;
  56         $lang //= 'en';
  57         my $meat = _render($tmpl, $lang, %args);
  58         _render('skel', $lang, %args, meat => $meat)
  59 }
  60
  61 sub render_article {
  62         my ($art, $lang, %args) = @_;
  63         $lang //= 'en';
  64         my $title = read_file "a/$art.$lang.title";
  65         my $meat  = read_file "a/$art.$lang";
  66         _render('skel', $lang, title => $title , meat => $meat, %args)
  67 }
  68
  69 sub _render {
  70         my ($tmpl, $lang, %args) = @_;
  71         my $tree = $page_cache{$tmpl, $lang}->clone or die "No such template/language combination: $tmpl/$lang\n";
  72         $tree = $tree->guts unless $tmpl eq 'skel';
  73         $tree->defmap(smap => \%args);
  74         my $process = __PACKAGE__->can("process_$tmpl");
  75         $process->($tree, %args) if $process;
  76         $_->detach for $tree->look_down(static => $args{static} ? 'no' : 'yes');
  77         $_->attr('static', undef) for $tree->look_down(sub {$_[0]->attr('static')});
  78         $_->attr('smap', undef) for $tree->look_down(sub {$_[0]->attr('smap')});
  79         $tree->as_HTML;
  80 }
  81
  82 sub process_skel {
  83         my ($tree, %args) = @_;
  84         $tree->content_handler(
  85                 title   =>         $args{title},
  86                 content => literal $args{meat});
  87 }
  88
  89 sub process_us_entry {
  90         my ($tree, %args) = @_;
  91         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
  92         $tree->fid('track_user')->attr('data-user', $args{id});
  93         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  94         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  95
  96         my $pbiter = sub {
  97                 my ($data, $li) = @_;
  98                 $li->find('a')->namedlink($data);
  99         };
 100         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
 101         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
 102         $tree->fid('solved_count')->replace_content(scalar @solved);
 103         $tree->fid('attempted_count')->replace_content(scalar @attempted);
 104
 105         my $ctiter = sub {
 106                 my ($data, $td) = @_;
 107                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
 108                 $td->fclass('score')->replace_content($data->{score});
 109                 $td->fclass('rank')->replace_content($data->{rank});
 110         };
 111         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 112 }
 113
 114 sub process_us {
 115         my ($tree, %args) = @_;
 116         my $iter = sub {
 117                 my ($data, $tr) = @_;
 118                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 119                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 120         };
 121         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 122 }
 123
 124 sub process_ct_entry {
 125         my ($tree, %args) = @_;
 126         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 127         $tree->fid('editorial')->detach unless $args{finished};
 128         $tree->fid('links')->detach unless $args{started};
 129         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 130         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 131         $tree->content_handler(
 132                 start       => ftime   $args{start},
 133                 stop        => ftime   $args{stop},
 134                 status      => $status,
 135                 description => literal $args{description});
 136         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 137 }
 138
 139 sub process_ct {
 140         my ($tree, %args) = @_;
 141         my $iter = sub {
 142                 my ($data, $tr) = @_;
 143                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 144                 $tr->hashmap(class => $data, [qw/name owner/]);
 145                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 146                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 147         };
 148         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 149 }
 150
 151 sub process_pb_entry {
 152         my ($tree, %args) = @_;
 153         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 154         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 155         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 156         $tree->content_handler(
 157                 statement => literal $args{statement},
 158                 level     => ucfirst $args{level},
 159                 author    =>         $args{author},
 160                 owner     =>         $args{owner_name} || $args{owner});
 161         if ($args{limits}) {
 162                 my @limits = (@{$args{limits}}, {format => 'Other', timeout => $args{timeout} });
 163                 @limits = map { sprintf '%s (%s)', @{$_}{qw/timeout format/} } @limits;
 164                 $tree->look_down(smap => 'timeout')->replace_content(join ', ', @limits);
 165         }
 166         if ($args{contest_stop}) {
 167                 $tree->fid('solution')->detach;
 168                 $tree->fid('solution_modal')->detach;
 169                 my $score = $tree->fid('score');
 170                 $score->attr('data-start' => $args{open_time});
 171                 $score->attr('data-stop'  => $args{contest_stop});
 172                 $score->attr('data-value'  => $args{value});
 173                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 174         } else {
 175                 $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 176                 $tree->fid('solution')->detach unless $args{solution};
 177                 $_->detach for $tree->fclass('rc'); # requires contest
 178                 $tree->fid('solution_modal')->fclass('modal-body')->replace_content(literal $args{solution});
 179         }
 180         if ($args{cansubmit}) {
 181                 $tree->fid('nosubmit')->detach;
 182                 $tree->look_down(name => 'problem')->attr(value => $args{id});
 183                 my $contest = $tree->look_down(name => 'contest');
 184                 $contest->attr(value => $args{args}{contest}) if $args{args}{contest};
 185                 $contest->detach unless $args{args}{contest}
 186         } else {
 187                 $tree->fid('nosubmit')->find('a')->edit_href(sub{s/id/$args{id}/});
 188                 $tree->fid('submit')->detach
 189         }
 190 }
 191
 192 sub process_sol {
 193         my ($tree, %args) = @_;
 194         $tree->content_handler(solution => literal $args{solution});
 195 }
 196
 197 sub process_pb {
 198         my ($tree, %args) = @_;
 199         my $titer = sub {
 200                 my ($data, $tr) = @_;
 201                 $tr->set_child_content(class => 'author', $data->{author});
 202                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 203                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 204                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 205                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private} && !$args{contest};
 206         };
 207         my $iter = sub {
 208                 my ($data, $div) = @_;
 209                 $div->attr(id => $data);
 210                 $div->find('h2')->replace_content(ucfirst $data);
 211                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 212         };
 213         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 214         $tree->fid('open-alert')->detach unless $args{contest};
 215 }
 216
 217 sub process_log_entry {
 218         my ($tree, %args) = @_;
 219         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 220         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 221         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 222         if ($args{contest}) {
 223                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 224                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 225         } else {
 226                 $tree->fid('contest')->left->detach;
 227                 $tree->fid('contest')->detach;
 228         }
 229
 230         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 231         my $iter = sub {
 232                 my ($data, $tr) = @_;
 233                 $data->{time} = sprintf '%.4fs', $data->{time};
 234                 $tr->defmap(class => $data);
 235                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 236         };
 237         $tree->fclass('result_text')->replace_content($args{result_text});
 238         $tree->fclass('result_text')->attr(class => "r$args{result}");
 239         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 240         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 241 }
 242
 243 sub process_log {
 244         my ($tree, %args) = @_;
 245         my $iter = sub {
 246                 my ($data, $tr) = @_;
 247                 $tr->fclass('id')->namedlink($data->{id});
 248                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 249                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{args}{contest}"}) if $args{args}{contest};
 250                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 251                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 252                 $tr->fclass('date')->replace_content(ftime $data->{date});
 253                 $tr->fclass('source')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB %s", $data->{size}/1024, Plack::App::Gruntmaster::FORMAT_EXTENSION()->{$data->{format}});
 254                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 255                 $tr->fclass('result_text')->replace_content($data->{result_text});
 256                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 257                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 258         };
 259         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 260         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 261         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 262         for my $cls (qw/next previous/) {
 263                 my $elem = $tree->fclass($cls);
 264                 next unless $elem;
 265                 delete $args{args}{page};
 266                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 267                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 268         }
 269         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 270
 271         my @detach;
 272         push @detach, $args{args}{$_} ? $tree->fclass($_) : () for qw/problem contest owner/;
 273         $_->detach for @detach;
 274 }
 275
 276 sub process_st {
 277         my ($tree, %args) = @_;
 278         $args{problems} //= [];
 279         my $pbiter = sub {
 280                 my ($data, $th) = @_;
 281                 $th->attr(class => undef);
 282                 $th->namedlink(@$data);
 283                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 284         };
 285         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 286         my $iter = sub {
 287                 my ($st, $tr) = @_;
 288                 $tr->set_child_content(class => 'rank', $st->{rank});
 289                 $tr->set_child_content(class => 'score', $st->{score});
 290                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 291                 my $pbscore = $tr->fclass('pbscore');
 292                 $pbscore->iter($pbscore => @{$st->{scores}});
 293         };
 294         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 295 }
 296
 297 sub process_ed {
 298         my ($tree, %args) = @_;
 299         $tree->content_handler(editorial => literal $args{editorial});
 300         my $iter = sub {
 301                 my ($data, $div) = @_;
 302                 $div->set_child_content(class => 'value', $data->{value});
 303                 $div->set_child_content(class => 'solution', literal $data->{solution});
 304                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 305         };
 306         my @pb = map { @{$args{$_} // []} } qw/beginner easy medium hard/;
 307         $tree->fclass('well')->iter3(\@pb, $iter);
 308 }
 309
 310 1;
 311 __END__