package Gruntmaster::Page::Generic;

use 5.014000;
use strict;
use warnings;
our $VERSION = '5999.000_001';

use Gruntmaster::Page::Base;
use JSON qw/encode_json decode_json/;
use Plack::Request;
use Sub::Name qw/subname/;

use constant PAGE_SIZE => 10;

sub putsym {
	my ($key, $value) = @_;
	no strict 'refs';
	subname $key => $value if ref $value eq 'CODE';
	*{"$key"} = $value;
}

sub makepkg {
	my ($pkg, $id, $title) = @_;
	my $fn = $pkg =~ s,::,/,gr;
	return if $INC{"$fn.pm"};
	$INC{"$fn.pm"} = 1;
	Gruntmaster::Page::Base->import_to($pkg, $id, $title);
	1
}

sub list {
	my ($thing, $lang, $env) = @_;
	my %thing = %$thing;
	my %params;
	#debug $env => "Contest is $ct";
	$thing{makers} //= sub { db(shift)->resultset($thing{rsname}) };
	my $rs = $thing{makers}->($env);
	$rs = $rs->search(undef, {order_by => 'me.id'}) unless $rs->is_ordered;
	if (my $page = $env->{'gruntmaster.page'}) {
		my $pages = int ($rs->count / PAGE_SIZE);
		$pages = 1 if $pages < 1;
		$page = $pages if $page == -1;
		@params{'page', 'pages'} = ($page, $pages);
		$rs = $rs->search(undef, {offset => ($page - 1) * PAGE_SIZE, ($page == $pages ? () : (rows => PAGE_SIZE))});
	}
	$rs = $rs->search(undef, {
		exists $thing{prefetch} ? (prefetch => $thing{prefetch}) : (),
		exists $thing{columns} ? (columns => $thing{columns}) : (),
	});
	my @thing = map +{rs => $_, $_->get_columns}, $rs->all;
	@thing = map  { $thing{mangle}->(); $_ } @thing if exists $thing{mangle};
	@thing = grep { $thing{choose}->() } @thing if exists $thing{choose};
	@thing = sort { $thing{sortby}->() } @thing if exists $thing{sortby};
	$thing{group} //= sub { $thing{id} };
	for (@thing) {
		my $group = $thing{group}->();
		$params{$group} //= [];
		push $params{$group}, $_
	}
	wantarray ? %params : \%params
}

sub entry {
	my ($thing, $lang, $env, $id) = @_;
	my %thing = %$thing;
	debug $env => "Rsname is $thing{rsname} and id is $id";
	my %params = map {+ rs => $_, $_->get_columns } db($env)->resultset($thing{rsname})->find($id);
	$thing{mangle}->(local $_ = \%params) if exists $thing{mangle};
	wantarray ? %params : \%params
}

sub headers ($) { ['Content-Type' => 'application/json', 'Cache-Control' => 'max-age=' . $_[0]->max_age] }

sub create_thing {
	my %thing = @_;
	my $ucid = ucfirst $thing{id};
	my $pkg = "Gruntmaster::Page::$ucid";

	putsym "${pkg}::_generate", sub { $_[1]->param(list \%thing, @_[2..$#_]) } if makepkg $pkg, @thing{qw/id title/};
	putsym "${pkg}::Entry::_generate",  sub { $_[1]->param(entry \%thing, @_[2..$#_]) } if makepkg "${pkg}::Entry", "$thing{id}_entry", $thing{entry_title} // '<tmpl_var name>';
	putsym "${pkg}::Read::generate", sub { [200, headers shift, [encode_json list \%thing, @_]] } if makepkg "${pkg}::Read";
	putsym "${pkg}::Entry::Read::generate", sub { [200, headers shift, [encode_json entry \%thing, @_]] } if makepkg "${pkg}::Entry::Read";
}

sub params;
sub makers (&);
sub choose (&);
sub sortby (&);
sub group  (&);
sub mangle (&);
sub prefetch;
sub columns;

sub thing (&){
	my %thing;
	no strict 'refs';
	local *{"params"} = sub { @thing{qw/id rsname title entry_title/} = @_ };
	local *{"choose"} = sub { $thing{choose} = shift };
	local *{"sortby"} = sub { $thing{sortby} = shift };
	local *{"mangle"} = sub { $thing{mangle} = shift };
	local *{"group"} = sub { $thing{group} = shift };
	local *{"makers"} = sub { $thing{makers} = shift };
	local *{"prefetch"} = sub { $thing{prefetch} = \@_ };
	local *{"columns"} = sub { $thing{columns} = \@_ };
	use strict 'refs';

	shift->();
	create_thing %thing
}

##################################################

thing {
	params qw/us User Users/;
	choose { $_->{name} =~ /\w/ };
	sortby { lc $a->{name} cmp lc $b->{name} };
};

thing {
	params qw/pb Problem Problems/;
	prefetch 'owner';
	makers {
		my $env = $_[0];
		my $db = db $env;
		return $db->problems->search({owner => $env->{'gruntmaster.user'}}) if exists $env->{'gruntmaster.user'};
		return $db->problems->search({'contest_problems.contest' => $env->{'gruntmaster.contest'}}, {join => 'contest_problems'}) if exists $env->{'gruntmaster.contest'};
		$db->problems->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1});
	};
	sortby { $a->{name} cmp $b->{name}};
	group { $_->{level} };
	mangle {
		my $env = shift;
		$_->{owner_name} = $_->{rs}->owner->name;
		$_->{cansubmit} = $env->{'gruntmaster.contest'} ? time < db($env)->contest($env->{'gruntmaster.contest'})->stop : 1;
		eval {
			db($env)->open->create({
				contest => $env->{'gruntmaster.contest'},
				problem => $_->{id},
				owner   => $env->{REMOTE_USER},
			})
		} if $env->{'gruntmaster.contest'} && time >= db($env)->contest($env->{'gruntmaster.contest'})->start;
	};
};

thing {
	params qw/ct Contest Contests/;
	prefetch 'owner';
	sortby { $b->{start} <=> $a->{start} };
	group { time < $_->{start} ? 'pending' : time > $_->{stop} ? 'finished' : 'running' };
	mangle { $_->{started} = time >= $_->{start}; $_->{owner_name} =  $_->{rs}->owner->name };
};

thing {
	params qw/log Job/, 'Job log', 'Job <tmpl_var id>';
	prefetch 'owner', 'problem';
	makers {
		my $env = $_[0];
		my $db = db $env;
		return $db->jobs->search({'me.owner' => $env->{'gruntmaster.user'}}) if exists $env->{'gruntmaster.user'};
		return $db->jobs->search({problem => $env->{'gruntmaster.problem'}}) if exists $env->{'gruntmaster.problem'};
		$db->jobs->search({contest => $env->{'gruntmaster.contest'}})
	};
	sortby { $b->{id} <=> $a->{id}};
	mangle {
		my $env = shift;
		$_->{results} &&= decode_json $_->{results};
		$_->{owner_name} = $_->{rs}->owner->name;
		$_->{problem_name} = $_->{rs}->problem->name;
		$_->{size} = length $_->{source};
		delete $_->{source};
		$_->{pageprefix} = $env->{'gruntmaster.page'} == -1 ? 'page/' : '';
	}
};

putsym 'Gruntmaster::Page::Pb::Entry::vary',    sub { 'Authorization' };
putsym 'Gruntmaster::Page::Pb::Entry::max_age', sub { 600 };

1
