package Gruntmaster::Page::Log;

use 5.014000;
use strict;
use warnings;
use parent qw/Exporter/;
our @EXPORT_OK = qw/generate/;
our $VERSION = '0.001';

use constant TITLE => 'Job log';
use constant PAGE_SIZE => 10;

use HTML::Template::Compiled;
use POSIX qw/strftime/;
use Gruntmaster::Page::Common qw/header footer/;
use Gruntmaster::Data qw/job_date job_file job_name job_private job_problem job_result job_result_text job_user/;

my %templates = (
	en => <<'HTML',
<table border>
<thead>
<tr><th>ID<th>Problem<th>Date<th>Size<th>User<th>Result
<tbody>
<tmpl_loop log><tr><td><a href="<tmpl_var id>"><tmpl_var id></a>
<td><a href="/pb/<tmpl_var problem>"><tmpl_var name></a>
<td><tmpl_var date>
<td><tmpl_var size></a>
<td><tmpl_var user><td class="r<tmpl_var result>"><tmpl_var result_text>
</tmpl_loop>
</table>
HTML
);

$templates{$_}  = header($_, TITLE) . $templates{$_} for keys %templates;
$templates{$_} .= footer $_ for keys %templates;

sub generate{
	$_[0] =~ m,^(?:ct/([^/]+)/)?log/(\w+)\.html$,;
	local $Gruntmaster::Data::contest = $1;
	my $page = $2 eq 'index' ? 0 : $2;

	my $htc = HTML::Template::Compiled->new(scalarref => \$templates{$_[1]});
	my @log = sort { $b->{id} <=> $a->{id} } map +{
		id => $_,
		(job_private() ? (private => job_private) : ()),
		date => (job_date() ? strftime ('%c' => localtime job_date) : '?'),
		name => job_name,
		problem => job_problem,
		result => job_result,
		result_text => job_result_text,
		size => sprintf ("%.2f KiB", (length job_file) / 1024),
		user => job_user}, ($page - 1) * PAGE_SIZE + 1 .. $page * PAGE_SIZE;
	$htc->param(log => \@log);
	$htc->output
}

1
