package Gruntmaster::Page::Log;

use 5.014000;
use strict;
use warnings;
use parent qw/Exporter/;
our @EXPORT_OK = qw/generate/;
our $VERSION = '0.001';

use constant PAGE_SIZE => 10;

use constant FORMAT_EXTENSION => {
  CPP => 'cpp',
};

use HTML::Template::Compiled;
use POSIX qw/strftime/;
use Gruntmaster::Page::Common qw/cook_templates reload_templates/;
use Gruntmaster::Data qw/jobcard job_date job_extension job_filesize problem_name job_private job_problem job_result job_result_text job_user/;

my %orig_templates = (
	en => <<'HTML',
<table border>
<thead>
<tr><th>ID<th>Problem<th>Date<th>Size<th>User<th>Result
<tbody>
<tmpl_loop log><tr><td><a href="job/<tmpl_var id>.var"><tmpl_var id></a>
<td><a href="../pb/<tmpl_var problem>"><tmpl_var name></a>
<td><tmpl_var date>
<td><a href="src/<tmpl_var id>.<tmpl_var extension>"<tmpl_if private> data-private</tmpl_if>><tmpl_var size></a></a>
<td><tmpl_var user><td class="r<tmpl_var result>"><tmpl_var result_text>
</tmpl_loop>
</table>
HTML
);

my %templates = cook_templates %orig_templates, log => 'Job log';

sub generate{
	%templates = cook_templates %orig_templates, log => 'Job log' if reload_templates;
	$_[0] =~ m,^(?:ct/([^/]+)/)?log/(\w+)\.html$,;
	local $Gruntmaster::Data::contest = $1;
	my $pages = jobcard / PAGE_SIZE;
	my $page = $2 eq 'index' ? $pages : $2;

	my $htc = HTML::Template::Compiled->new(scalarref => \$templates{$_[1]});
	my @log = sort { $b->{id} <=> $a->{id} } map +{
		id => $_,
		(job_private() ? (private => job_private) : ()),
		date => (job_date() ? strftime ('%c' => localtime job_date) : '?'),
		extension => job_extension,
		name => problem_name job_problem,
		problem => job_problem,
		result => job_result,
		result_text => job_result_text,
		size => sprintf ("%.2f KiB", job_filesize() / 1024),
		user => job_user}, ($page - 1) * PAGE_SIZE + 1 .. $page == $pages ? jobcard : $page * PAGE_SIZE;
	$htc->param(log => \@log);
	$htc->output
}

1
