package Gruntmaster::Page::Pb::Entry;

use 5.014000;
use strict;
use warnings;
use parent qw/Exporter/;
our @EXPORT_OK = qw/generate/;
our $VERSION = '0.001';

use Fcntl qw/:flock/;
use HTML::Template::Compiled;
use IO::File;
use POSIX qw/strftime/;
use YAML::Any qw/LoadFile/;
use File::Basename qw/fileparse/;
use File::Slurp qw/slurp/;
use Gruntmaster::Page qw/header footer/;

use constant FORMATS => [qw/CPP/];
use constant TITLE => '<tmpl_var name>';

my %templates = (
  en => <<'HTML',
<tmpl_var statement>

<h1>Submit solution</h1>
<form action="https://gm.ieval.ro/action/submit" method="POST" enctype="multipart/form-data">
<input type="hidden" name="problem" value="<tmpl_var id>">
<label>File: <input name="prog" required type="file"></label>

<label>File format: <select name="prog_format" required>
<tmpl_loop formats><option value="<tmpl_var _>"><tmpl_var _></option>
</tmpl_loop></select></label>

<input type="submit" value="Submit job">
HTML
);

$templates{$_}  = header($_, TITLE) . $templates{$_} for keys %templates;
$templates{$_} .= footer $_ for keys %templates;

sub generate{
  my ($path, $lang) = @_;
  $path = ($path =~ m,pb/(.*)/index,)[0];
  my $template = $templates{$_[1]};
  my $htc = HTML::Template::Compiled->new(scalarref => \$template);
  flock my $metafh = IO::File->new("<pb/$path/meta.yml"), LOCK_SH;
  my $meta = LoadFile "pb/$path/meta.yml";

  $htc->param(formats => FORMATS);
  $htc->param(id => $path);
  $htc->param(name => $meta->{name});
  $htc->param(statement => scalar slurp "pb/$path/statement.$lang");
  $htc->output
}

1
