package Gruntmaster::Page::St;

use Gruntmaster::Page::Base st => 'Standings';

use constant LEVEL_VALUES => {
	beginner => 100,
	easy => 250,
	medium => 500,
	hard => 1000,
};

sub calc_score{
	my ($mxscore, $time, $tries, $totaltime) = @_;
	my $score = $mxscore;
	$time = 0 if $time < 0;
	$time = 300 if $time > $totaltime;
	$score = ($totaltime - $time) / $totaltime * $score;
	$score -= $tries / 10 * $mxscore;
	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
	int $score + 0.5
}

sub _generate{
	my ($self, $htc, $lang, $env) = @_;
	#debug $env => "language is '$lang'";

	my $ct = $env->{'gruntmaster.contest'} && db($env)->contest($env->{'gruntmaster.contest'});

	my @problems = map { $_->problem } db($env)->contest_problems->search({contest => $ct && $ct->id}, {qw/join problem order_by problem.level/});
	my (%scores, %tries);
	for my $job (db($env)->jobs->search({contest => $ct && $ct->id}, {order_by => 'id'})) {

		if ($ct) {
			my $open = db($env)->opens->find($ct->id, $job->problem->id, $job->owner->id);
			my $time = $job->date - ($open ? $open->time : $ct->start);
			next if $time < 0;
			my $value = $job->problem->value // LEVEL_VALUES->{$job->problem->level};
			$scores{$job->owner->id}{$job->problem->id} = $job->result ? 0 : calc_score ($value, $time, $tries{$job->owner}{$job->problem}, $ct->stop - $ct->start);
			$tries{$job->owner->id}{$job->problem->id}++;
		} else {
			no warnings 'numeric';
			$scores{$job->owner->id}{$job->problem->id} = 0 + $job->result_text || ($job->result ? 0 : 100)
		}
	}

	my @st = sort { $b->{score} <=> $a->{score} or $a->{user}->id cmp $b->{user}->id} map {
		my $user = $_;
		+{
			user => db($env)->user($user),
			score => sum (values $scores{$user}),
			scores => [map { $scores{$user}{$_->id} // '-'} @problems],
			problems => $ct,
		}
	} keys %scores;

	$st[0]->{rank} = 1;
	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
	$htc->param(problems => \@problems) if $ct;
	$htc->param(st => \@st);
}

1
