+use constant LEVEL_VALUES => {
+ beginner => 100,
+ easy => 250,
+ medium => 500,
+ hard => 1000,
+};
+
+sub calc_score{
+ my ($mxscore, $time, $tries, $totaltime) = @_;
+ my $score = $mxscore;
+ $time = 0 if $time < 0;
+ $time = 300 if $time > $totaltime;
+ $score = ($totaltime - $time) / $totaltime * $score;
+ $score -= $tries / 10 * $mxscore;
+ $score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
+ int $score + 0.5
+}
+
+sub standings {
+ my ($self, $ct) = @_;
+ $ct &&= $self->contest($ct);
+
+ my @problems = map { $_->problem } $self->contest_problems->search({contest => $ct && $ct->id}, {qw/join problem order_by problem.level/});
+ my (%scores, %tries);
+ for my $job ($self->jobs->search({contest => $ct && $ct->id}, {order_by => 'id'})) {
+ if ($ct) {
+ my $open = $self->opens->find($ct->id, $job->problem->id, $job->owner->id);
+ my $time = $job->date - ($open ? $open->time : $ct->start);
+ next if $time < 0;
+ my $value = $job->problem->value // LEVEL_VALUES->{$job->problem->level};
+ my $factor = $job->result ? 0 : 1;
+ $factor = $1 / 100 if $job->result_text =~ /^(\d+ )/;
+ $scores{$job->owner->id}{$job->problem->id} = int ($factor * calc_score ($value, $time, $tries{$job->owner->id}{$job->problem->id}++, $ct->stop - $ct->start));
+ } else {
+ no warnings 'numeric';
+ $scores{$job->owner->id}{$job->problem->id} = 0 + $job->result_text || ($job->result ? 0 : 100)
+ }
+ }
+
+ my @st = sort { $b->{score} <=> $a->{score} or $a->{user}->id cmp $b->{user}->id} map {
+ my $user = $_;
+ +{
+ user => $self->user($user),
+ score => sum (values %{$scores{$user}}),
+ scores => [map { $scores{$user}{$_->id} // '-'} @problems],
+ problems => $ct,
+ }
+ } keys %scores;
+
+ $st[0]->{rank} = 1;
+ $st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
+ @st
+}
+
+sub user_list {
+ my $rs = $_[0]->users->search(undef, {order_by => 'name', columns => USER_PUBLIC_COLUMNS});
+ [ map +{ $_->get_columns }, $rs->all ]
+}
+
+sub user_entry {
+ my ($self, $id) = @_;
+ +{ $self->users->find($id, {columns => USER_PUBLIC_COLUMNS})->get_columns }
+}
+
+sub problem_list {
+ my ($self, %args) = @_;
+ my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
+ $rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest};
+ $rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
+ $rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
+ my %params;
+ $params{contest} = $args{contest} if $args{contest};
+ for ($rs->all) {
+ $params{$_->level} //= [];
+ push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
+ }
+ \%params
+}
+
+sub problem_entry {
+ my ($self, $id, $contest, $user) = @_;
+ my $pb = $self->problems->find($id, {columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
+ my $running = $contest && $self->contest($contest)->is_running;
+ eval {
+ $self->opens->create({
+ contest => $contest,
+ problem => $id,
+ owner => $user,
+ time => time,
+ })
+ } if $running;
+ +{ $pb->get_columns, owner_name => $pb->owner->name, cansubmit => $contest ? $running : 1 }
+}
+
+sub contest_list {
+ my ($self, %args) = @_;
+ my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
+ $rs = $rs->search({owner => $args{owner}}) if $args{owner};
+ my %params;
+ for ($rs->all) {
+ my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
+ $params{$state} //= [];
+ push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
+ }
+ \%params
+}
+
+sub contest_entry {
+ my ($self, $id) = @_;
+ my $ct = $self->contest($id);
+ +{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
+}
+
+sub job_list {
+ my ($self, %args) = @_;
+ $args{page} //= 1;
+ my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
+ $rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
+ $rs = $rs->search({contest => $args{contest}}) if $args{contest};
+ $rs = $rs->search({problem => $args{problem}}) if $args{problem};
+ return {
+ log => [map {
+ my %params = $_->get_columns;
+ $params{owner_name} = $_->owner->name;
+ $params{problem_name} = $_->problem->name;
+ $params{results} &&= decode_json $params{results};
+ $params{size} = length $params{source};
+ delete $params{source};
+ \%params
+ } $rs->all],
+ current_page => $rs->pager->current_page,
+ maybe previous_page => $rs->pager->previous_page,
+ maybe next_page => $rs->pager->next_page,
+ maybe last_page => $rs->pager->last_page,
+ }
+}
+
+sub job_entry {
+ my ($self, $id) = @_;
+ my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner']});
+ my %params = $job->get_columns;
+ $params{owner_name} = $job->owner->name;
+ $params{problem_name} = $job->problem->name;
+ $params{results} &&= decode_json $params{results};
+ $params{size} = length $params{source};
+ delete $params{source};
+ \%params
+}
+