X-Git-Url: http://git.ieval.ro/?a=blobdiff_plain;f=lib%2FGruntmaster%2FData.pm;h=3258c85c32b769b460c769188c4300e0e79d4135;hb=a2aa46e6fb478ba94f05d5ce36b7848e7a8bf807;hp=35f4365ef205e838efe6159b973608a32ad93298;hpb=812e07636fbffb1c85aaa1864721401d7de1057a;p=gruntmaster-data.git

diff --git a/lib/Gruntmaster/Data.pm b/lib/Gruntmaster/Data.pm
index 35f4365..3258c85 100644
--- a/lib/Gruntmaster/Data.pm
+++ b/lib/Gruntmaster/Data.pm
@@ -15,26 +15,209 @@ __PACKAGE__->load_namespaces;
 # Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
 # DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
 
-our $VERSION = '5999.000_006';
+our $VERSION = '5999.000_011';
 
 use Lingua::EN::Inflect qw/PL_N/;
+use JSON::MaybeXS qw/decode_json/;
+use List::Util qw/sum/;
+use PerlX::Maybe qw/maybe/;
 use Sub::Name qw/subname/;
 
+use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private statement timeout olimit value/];
+use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
+use constant JOBS_PER_PAGE => 10;
+
 sub dynsub{
 	our ($name, $sub) = @_;
-	no strict 'refs';
+	no strict 'refs'; ## no critic (Strict)
 	*$name = subname $name => $sub
 }
 
 BEGIN {
-	for my $rs (qw/contest contest_problem job open problem user/) {
+	for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
 		my $rsname = ucfirst $rs;
-		$rsname =~ s/_([a-z])/\u$1/g;
+		$rsname =~ s/_([a-z])/\u$1/gs;
 		dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
 		dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
 	}
 }
 
+sub calc_score{
+	my ($mxscore, $time, $tries, $totaltime) = @_;
+	my $score = $mxscore;
+	$time = 0 if $time < 0;
+	$time = 300 if $time > $totaltime;
+	$score = ($totaltime - $time) / $totaltime * $score;
+	$score -= $tries / 10 * $mxscore;
+	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
+	int $score + 0.5
+}
+
+sub standings {
+	my ($self, $ct) = @_;
+	$ct &&= $self->contest($ct);
+
+	my @problems = map { $_->rawproblem } $self->contest_problems->search({contest => $ct && $ct->id}, {qw/join problem order_by problem.level/});
+	my (%scores, %tries, %opens);
+	$opens{$_->rawproblem, $_->rawowner} = $_ for $self->opens->search({contest => $ct && $ct->id});
+	for my $job ($self->jobs->search({contest => $ct && $ct->id}, {qw/order_by me.id prefetch/ => [qw/problem/]})) {
+		if ($ct) {
+			my $open = $opens{$job->rawproblem, $job->rawowner};
+			my $time = $job->date - ($open ? $open->time : $ct->start);
+			next if $time < 0;
+			my $value = $job->problem->value;
+			my $factor = $job->result ? 0 : 1;
+			$factor = $1 / 100 if $job->result_text =~ /^(\d+ )/s;
+			$scores{$job->rawowner}{$job->rawproblem} = int ($factor * calc_score ($value, $time, $tries{$job->rawowner}{$job->rawproblem}++, $ct->stop - $ct->start));
+		} else {
+			no warnings 'numeric'; ## no critic (ProhibitNoWarnings)
+			$scores{$job->rawowner}{$job->rawproblem} = 0 + $job->result_text || ($job->result ? 0 : 100)
+		}
+	}
+
+	my %user_to_name = map { $_ => $_->name } $self->users->all;
+
+	my @st = sort { $b->{score} <=> $a->{score} or $a->{user} cmp $b->{user} } map { ## no critic (ProhibitReverseSortBlock)
+		my $user = $_;
+		+{
+			user => $user,
+			user_name => $user_to_name{$user},
+			score => sum (values %{$scores{$user}}),
+			scores => [map { $scores{$user}{$_} // '-'} @problems],
+			problems => $ct,
+		}
+	} keys %scores;
+
+	$st[0]->{rank} = 1;
+	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
+	@st
+}
+
+sub user_list {
+	my $rs = $_[0]->users->search(undef, {order_by => 'name', columns => USER_PUBLIC_COLUMNS});
+	[ map { { $_->get_columns } } $rs->all ]
+}
+
+sub user_entry {
+	my ($self, $id) = @_;
+	my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
+	my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses;
+	my @contests = map { {contest => $_->get_column('contest'), rank => $_->rank, score => $_->score} } $user->contest_statuses;
+	+{ $user->get_columns, problems => \@problems, contests => \@contests }
+}
+
+sub problem_list {
+	my ($self, %args) = @_;
+	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
+	$rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest};
+	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
+	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
+	my %params;
+	$params{contest} = $args{contest} if $args{contest};
+	for ($rs->all) {
+		$params{$_->level} //= [];
+		push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
+	}
+	\%params
+}
+
+sub problem_entry {
+	my ($self, $id, $contest, $user) = @_;
+	my $running = $contest && $self->contest($contest)->is_running;
+	my $columns = PROBLEM_PUBLIC_COLUMNS;
+	push @$columns, 'solution' unless $running;
+	my $pb = $self->problems->find($id, {columns => $columns, prefetch => 'owner'});
+	eval { ## no critic (RequireCheckingReturnValueOfEval)
+		$self->opens->create({
+			contest => $contest,
+			problem => $id,
+			owner => $user,
+			time => time,
+		})
+	} if $running;
+	$contest &&= $self->contest($contest);
+	+{ $pb->get_columns, owner_name => $pb->owner->name, cansubmit => $contest ? $running : 1, $running ? (contest_start => $contest->start, contest_stop => $contest->stop) : () }
+}
+
+sub contest_list {
+	my ($self, %args) = @_;
+	my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
+	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
+	my %params;
+	for ($rs->all) {
+		my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
+		$params{$state} //= [];
+		push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
+	}
+	\%params
+}
+
+sub contest_entry {
+	my ($self, $id) = @_;
+	my $ct = $self->contest($id);
+	+{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
+}
+
+sub job_list {
+	my ($self, %args) = @_;
+	$args{page} //= 1;
+	my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
+	$rs = $rs->search({'me.owner' => $args{owner}})   if $args{owner};
+	$rs = $rs->search({contest    => $args{contest}}) if $args{contest};
+	$rs = $rs->search({problem    => $args{problem}}) if $args{problem};
+	return {
+		log => [map {
+			my %params = $_->get_columns;
+			$params{owner_name}   = $_->owner->name;
+			$params{problem_name} = $_->problem->name;
+			$params{results} &&= decode_json $params{results};
+			$params{size}      = length $params{source};
+			delete $params{source};
+			\%params
+		} $rs->all],
+		current_page => $rs->pager->current_page,
+		maybe previous_page => $rs->pager->previous_page,
+		maybe next_page => $rs->pager->next_page,
+		maybe last_page => $rs->pager->last_page,
+	}
+}
+
+sub job_entry {
+	my ($self, $id) = @_;
+	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner']});
+	my %params = $job->get_columns;
+	$params{owner_name}   = $job->owner->name;
+	$params{problem_name} = $job->problem->name;
+	$params{results} &&= decode_json $params{results};
+	$params{size}      = length $params{source};
+	delete $params{source};
+	\%params
+}
+
+sub update_status {
+	my ($self) = @_;
+	my @jobs = $self->jobs->search(undef, {cache => 1})->all;
+
+	my %hash;
+	$hash{$_->get_column('problem'), $_->get_column('owner')} = [$_->id, $_->result ? 1 : 0] for @jobs;
+	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
+
+	my @contest_statuses = map {
+		my $contest = $_->id;
+		my @standings = $self->standings($contest);
+		map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } @standings;
+	} $self->contests->all;
+
+	my $txn = sub {
+		$self->problem_statuses->delete;
+		$self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
+		$self->contest_statuses->delete;
+		$self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
+	};
+
+	$self->txn_do($txn);
+}
+
 1;
 
 __END__
@@ -117,6 +300,98 @@ Equivalent to C<< $schema->resultset('Problem')->find($id) >>
 
 Equivalent to C<< $schema->resultset('User')->find($id) >>
 
+=item user_list
+
+Returns a list of users as an arrayref containing hashrefs.
+
+=item user_entry($id)
+
+Returns a hashref with information about the user $id.
+
+=item problem_list([%args])
+
+Returns a list of problems grouped by level. A hashref with levels as keys.
+
+Takes the following arguments:
+
+=over
+
+=item owner
+
+Only show problems owned by this user
+
+=item contest
+
+Only show problems in this contest
+
+=back
+
+=item problem_entry($id, [$contest, $user])
+
+Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
+
+=item contest_list([%args])
+
+Returns a list of contests grouped by state. A hashref with the following keys:
+
+=over
+
+=item pending
+
+An arrayref of hashrefs representing pending contests
+
+=item running
+
+An arrayref of hashrefs representing running contests
+
+=item finished
+
+An arrayref of hashrefs representing finished contests
+
+=back
+
+Takes the following arguments:
+
+=over
+
+=item owner
+
+Only show contests owned by this user.
+
+=back
+
+=item contest_entry($id)
+
+Returns a hashref with information about the contest $id.
+
+=item job_list([%args])
+
+Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
+
+=over
+
+=item owner
+
+Only show jobs submitted by this user.
+
+=item contest
+
+Only show jobs submitted in this contest.
+
+=item problem
+
+Only show jobs submitted for this problem.
+
+=item page
+
+Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
+
+=back
+
+=item job_entry($id)
+
+Returns a hashref with information about the job $id.
+
 =back
 
 =head1 AUTHOR