X-Git-Url: http://git.ieval.ro/?a=blobdiff_plain;f=lib%2FGruntmaster%2FData.pm;h=4393a62de6f687d724f8cab874b7e190cfd31283;hb=5bfe4fee59691741265842a2d06cf53a1d86aa6e;hp=1b2492cc28c6a07dc927edf30d4039ec9fe1e1eb;hpb=014ee8a614839ded741f61979d979cdd4f20044c;p=gruntmaster-data.git

diff --git a/lib/Gruntmaster/Data.pm b/lib/Gruntmaster/Data.pm
index 1b2492c..4393a62 100644
--- a/lib/Gruntmaster/Data.pm
+++ b/lib/Gruntmaster/Data.pm
@@ -1,102 +1,490 @@
 package Gruntmaster::Data;
-use v5.14;
+use 5.014;
 use warnings;
+
 use parent qw/Exporter/;
+our $VERSION = '5999.000_013';
+our @EXPORT = qw/purge db user_list user_entry problem_list problem_entry contest_list contest_entry contest_full contest_has_problem job_list job_entry job_full create_job standings update_status rerun_job/; ## no critic (ProhibitAutomaticExportation)
+
+use JSON::MaybeXS qw/decode_json/;
+use HTTP::Tiny;
+use PerlX::Maybe qw/maybe/;
+
+use DBI;
+use DBIx::Simple;
+use List::Util qw/sum/;
+use SQL::Abstract;
+
+use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
+use constant JOBS_PER_PAGE => 50;
+
+my %statements = (
+	user_list_sth => 'SELECT * FROM user_list LIMIT 200',
+	user_entry_sth => 'SELECT * FROM user_data WHERE id = ?',
 
-use JSON qw/encode_json decode_json/;
+	problem_status_sth => 'SELECT problem,solved FROM problem_status WHERE owner = ?',
+	contest_status_sth => 'SELECT contest,score,rank FROM contest_status WHERE owner = ?',
 
-use Redis;
+	contest_list_sth => 'SELECT * FROM contest_entry',
+	contest_entry_sth => 'SELECT * FROM contest_entry WHERE id = ?',
+	contest_full_sth => 'SELECT * FROM contests WHERE id = ?',
+	contest_problems_sth => 'SELECT problem FROM contest_problems JOIN problems pb ON problem=pb.id WHERE contest = ? ORDER BY pb.value',
+	contest_has_problem_sth => 'SELECT EXISTS(SELECT 1 FROM contest_problems WHERE contest = ? AND problem = ?)',
+	opens_sth => 'SELECT problem,owner,time FROM opens WHERE contest = ?',
 
-our $contest;
-my $redis = Redis->new;
-my $pubsub = Redis->new;
+	problem_entry_sth => 'SELECT ' . (join ',', @{PROBLEM_PUBLIC_COLUMNS()}, 'statement', 'solution') . ' FROM problems WHERE id = ?',
+	limits_sth => 'SELECT format,timeout FROM limits WHERE problem = ?',
+	problem_values_sth => 'SELECT id,value FROM problems',
+
+	job_entry_sth => 'SELECT * FROM job_entry WHERE id = ?',
+	job_full_sth => 'SELECT * FROM jobs WHERE id = ?',
+
+	rerun_job_sth => 'UPDATE jobs SET daemon=NULL,result=-2,result_text=NULL,results=NULL,errors=NULL WHERE id = ?',
+);
+
+our $db;
+sub db () { $db }
+
+sub init {
+	$db = DBIx::Simple->new(@_);
+	$db->keep_statements = 100;
+};
 
-sub dynsub{
-	no strict 'refs';
-	*{$_[0]} = $_[1];
+sub purge;
+
+sub query {
+	my ($stat, @extra) = @_;
+	$db->query($statements{$stat}, @extra)
 }
 
-BEGIN {
-	for my $cmd (qw/multi exec smembers get hget hdel hset sadd srem incr hmset hsetnx publish del/) {
-		dynsub uc $cmd, sub { $redis->$cmd(@_) };
+my (%name_cache, %name_cache_time);
+use constant NAME_CACHE_MAX_AGE => 5;
+
+sub object_name {
+	my ($table, $id) = @_;
+	$name_cache_time{$table} //= 0;
+	if (time - $name_cache_time{$table} > NAME_CACHE_MAX_AGE) {
+		$name_cache_time{$table} = time;
+		$name_cache{$table} = {};
+		$name_cache{$table} = $db->select($table, 'id,name')->map;
 	}
 
-	for my $cmd (qw/subscribe wait_for_messages/) {
-		dynsub uc $cmd, sub { $pubsub->$cmd(@_) };
+	$name_cache{$table}{$id}
+}
+
+
+sub add_names ($) { ## no critic (ProhibitSubroutinePrototypes)
+	my ($el) = @_;
+	if (ref $el eq 'ARRAY') {
+		&add_names ($_) for @$el ## no critic (ProhibitAmpersandSigils)
+	} else {
+		for my $object (qw/contest owner problem/) {
+			my $table = $object eq 'owner' ? 'users' : "${object}s";
+			$el->{"${object}_name"} = object_name $table, $el->{$object} if defined $el->{$object}
+		}
 	}
+
+	$el
 }
 
-sub cp { defined $contest ? "contest.$contest." : '' }
+sub user_list { +{us => scalar query('user_list_sth')->hashes} }
+
+sub user_entry {
+	my ($id) = @_;
+	my $ret = query('user_entry_sth', $id)->hash;
+	$ret->{problems} = add_names query('problem_status_sth', $id)->hashes;
+	$ret->{contests} = add_names query('contest_status_sth', $id)->hashes;
 
-sub multi				()		{ MULTI }
-sub rexec				()		{ EXEC }
+	$ret;
+}
 
-sub problems			()		{ SMEMBERS cp . 'problem' }
-sub contests			()		{ SMEMBERS cp . 'contest' }
-sub users				()		{ SMEMBERS cp . 'user' }
-sub jobcard				()		{ GET cp . 'job' }
+sub problem_list {
+	my (%args) = @_;
+	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
+	push @columns, 'solution' if $args{solution};
+	my %where;
+	$where{private} = 0 unless $args{contest} || $args{private};
+	$where{'cp.contest'} = $args{contest} if $args{contest};
+	$where{owner} = $args{owner} if $args{owner};
 
-sub job_results			(_)		{ decode_json HGET cp . "job.$_[0]", 'results' }
-sub set_job_results		($+)	{ HSET cp . "job.$_[0]", 'results', encode_json $_[1] }
-sub job_inmeta			(_)		{ decode_json HGET cp . "job.$_[0]", 'inmeta' }
-sub set_job_inmeta		($+)	{ HSET cp . "job.$_[0]", 'inmeta', encode_json $_[1] }
-sub problem_meta		(_)		{ decode_json HGET cp . "problem.$_[0]", 'meta' }
-sub set_problem_meta	($+)	{ HSET cp . "problem.$_[0]", 'meta', encode_json $_[1] }
-sub job_daemon			(_)		{ HGET cp . "job.$_[0]", 'daemon' }
-sub set_job_daemon		($$)	{ HSETNX cp . "job.$_[0]", 'daemon', $_[1] };
+	my $table = $args{contest} ? 'problems JOIN contest_problems cp ON cp.problem = id' : 'problems';
+	my $ret = add_names $db->select(\$table, \@columns, \%where, 'name')->hashes;
 
-sub defhash{
-	my ($name, @keys) = @_;
-	for my $key (@keys) {
-		dynsub "${name}_$key", sub (_)  { HGET cp . "$name.$_[0]", $key };
-		dynsub "set_${name}_$key", sub ($$) { HSET cp . "$name.$_[0]", $key, $_[1] };
+	my %params;
+	for (@$ret) {
+		$params{$_->{level}} //= [];
+		push @{$params{$_->{level}}}, $_
 	}
+	\%params
+}
 
-	dynsub "edit_$name", sub {
-		my ($key, %values) = @_;
-		HMSET cp . "$name.$key", %values;
-	};
+sub problem_entry {
+	my ($id, $contest) = @_;
+	$contest = contest_entry ($contest) if $contest;
+	my $ret = add_names query(problem_entry_sth => $id)->hash;
+	my $limits = query(limits_sth => $id)->hashes;
+	$ret->{limits} = $limits if @$limits;
 
-	dynsub "insert_$name", sub {
-		my ($key, %values) = @_;
-		SADD cp . $name, $key or return;
-		HMSET cp . "$name.$key", %values;
-	};
-	dynsub "remove_$name", sub (_) {
-		my $key = shift;
-		SREM cp . $name, $key;
-		DEL cp . "$name.$key";
-	};
+	if ($contest) {
+		$ret->{contest_start} = $contest->{start};
+		$ret->{contest_stop}  = $contest->{stop};
+		delete $ret->{solution}
+	}
 
-	dynsub "push_$name", sub {
-		my $nr = INCR cp . $name;
-		HMSET cp . "$name.$nr", @_;
-		$nr
-	};
+	$ret
 }
 
-defhash problem => qw/name level statement owner author/;
-defhash contest => qw/start end name owner/;
-defhash job => qw/date errors extension filesize private problem result result_text user/;
-defhash user => qw/name email town university level/;
+sub contest_list {
+	my $ret = add_names query('contest_list_sth')->hashes;
+
+	my %ret;
+	for (@$ret) {
+		my $state = $_->{finished} ? 'finished' : $_->{started} ? 'running' : 'pending';
+		$ret{$state} //= [];
+		push @{$ret{$state}}, $_;
+	}
 
-sub clean_job (_){
-	HDEL cp . "job.$_[0]", qw/result result_text results daemon/
+	\%ret
 }
 
-sub mark_open {
-	my ($problem, $user) = @_;
-	HSETNX cp . 'open', "$problem.$user", time;
+sub contest_entry {
+	my ($id) = @_;
+	add_names query(contest_entry_sth => $id)->hash;
 }
 
-sub get_open {
-	my ($problem, $user) = @_;
-	HGET cp . 'open', "$problem.$user";
+sub contest_full {
+	my ($id) = @_;
+	scalar query(contest_full_sth => $id)->hash;
 }
 
-our @EXPORT = do {
-	no strict 'refs';
-	grep { $_ =~ /^[a-zA-Z]/ and exists &$_ } keys %{__PACKAGE__ . '::'};
-};
+sub contest_has_problem {
+	my ($contest, $problem) = @_;
+	query('contest_has_problem_sth', $contest, $problem)->flat
+}
+
+sub job_list {
+	my (%args) = @_;
+	$args{page} //= 1;
+	my %where = (
+		maybe contest => $args{contest},
+		maybe owner => $args{owner},
+		maybe problem => $args{problem},
+		maybe result => $args{result},
+	);
+	$where{private} = 0 unless $args{private};
+
+	my $rows = $db->select('job_entry', 'COUNT(*)', \%where)->list;
+	my $pages = int (($rows + JOBS_PER_PAGE - 1) / JOBS_PER_PAGE);
+	my ($stmt, @bind) = $db->abstract->select('job_entry', '*', \%where, {-desc => 'id'});
+	my $jobs = $db->query("$stmt LIMIT " . JOBS_PER_PAGE . ' OFFSET ' . ($args{page} - 1) * JOBS_PER_PAGE, @bind)->hashes;
+	my %ret = (
+		log => add_names $jobs,
+		current_page => $args{page},
+		last_page    => $pages,
+	);
+	$ret{previous_page} = $args{page} - 1 if $args{page} - 1;
+	$ret{next_page} = $args{page} + 1 if $args{page} < $pages;
+
+	\%ret;
+}
+
+sub job_entry {
+	my ($id) = @_;
+	my $ret = add_names query(job_entry_sth => $id)->hash;
+	$ret->{results} = decode_json $ret->{results} if $ret->{results};
+	$ret
+}
+
+sub job_full {
+	my ($id) = @_;
+	scalar query(job_full_sth => $id)->hash
+}
+
+sub create_job {
+	my (%args) = @_;
+	$db->update('users', {lastjob => time});
+	purge '/log/';
+	scalar $db->insert('jobs', \%args, {returning => 'id'})->list
+}
+
+sub calc_score {
+	my ($mxscore, $time, $tries, $totaltime) = @_;
+	my $score = $mxscore;
+	$time = 300 if $time > $totaltime; # uncoverable branch true does not happen anymore (only possible if opens are broken)
+	$score = ($totaltime - $time) / $totaltime * $score;
+	$score -= $tries / 10 * $mxscore;
+	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
+	int $score + 0.5
+}
+
+sub standings {
+	my ($ct) = @_;
+	$ct = contest_entry $ct;
+
+	my @problems = query(contest_problems_sth => $ct->{id})->flat;
+	my $pblist = problem_list;
+	my %values = query('problem_values_sth')->map;
+
+	my (%scores, %tries, %opens);
+	my $opens = query(opens_sth => $ct->{id});
+	while ($opens->into(my ($problem, $owner, $time))) {
+		$opens{$problem, $owner} = $time;
+	}
+
+	my $jobs = $db->select('job_entry', '*', {contest => $ct->{id}}, 'id');
+
+	while (my $job = $jobs->hash) {
+		my $open = $opens{$job->{problem}, $job->{owner}} // $ct->{start};
+		my $time = $job->{date} - $open;
+		next if $time < 0; # uncoverable branch true job sent before contest is deprecated
+		my $value = $values{$job->{problem}};
+		my $factor = $job->{result} ? 0 : 1;
+		$factor = $1 / 100 if $job->{result_text} =~ /^(\d+ )/s;
+		$scores{$job->{owner}}{$job->{problem}} = int ($factor * calc_score ($value, $time, $tries{$job->{owner}}{$job->{problem}}++, $ct->{stop} - $ct->{start}));
+	}
+
+	my @st = sort { $b->{score} <=> $a->{score} or $a->{user} cmp $b->{user} } map { ## no critic (ProhibitReverseSortBlock)
+		my $user = $_;
+		+{
+			user => $user,
+			user_name => object_name(users => $user),
+			score => sum (values %{$scores{$user}}),
+			scores => [map { $scores{$user}{$_} // '-'} @problems],
+		}
+	} keys %scores;
+
+	$st[0]->{rank} = 1 if @st;
+	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
+	+{
+		st => \@st,
+		problems => [map { [ $_, object_name(problems => $_)] } @problems],
+	}
+}
+
+sub update_status {
+	my $jobs = $db->select('jobs', 'id,owner,problem,result', {-not_bool => 'private'}, 'id');
+
+	my %hash;
+	while ($jobs->into(my ($id, $owner, $problem, $result))) {
+		$hash{$problem, $owner} = [$id, $result ? 0 : 1];
+	}
+
+	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
+
+	my @contest_statuses = map {
+		my $ct = $_;
+		map { [$ct, $_->{user}, $_->{score}, $_->{rank}] } @{standings($ct)->{st}}
+	} $db->select('contests', 'id')->flat;
+
+	$db->begin;
+	$db->delete('problem_status');
+	$db->query('INSERT INTO problem_status (problem,owner,job,solved) VALUES (??)', @$_) for @problem_statuses;
+	$db->delete('contest_status');
+	$db->query('INSERT INTO contest_status (contest,owner,score,rank) VALUES (??)', @$_) for @contest_statuses;
+	$db->commit
+}
+
+sub rerun_job {
+	my ($id) = @_;
+	$db->query(rerun_job_sth => $id);
+	purge '/log/';
+	purge "/log/$id";
+}
+
+my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
+my $ht = HTTP::Tiny->new;
+
+sub purge {
+	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
+}
+
+1;
+
+__END__
+
+=encoding utf-8
+
+=head1 NAME
+
+Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
+
+=head1 SYNOPSIS
+
+  my $db = Gruntmaster::Data->connect('dbi:Pg:');
+
+  my $problem = $db->problem('my_problem');
+  $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
+  $problem->rerun; # And rerun all jobs for this problem
+
+  # ...
+
+  my $contest = $db->contests->create({ # Create a new contest
+    id => 'my_contest',
+    name => 'My Awesome Contest',
+    start => time + 100,
+    end => time + 1900,
+  });
+  $db->contest_problems->create({ # Add a problem to the contest
+    contest => 'my_contest',
+    problem => 'my_problem',
+  });
+
+  say 'The contest has not started yet' if $contest->is_pending;
+
+  # ...
+
+  my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
+  $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
+
+=head1 DESCRIPTION
+
+Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
+
+In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
+
+=over
+
+=item contests
+
+Equivalent to C<< $schema->resultset('Contest') >>
+
+=item contest_problems
+
+Equivalent to C<< $schema->resultset('ContestProblem') >>
+
+=item jobs
+
+Equivalent to C<< $schema->resultset('Job') >>
+
+=item problems
+
+Equivalent to C<< $schema->resultset('Problem') >>
+
+=item users
+
+Equivalent to C<< $schema->resultset('User') >>
+
+=item contest($id)
+
+Equivalent to C<< $schema->resultset('Contest')->find($id) >>
+
+=item job($id)
+
+Equivalent to C<< $schema->resultset('Job')->find($id) >>
+
+=item problem($id)
+
+Equivalent to C<< $schema->resultset('Problem')->find($id) >>
+
+=item user($id)
+
+Equivalent to C<< $schema->resultset('User')->find($id) >>
+
+=item user_list
+
+Returns a list of users as an arrayref containing hashrefs.
+
+=item user_entry($id)
+
+Returns a hashref with information about the user $id.
+
+=item problem_list([%args])
+
+Returns a list of problems grouped by level. A hashref with levels as keys.
+
+Takes the following arguments:
+
+=over
+
+=item owner
+
+Only show problems owned by this user
+
+=item contest
+
+Only show problems in this contest
+
+=back
+
+=item problem_entry($id, [$contest, $user])
+
+Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
+
+=item contest_list([%args])
+
+Returns a list of contests grouped by state. A hashref with the following keys:
+
+=over
+
+=item pending
+
+An arrayref of hashrefs representing pending contests
+
+=item running
+
+An arrayref of hashrefs representing running contests
+
+=item finished
+
+An arrayref of hashrefs representing finished contests
+
+=back
+
+Takes the following arguments:
+
+=over
+
+=item owner
+
+Only show contests owned by this user.
+
+=back
+
+=item contest_entry($id)
+
+Returns a hashref with information about the contest $id.
+
+=item job_list([%args])
+
+Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
+
+=over
+
+=item owner
+
+Only show jobs submitted by this user.
+
+=item contest
+
+Only show jobs submitted in this contest.
+
+=item problem
+
+Only show jobs submitted for this problem.
+
+=item page
+
+Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
+
+=back
+
+=item job_entry($id)
+
+Returns a hashref with information about the job $id.
+
+=back
+
+=head1 AUTHOR
+
+Marius Gavrilescu E<lt>marius@ieval.roE<gt>
+
+=head1 COPYRIGHT AND LICENSE
+
+Copyright (C) 2014 by Marius Gavrilescu
+
+This library is free software; you can redistribute it and/or modify
+it under the same terms as Perl itself, either Perl version 5.18.1 or,
+at your option, any later version of Perl 5 you may have available.
+
 
-1
+=cut