| 1 | package App::MusicExpo; |
| 2 | use v5.14; |
| 3 | use strict; |
| 4 | use warnings; |
| 5 | |
| 6 | our $VERSION = '0.005'; |
| 7 | |
| 8 | use Audio::FLAC::Header qw//; |
| 9 | use HTML::Template::Compiled qw//; |
| 10 | use Memoize qw/memoize/; |
| 11 | use MP3::Info qw/get_mp3tag/; |
| 12 | use Ogg::Vorbis::Header::PurePerl; |
| 13 | use MP4::Info qw/get_mp4tag get_mp4info/; |
| 14 | |
| 15 | use DB_File qw//; |
| 16 | use Encode qw/encode/; |
| 17 | use File::Basename qw/fileparse/; |
| 18 | use Fcntl qw/O_RDWR O_CREAT/; |
| 19 | use Getopt::Long; |
| 20 | use Storable qw/thaw freeze/; |
| 21 | |
| 22 | ################################################## |
| 23 | |
| 24 | my $default_template; |
| 25 | |
| 26 | our $prefix='/music/'; |
| 27 | our $cache=''; |
| 28 | our $template=''; |
| 29 | |
| 30 | GetOptions ( |
| 31 | "template:s" => \$template, |
| 32 | "prefix:s" => \$prefix, |
| 33 | "cache:s" => \$cache, |
| 34 | ); |
| 35 | |
| 36 | sub flacinfo{ |
| 37 | my $file=$_[0]; |
| 38 | my $flac=Audio::FLAC::Header->new($file); |
| 39 | |
| 40 | freeze +{ |
| 41 | format => 'FLAC', |
| 42 | title => $flac->tags('TITLE') // '?', |
| 43 | artist => $flac->tags('ARTIST') // '?', |
| 44 | year => $flac->tags('DATE') // '?', |
| 45 | album => $flac->tags('ALBUM') // '?', |
| 46 | tracknumber => $flac->tags('TRACKNUMBER') // '?', |
| 47 | tracktotal => $flac->tags('TRACKTOTAL') // '?', |
| 48 | genre => $flac->tags('GENRE') // '?', |
| 49 | file => scalar fileparse $file, |
| 50 | } |
| 51 | } |
| 52 | |
| 53 | sub mp3info{ |
| 54 | my $file=$_[0]; |
| 55 | my %tag = map { encode 'UTF-8', $_ } %{get_mp3tag $file}; |
| 56 | my @trkn = split '/', $tag{TRACKNUM} // ''; |
| 57 | |
| 58 | freeze +{ |
| 59 | format => 'MP3', |
| 60 | title => $tag{TITLE} || '?', |
| 61 | artist => $tag{ARTIST} || '?', |
| 62 | year => $tag{YEAR} || '?', |
| 63 | album => $tag{ALBUM} || '?', |
| 64 | tracknumber => $trkn[0] || '?', |
| 65 | tracktotal => $trkn[1] || '?', |
| 66 | genre => $tag{GENRE} || '?', |
| 67 | file => scalar fileparse $file, |
| 68 | } |
| 69 | } |
| 70 | |
| 71 | sub vorbisinfo{ |
| 72 | my $file=$_[0]; |
| 73 | my $ogg=Ogg::Vorbis::Header::PurePerl->new($file); |
| 74 | |
| 75 | freeze +{ |
| 76 | format => 'Vorbis', |
| 77 | title => $ogg->comment('TITLE') || '?', |
| 78 | artist => $ogg->comment('artist') || '?', |
| 79 | year => $ogg->comment('DATE') || '?', |
| 80 | album => $ogg->comment('ALBUM') || '?', |
| 81 | tracknumber => $ogg->comment('TRACKNUMBER') || '?', |
| 82 | tracktotal => $ogg->comment('TRACKTOTAL') || '?', |
| 83 | genre => $ogg->comment('GENRE') || '?', |
| 84 | file => scalar fileparse $file, |
| 85 | } |
| 86 | } |
| 87 | |
| 88 | sub mp4_format ($){ |
| 89 | my $encoding = $_[0]; |
| 90 | return 'AAC' if $encoding eq 'mp4a'; |
| 91 | return 'ALAC' if $encoding eq 'alac'; |
| 92 | "MP4-$encoding" |
| 93 | } |
| 94 | |
| 95 | sub mp4info{ |
| 96 | my $file=$_[0]; |
| 97 | my %tag = map { ref() ? $_ : encode 'UTF-8', $_ } %{get_mp4tag $file}; |
| 98 | my %info = %{get_mp4info $file}; |
| 99 | |
| 100 | freeze +{ |
| 101 | format => mp4_format $info{ENCODING}, |
| 102 | title => $tag{TITLE} || '?', |
| 103 | artist => $tag{ARTIST} || '?', |
| 104 | year => $tag{YEAR} || '?', |
| 105 | album => $tag{ALBUM} || '?', |
| 106 | tracknumber => $tag{TRACKNUM} || '?', |
| 107 | tracktotal => ($tag{TRKN} ? $tag{TRKN}->[1] : undef) || '?', |
| 108 | genre => $tag{GENRE} || '?', |
| 109 | file => scalar fileparse $file, |
| 110 | }; |
| 111 | } |
| 112 | |
| 113 | my %info = ( |
| 114 | '.flac' => \&flacinfo, |
| 115 | '.mp3' => \&mp3info, |
| 116 | '.ogg' => \&vorbisinfo, |
| 117 | '.oga' => \&vorbisinfo, |
| 118 | '.mp4' => \&mp4info, |
| 119 | '.aac' => \&mp4info, |
| 120 | '.m4a' => \&mp4info, |
| 121 | ); |
| 122 | |
| 123 | sub normalizer{ |
| 124 | "$_[0]|".(stat $_[0])[9] |
| 125 | } |
| 126 | |
| 127 | sub make_fragment{ join '-', map { lc =~ y/a-z0-9/_/csr } @_ } |
| 128 | |
| 129 | sub run { |
| 130 | my %info = %info; |
| 131 | if ($cache) { |
| 132 | tie my %cache, 'DB_File', $cache, O_RDWR|O_CREAT, 0644; |
| 133 | $info{$_} = memoize $info{$_}, INSTALL => undef, NORMALIZER => \&normalizer, LIST_CACHE => 'FAULT', SCALAR_CACHE => [HASH => \%cache] for keys %info; |
| 134 | } |
| 135 | |
| 136 | my %files; |
| 137 | for my $file (@ARGV) { |
| 138 | my ($basename, undef, $suffix) = fileparse $file, keys %info; |
| 139 | $files{$basename} //= []; |
| 140 | push @{$files{$basename}}, thaw scalar $info{$suffix}->($file); |
| 141 | } |
| 142 | |
| 143 | my $ht=HTML::Template::Compiled->new( |
| 144 | default_escape => 'HTML', |
| 145 | global_vars => 2, |
| 146 | $template eq '' ? (scalarref => \$default_template) : (filename => $template), |
| 147 | ); |
| 148 | |
| 149 | my @files; |
| 150 | for (values %files) { |
| 151 | my @versions = @$_; |
| 152 | my %entry = (%{$versions[0]}, formats => []); |
| 153 | for my $ver (@versions) { |
| 154 | push @{$entry{formats}}, {format => $ver->{format}, file => $ver->{file}}; |
| 155 | for my $key (keys %$ver) { |
| 156 | $entry{$key} = $ver->{$key} if $ver->{$key} ne '?'; |
| 157 | } |
| 158 | } |
| 159 | delete $entry{$_} for qw/format file/; |
| 160 | $entry{fragment} = make_fragment @entry{qw/artist title/}; |
| 161 | push @files, \%entry |
| 162 | } |
| 163 | |
| 164 | @files = sort { $a->{title} cmp $b->{title} } @files; |
| 165 | $ht->param(files => \@files, prefix => $prefix); |
| 166 | print $ht->output; |
| 167 | } |
| 168 | |
| 169 | $default_template = <<'HTML'; |
| 170 | <!DOCTYPE html> |
| 171 | <title>Music</title> |
| 172 | <meta charset="utf-8"> |
| 173 | <link rel="stylesheet" href="musicexpo.css"> |
| 174 | <script async defer type="application/javascript" src="player.js"></script> |
| 175 | |
| 176 | <div id="player"></div> |
| 177 | |
| 178 | <table border> |
| 179 | <thead> |
| 180 | <tr><th>Title<th>Artist<th>Album<th>Genre<th>Track<th>Year<th>Type |
| 181 | <tbody><tmpl_loop files> |
| 182 | <tr><td class="title"><a href="#<tmpl_var fragment>" data-hash="#<tmpl_var fragment>"><tmpl_var title></a><td class="artist"><tmpl_var artist><td class="album"><tmpl_var album><td class="genre"><tmpl_var genre><td class="track"><tmpl_var tracknumber>/<tmpl_var tracktotal><td class="year"><tmpl_var year><td class="formats"><tmpl_loop formats><a href="<tmpl_var ...prefix><tmpl_var ESCAPE=URL file>"><tmpl_var format></a> </tmpl_loop></tmpl_loop> |
| 183 | </table> |
| 184 | HTML |
| 185 | |
| 186 | 1; |
| 187 | |
| 188 | __END__ |
| 189 | |
| 190 | =encoding utf-8 |
| 191 | |
| 192 | =head1 NAME |
| 193 | |
| 194 | App::MusicExpo - script which generates a HTML table of music tags |
| 195 | |
| 196 | =head1 SYNOPSIS |
| 197 | |
| 198 | use App::MusicExpo; |
| 199 | App::MusicExpo->run; |
| 200 | |
| 201 | =head1 DESCRIPTION |
| 202 | |
| 203 | App::MusicExpo creates a HTML table from a list of songs. |
| 204 | |
| 205 | The default template looks like: |
| 206 | |
| 207 | | Title | Artist | Album | Genre | Track | Year | Type | |
| 208 | |---------+---------+-----------------+---------+-------+------+------| |
| 209 | | Cellule | Silence | L'autre endroit | Electro | 01/09 | 2005 | FLAC | |
| 210 | |
| 211 | where the type is a download link. If you have multiple files with the same |
| 212 | basename (such as C<cellule.flac> and C<cellule.ogg>), they will be treated |
| 213 | as two versions of the same file, so a row will be created with two download |
| 214 | links, one for each format. |
| 215 | |
| 216 | =head1 OPTIONS |
| 217 | |
| 218 | =over |
| 219 | |
| 220 | =item B<--template> I<template> |
| 221 | |
| 222 | Path to the HTML::Template::Compiled template used for generating the music table. If '' (empty), uses the default format. Is empty by default. |
| 223 | |
| 224 | =item B<--prefix> I<prefix> |
| 225 | |
| 226 | Prefix for download links. Defaults to '/music/'. |
| 227 | |
| 228 | =item B<--cache> I<filename> |
| 229 | |
| 230 | Path to the cache file. Created if it does not exist. If '' (empty), disables caching. Is empty by default. |
| 231 | |
| 232 | =back |
| 233 | |
| 234 | =head1 AUTHOR |
| 235 | |
| 236 | Marius Gavrilescu, E<lt>marius@ieval.roE<gt> |
| 237 | |
| 238 | =head1 COPYRIGHT AND LICENSE |
| 239 | |
| 240 | Copyright (C) 2013-2015 by Marius Gavrilescu |
| 241 | |
| 242 | This library is free software; you can redistribute it and/or modify |
| 243 | it under the same terms as Perl itself, either Perl version 5.14.2 or, |
| 244 | at your option, any later version of Perl 5 you may have available. |