[app-musicexpo.git] / lib / App / MusicExpo.pm

package App::MusicExpo;
use v5.14;
use strict;
use warnings;

our $VERSION = '0.006';

use Audio::FLAC::Header qw//;
use HTML::Template::Compiled qw//;
use Memoize qw/memoize/;
use MP3::Info qw/get_mp3tag/;
use Ogg::Vorbis::Header::PurePerl;
use MP4::Info qw/get_mp4tag get_mp4info/;

use DB_File qw//;
use Encode qw/encode/;
use File::Basename qw/fileparse/;
use Fcntl qw/O_RDWR O_CREAT/;
use Getopt::Long;
use Storable qw/thaw freeze/;
use sort 'stable';

##################################################

my $default_template;

our $prefix='/music/';
our $cache='';
our $template='';

GetOptions (
	"template:s" => \$template,
	"prefix:s" => \$prefix,
	"cache:s" => \$cache,
);

sub flacinfo{
	my $file=$_[0];
	my $flac=Audio::FLAC::Header->new($file);

	freeze +{
		format => 'FLAC',
		title => $flac->tags('TITLE'),
		artist => $flac->tags('ARTIST'),
		year => $flac->tags('DATE'),
		album => $flac->tags('ALBUM'),
		tracknumber => $flac->tags('TRACKNUMBER'),
		tracktotal => $flac->tags('TRACKTOTAL'),
		genre => $flac->tags('GENRE'),
		file => scalar fileparse $file,
	}
}

sub mp3info{
	my $file=$_[0];
	my %tag = map { encode 'UTF-8', $_ } %{get_mp3tag $file};
	my @trkn = split '/', $tag{TRACKNUM} // '';

	freeze +{
		format => 'MP3',
		title => $tag{TITLE},
		artist => $tag{ARTIST},
		year => $tag{YEAR},
		album => $tag{ALBUM},
		tracknumber => $trkn[0],
		tracktotal => $trkn[1],
		genre => $tag{GENRE},
		file => scalar fileparse $file,
	}
}

sub vorbisinfo{
	my $file=$_[0];
	my $ogg=Ogg::Vorbis::Header::PurePerl->new($file);

	freeze +{
		format => 'Vorbis',
		title => scalar $ogg->comment('TITLE'),
		artist => scalar $ogg->comment('artist'),
		year => scalar $ogg->comment('DATE'),
		album => scalar $ogg->comment('ALBUM'),
		tracknumber => scalar $ogg->comment('TRACKNUMBER'),
		tracktotal => scalar $ogg->comment('TRACKTOTAL'),
		genre => scalar $ogg->comment('GENRE'),
		file => scalar fileparse $file,
	}
}

sub mp4_format ($){
	my $encoding = $_[0];
	return 'AAC' if $encoding eq 'mp4a';
	return 'ALAC' if $encoding eq 'alac';
	"MP4-$encoding"
}

sub mp4info{
	my $file=$_[0];
	my %tag = map { ref() ? $_ : encode 'UTF-8', $_ } %{get_mp4tag $file};
	my %info = %{get_mp4info $file};

	freeze +{
		format => mp4_format $info{ENCODING},
		title => $tag{TITLE},
		artist => $tag{ARTIST},
		year => $tag{YEAR},
		album => $tag{ALBUM},
		tracknumber => $tag{TRACKNUM},
		tracktotal => ($tag{TRKN} ? $tag{TRKN}->[1] : undef),
		genre => $tag{GENRE},
		file => scalar fileparse $file,
	};
}

my %info = (
	'.flac' => \&flacinfo,
	'.mp3' => \&mp3info,
	'.ogg' => \&vorbisinfo,
	'.oga' => \&vorbisinfo,
	'.mp4' => \&mp4info,
	'.aac' => \&mp4info,
	'.m4a' => \&mp4info,
);

sub normalizer{
	"$_[0]|".(stat $_[0])[9]
}

sub make_fragment{ join '-', map { lc =~ y/a-z0-9/_/csr } @_ }

sub run {
	my %info = %info;
	if ($cache) {
		tie my %cache, 'DB_File', $cache, O_RDWR|O_CREAT, 0644;
		$info{$_} = memoize $info{$_}, INSTALL => undef, NORMALIZER => \&normalizer, LIST_CACHE => 'FAULT', SCALAR_CACHE => [HASH => \%cache] for keys %info;
	}

	my %files;
	for my $file (@ARGV) {
		my ($basename, undef, $suffix) = fileparse $file, keys %info;
		$files{$basename} //= [];
		push @{$files{$basename}}, thaw scalar $info{$suffix}->($file);
	}

	my $ht=HTML::Template::Compiled->new(
		default_escape => 'HTML',
		global_vars => 2,
		$template eq '' ? (scalarref => \$default_template) : (filename => $template),
	);

	my @files;
	for (sort keys %files) {
		my @versions = @{$files{$_}};
		my %entry = (formats => [], map { $_ => '?' } qw/title artist year album tracknumber tracktotal genre/);
		for my $ver (@versions) {
			push @{$entry{formats}}, {format => $ver->{format}, file => $ver->{file}};
			for my $key (keys %$ver) {
				$entry{$key} = $ver->{$key} if $ver->{$key} && $ver->{$key} ne '?';
			}
		}
		delete $entry{$_} for qw/format file/;
		$entry{fragment} = make_fragment @entry{qw/artist title/};
		push @files, \%entry
	}

	@files = sort { $a->{title} cmp $b->{title} } @files;
	$ht->param(files => \@files, prefix => $prefix);
	print $ht->output;
}

$default_template = <<'HTML';
<!DOCTYPE html>
<title>Music</title>
<meta charset="utf-8">
<link rel="stylesheet" href="musicexpo.css">
<script async defer type="application/javascript" src="player.js"></script>

<div id="player"></div>

<table border>
<thead>
<tr><th>Title<th>Artist<th>Album<th>Genre<th>Track<th>Year<th>Type
<tbody><tmpl_loop files>
<tr><td class="title"><a href="#<tmpl_var fragment>" data-hash="#<tmpl_var fragment>"><tmpl_var title></a><td class="artist"><tmpl_var artist><td class="album"><tmpl_var album><td class="genre"><tmpl_var genre><td class="track"><tmpl_var tracknumber>/<tmpl_var tracktotal><td class="year"><tmpl_var year><td class="formats"><tmpl_loop formats><a href="<tmpl_var ...prefix><tmpl_var ESCAPE=URL file>"><tmpl_var format></a> </tmpl_loop></tmpl_loop>
</table>
HTML

1;

__END__

=encoding utf-8

=head1 NAME

App::MusicExpo - script which generates a HTML table of music tags

=head1 SYNOPSIS

  use App::MusicExpo;
  App::MusicExpo->run;

=head1 DESCRIPTION

App::MusicExpo creates a HTML table from a list of songs.

The default template looks like:

    | Title   | Artist  | Album           | Genre   | Track | Year | Type |
    |---------+---------+-----------------+---------+-------+------+------|
    | Cellule | Silence | L'autre endroit | Electro | 01/09 | 2005 | FLAC |

where the type is a download link. If you have multiple files with the same
basename (such as C<cellule.flac> and C<cellule.ogg>), they will be treated
as two versions of the same file, so a row will be created with two download
links, one for each format.

=head1 OPTIONS

=over

=item B<--template> I<template>

Path to the HTML::Template::Compiled template used for generating the music table. If '' (empty), uses the default format. Is empty by default.

=item B<--prefix> I<prefix>

Prefix for download links. Defaults to '/music/'.

=item B<--cache> I<filename>

Path to the cache file. Created if it does not exist. If '' (empty), disables caching. Is empty by default.

=back

=head1 AUTHOR

Marius Gavrilescu, E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2013-2015 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.14.2 or,
at your option, any later version of Perl 5 you may have available.
Commit	Line	Data
	1	package App::MusicExpo;
	2	use v5.14;
	3	use strict;
	4	use warnings;
	5
	6	our $VERSION = '0.006';
	7
	8	use Audio::FLAC::Header qw//;
	9	use HTML::Template::Compiled qw//;
	10	use Memoize qw/memoize/;
	11	use MP3::Info qw/get_mp3tag/;
	12	use Ogg::Vorbis::Header::PurePerl;
	13	use MP4::Info qw/get_mp4tag get_mp4info/;
	14
	15	use DB_File qw//;
	16	use Encode qw/encode/;
	17	use File::Basename qw/fileparse/;
	18	use Fcntl qw/O_RDWR O_CREAT/;
	19	use Getopt::Long;
	20	use Storable qw/thaw freeze/;
	21	use sort 'stable';
	22
	23	##################################################
	24
	25	my $default_template;
	26
	27	our $prefix='/music/';
	28	our $cache='';
	29	our $template='';
	30
	31	GetOptions (
	32	"template:s" => \$template,
	33	"prefix:s" => \$prefix,
	34	"cache:s" => \$cache,
	35	);
	36
	37	sub flacinfo{
	38	my $file=$_[0];
	39	my $flac=Audio::FLAC::Header->new($file);
	40
	41	freeze +{
	42	format => 'FLAC',
	43	title => $flac->tags('TITLE'),
	44	artist => $flac->tags('ARTIST'),
	45	year => $flac->tags('DATE'),
	46	album => $flac->tags('ALBUM'),
	47	tracknumber => $flac->tags('TRACKNUMBER'),
	48	tracktotal => $flac->tags('TRACKTOTAL'),
	49	genre => $flac->tags('GENRE'),
	50	file => scalar fileparse $file,
	51	}
	52	}
	53
	54	sub mp3info{
	55	my $file=$_[0];
	56	my %tag = map { encode 'UTF-8', $_ } %{get_mp3tag $file};
	57	my @trkn = split '/', $tag{TRACKNUM} // '';
	58
	59	freeze +{
	60	format => 'MP3',
	61	title => $tag{TITLE},
	62	artist => $tag{ARTIST},
	63	year => $tag{YEAR},
	64	album => $tag{ALBUM},
	65	tracknumber => $trkn[0],
	66	tracktotal => $trkn[1],
	67	genre => $tag{GENRE},
	68	file => scalar fileparse $file,
	69	}
	70	}
	71
	72	sub vorbisinfo{
	73	my $file=$_[0];
	74	my $ogg=Ogg::Vorbis::Header::PurePerl->new($file);
	75
	76	freeze +{
	77	format => 'Vorbis',
	78	title => scalar $ogg->comment('TITLE'),
	79	artist => scalar $ogg->comment('artist'),
	80	year => scalar $ogg->comment('DATE'),
	81	album => scalar $ogg->comment('ALBUM'),
	82	tracknumber => scalar $ogg->comment('TRACKNUMBER'),
	83	tracktotal => scalar $ogg->comment('TRACKTOTAL'),
	84	genre => scalar $ogg->comment('GENRE'),
	85	file => scalar fileparse $file,
	86	}
	87	}
	88
	89	sub mp4_format ($){
	90	my $encoding = $_[0];
	91	return 'AAC' if $encoding eq 'mp4a';
	92	return 'ALAC' if $encoding eq 'alac';
	93	"MP4-$encoding"
	94	}
	95
	96	sub mp4info{
	97	my $file=$_[0];
	98	my %tag = map { ref() ? $_ : encode 'UTF-8', $_ } %{get_mp4tag $file};
	99	my %info = %{get_mp4info $file};
	100
	101	freeze +{
	102	format => mp4_format $info{ENCODING},
	103	title => $tag{TITLE},
	104	artist => $tag{ARTIST},
	105	year => $tag{YEAR},
	106	album => $tag{ALBUM},
	107	tracknumber => $tag{TRACKNUM},
	108	tracktotal => ($tag{TRKN} ? $tag{TRKN}->[1] : undef),
	109	genre => $tag{GENRE},
	110	file => scalar fileparse $file,
	111	};
	112	}
	113
	114	my %info = (
	115	'.flac' => \&flacinfo,
	116	'.mp3' => \&mp3info,
	117	'.ogg' => \&vorbisinfo,
	118	'.oga' => \&vorbisinfo,
	119	'.mp4' => \&mp4info,
	120	'.aac' => \&mp4info,
	121	'.m4a' => \&mp4info,
	122	);
	123
	124	sub normalizer{
	125	"$_[0]\|".(stat $_[0])[9]
	126	}
	127
	128	sub make_fragment{ join '-', map { lc =~ y/a-z0-9/_/csr } @_ }
	129
	130	sub run {
	131	my %info = %info;
	132	if ($cache) {
	133	tie my %cache, 'DB_File', $cache, O_RDWR\|O_CREAT, 0644;
	134	$info{$_} = memoize $info{$_}, INSTALL => undef, NORMALIZER => \&normalizer, LIST_CACHE => 'FAULT', SCALAR_CACHE => [HASH => \%cache] for keys %info;
	135	}
	136
	137	my %files;
	138	for my $file (@ARGV) {
	139	my ($basename, undef, $suffix) = fileparse $file, keys %info;
	140	$files{$basename} //= [];
	141	push @{$files{$basename}}, thaw scalar $info{$suffix}->($file);
	142	}
	143
	144	my $ht=HTML::Template::Compiled->new(
	145	default_escape => 'HTML',
	146	global_vars => 2,
	147	$template eq '' ? (scalarref => \$default_template) : (filename => $template),
	148	);
	149
	150	my @files;
	151	for (sort keys %files) {
	152	my @versions = @{$files{$_}};
	153	my %entry = (formats => [], map { $_ => '?' } qw/title artist year album tracknumber tracktotal genre/);
	154	for my $ver (@versions) {
	155	push @{$entry{formats}}, {format => $ver->{format}, file => $ver->{file}};
	156	for my $key (keys %$ver) {
	157	$entry{$key} = $ver->{$key} if $ver->{$key} && $ver->{$key} ne '?';
	158	}
	159	}
	160	delete $entry{$_} for qw/format file/;
	161	$entry{fragment} = make_fragment @entry{qw/artist title/};
	162	push @files, \%entry
	163	}
	164
	165	@files = sort { $a->{title} cmp $b->{title} } @files;
	166	$ht->param(files => \@files, prefix => $prefix);
	167	print $ht->output;
	168	}
	169
	170	$default_template = <<'HTML';
	171	<!DOCTYPE html>
	172	<title>Music</title>
	173	<meta charset="utf-8">
	174	<link rel="stylesheet" href="musicexpo.css">
	175	<script async defer type="application/javascript" src="player.js"></script>
	176
	177	<div id="player"></div>
	178
	179	<table border>
	180	<thead>
	181	<tr><th>Title<th>Artist<th>Album<th>Genre<th>Track<th>Year<th>Type
	182	<tbody><tmpl_loop files>
	183	<tr><td class="title"><a href="#<tmpl_var fragment>" data-hash="#<tmpl_var fragment>"><tmpl_var title></a><td class="artist"><tmpl_var artist><td class="album"><tmpl_var album><td class="genre"><tmpl_var genre><td class="track"><tmpl_var tracknumber>/<tmpl_var tracktotal><td class="year"><tmpl_var year><td class="formats"><tmpl_loop formats><a href="<tmpl_var ...prefix><tmpl_var ESCAPE=URL file>"><tmpl_var format></a> </tmpl_loop></tmpl_loop>
	184	</table>
	185	HTML
	186
	187	1;
	188
	189	__END__
	190
	191	=encoding utf-8
	192
	193	=head1 NAME
	194
	195	App::MusicExpo - script which generates a HTML table of music tags
	196
	197	=head1 SYNOPSIS
	198
	199	use App::MusicExpo;
	200	App::MusicExpo->run;
	201
	202	=head1 DESCRIPTION
	203
	204	App::MusicExpo creates a HTML table from a list of songs.
	205
	206	The default template looks like:
	207
	208	\| Title \| Artist \| Album \| Genre \| Track \| Year \| Type \|
	209	\|---------+---------+-----------------+---------+-------+------+------\|
	210	\| Cellule \| Silence \| L'autre endroit \| Electro \| 01/09 \| 2005 \| FLAC \|
	211
	212	where the type is a download link. If you have multiple files with the same
	213	basename (such as C<cellule.flac> and C<cellule.ogg>), they will be treated
	214	as two versions of the same file, so a row will be created with two download
	215	links, one for each format.
	216
	217	=head1 OPTIONS
	218
	219	=over
	220
	221	=item B<--template> I<template>
	222
	223	Path to the HTML::Template::Compiled template used for generating the music table. If '' (empty), uses the default format. Is empty by default.
	224
	225	=item B<--prefix> I<prefix>
	226
	227	Prefix for download links. Defaults to '/music/'.
	228
	229	=item B<--cache> I<filename>
	230
	231	Path to the cache file. Created if it does not exist. If '' (empty), disables caching. Is empty by default.
	232
	233	=back
	234
	235	=head1 AUTHOR
	236
	237	Marius Gavrilescu, E<lt>marius@ieval.roE<gt>
	238
	239	=head1 COPYRIGHT AND LICENSE
	240
	241	Copyright (C) 2013-2015 by Marius Gavrilescu
	242
	243	This library is free software; you can redistribute it and/or modify
	244	it under the same terms as Perl itself, either Perl version 5.14.2 or,
	245	at your option, any later version of Perl 5 you may have available.