[app-scheme79asm.git] / lib / App / Scheme79asm.pm

package App::Scheme79asm;

use 5.014000;
use strict;
use warnings;

use Data::Dumper qw/Dumper/;
use Data::SExpression qw/consp scalarp/;
use Scalar::Util qw/looks_like_number/;

our $VERSION = '0.004';

our %TYPES = (
	LIST => 0,
	SYMBOL => 1,
	NUMBER => 1,
	VAR => 2,
	VARIABLE => 2,
	CLOSURE => 3,
	PROC => 4,
	PROCEDURE => 4,
	IF => 5,
	COND => 5,
	CONDITIONAL => 5,
	CALL => 6,
	QUOTE => 7,
	QUOTED => 7,

	MORE => 0,
	CAR => 1,
	CDR => 2,
	CONS => 3,
	ATOM => 4,
	PROGN => 5,
	'REVERSE-LIST' => 6,
	FUNCALL => 7,
);

*consp = *Data::SExpression::consp;
*scalarp = *Data::SExpression::scalarp;

sub process {
	my ($self, $sexp, $location) = @_;
	die 'Toplevel is not a list: ', Dumper($sexp), "\n" unless ref $sexp eq 'ARRAY';
	my ($type, @addrs) = @$sexp;
	my $addr;

	die 'Type of toplevel is not atom: '. Dumper($type), "\n" unless scalarp($type);

	if (@addrs > 1) {
		$addr = $self->{freeptr} + 1;
		$self->{freeptr} += @addrs;
		$self->process($addrs[$_], $addr + $_) for 0 .. $#addrs;
	} else {
		$addr = $addrs[0];
	}

	$addr = $self->process($addr) if ref $addr eq 'ARRAY';
	die 'Addr of toplevel is not atom: ', Dumper($addr), "\n" unless scalarp($addr);
	my ($comment_type, $comment_addr) = ($type, $addr);
	die 'Computed addr is not a number: ', Dumper($addr), "\n" unless looks_like_number $addr;

	if (!looks_like_number $type) {
		die "No such type: $type\n" unless exists $TYPES{$type};
		$type = $TYPES{$type};
	}

	$addr += (1 << $self->{addr_bits}) if $addr < 0;
	die "Type too large: $type\n" unless $type < (1 << $self->{type_bits});
	die "Addr too large: $addr\n" unless $addr < (1 << $self->{addr_bits});
	my $result = ($type << $self->{addr_bits}) + $addr;
	unless ($location) {
		$self->{freeptr}++;
		$location = $self->{freeptr}
	}
	$self->{memory}[$location] = $result;
	$self->{comment}[$location] = "$comment_type $comment_addr";
	$location
}

sub parse {
	my ($self, $string) = @_;
	my $ds = Data::SExpression->new({symbol_case => 'up', use_symbol_class => 1, fold_lists => 1});

	my $sexp;
	while () {
		last if $string =~ /^\s*$/;
		($sexp, $string) = $ds->read($string);
		$self->process($sexp)
	}
}

sub finish {
	my ($self) = @_;
	$self->{memory}[5] = $self->{memory}[$self->{freeptr}];
	$self->{comment}[5] = $self->{comment}[$self->{freeptr}];
	$self->{memory}[4] = $self->{freeptr};
	delete $self->{memory}[$self->{freeptr}]
}

sub new {
	my ($class, %args) = @_;
	$args{type_bits} //= 3;
	$args{addr_bits} //= 8;
	$args{freeptr} //= 6;
	$args{memory} //= [0, 0, (1<<$args{addr_bits}), (1<<$args{addr_bits}), 0, 0, 0];
	$args{comment} = ['(cdr part of NIL)', '(car part of NIL)', '(cdr part of T)', '(car part of T)', '(free storage pointer)', '', '(result of computation)'];
	bless \%args, $class
}

sub print_binary16 {
	my ($self, $fh) = @_;
	$fh //= \*STDOUT; # uncoverable condition right

	die "addr_bits + type_bits >= 16\n"if $self->{addr_bits} + $self->{type_bits} > 16;

	my $length = @{$self->{memory}};
	print $fh pack('n', $length);
	for (@{$self->{memory}}) {
		print $fh pack('n', $_)
	}
}

sub print_verilog {
	my ($self, $fh) = @_;
	$fh //= \*STDOUT; # uncoverable condition right

	my $bits = $self->{type_bits} + $self->{addr_bits};
	my $index_length = length $#{$self->{memory}};
	my $index_format = '%' . $index_length . 'd';
	for my $index (0 .. $#{$self->{memory}}) {
		my $val = $self->{memory}[$index];
		my $comment = $self->{comment}[$index];
		if ($index == 4) {
			$val = "${bits}'d$val"
		} else {
			$val = $val ? sprintf "%d'b%0${bits}b", $bits, $val : '0';
		}
		my $spaces = ' ' x ($bits + 5 - (length $val));
		$index = sprintf $index_format, $index;

		print $fh "mem[$index] <= $val;";
		print $fh "$spaces // $comment" if defined $comment;
		print $fh "\n";
	}

}
sub parse_and_print_binary16 {
	my ($self, $string, $fh) = @_;
	$self->parse($string);
	$self->finish;
	$self->print_binary16($fh);
}

sub parse_and_print_verilog {
	my ($self, $string, $fh) = @_;
	$self->parse($string);
	$self->finish;
	$self->print_verilog($fh);
}

1;
__END__

=encoding utf-8

=head1 NAME

App::Scheme79asm - assemble sexp to Verilog ROM for SIMPLE processor

=head1 SYNOPSIS

  use App::Scheme79asm;
  my $asm = App::Scheme79asm->new(type_bits => 3, addr_bits => 5);
  $asm->parse_and_print_verilog('(number 70)');

=head1 DESCRIPTION

SIMPLE is a LISP processor defined in the 1979
B<Design of LISP-Based Processors> paper by Steele and Sussman.

The SIMPLE processor expects input in a particular tagged-pointer
format. This module takes a string containing a sequence of
S-expressions. Each S-expression is a list of one of three types:

C<(tag value)>, for example C<(symbol 2)>, represents a value to be
put in memory (for example a number, or a symbol, or a variable
reference).

C<(tag list)>, where C<list> is of one of these three types,
represents a tagged pointer. In this case, C<list> is (recursively)
laid out in memory as per these rules, and a pointer to that location
(and tagged C<tag>) is put somewhere in memory.

C<(tag list1 list2)>, where C<list1> and C<list2> are of one of these
three types (not necessarily the same type). In this case, C<list1>
and C<list2> are (recursively) laid out in memory such that C<list1>
is at position X and C<list2> is at position X+1, and a pointer of
type tag and value X is put somewhere in memory.

After this process the very last pointer placed in memory is moved to
the special location 5 (which is where SIMPLE expects to find the
expression to be evaluated).

In normal use a single S-expression will be supplied, representing an
entire program.

The C<tag> is either a number, a type, or a primitive.
The available types are:

=over

=item LIST

=item SYMBOL (syn. NUMBER)

=item VAR (syn. VARIABLE)

=item CLOSURE

=item PROC (syn. PROCEDURE)

=item IF (syn. COND, CONDITIONAL)

=item CALL

=item QUOTE (syn. QUOTED)

=back

The available primitives are:

=over

=item MORE

=item CAR

=item CDR

=item CONS

=item ATOM

=item PROGN

=item REVERSE-LIST

=item FUNCALL

=back

The following methods are available:

=over

=item App::Scheme79asm->B<new>([key => value, key => value, ...])

Create a new assembler object. Takes a list of keys and values, here
are the possible keys:

=over

=item type_bits

=item address_bits

A word is made of a type and an address, with the type occupying the
most significant C<type_bits> (default 3) bits, and the address
occupying the least significant C<address_bits> (default 8) bits.
Therefore the word size is C<type_bits + address_bits> (default 13).

=item freeptr

A pointer to the last used byte in memory (default 6). The program
will be laid out starting with location C<freeptr + 1>.

=item memory

The initial contents of the memory. Note that locations 4, 5, 6 will
be overwritten, as will every location larger than the value of
C<freeptr>.

=item comment

The initial comments for memory entries. C<< $comment->[$i] >> is the
comment for C<< $memory->[$i] >>.

=back

=item $asm->B<parse>(I<$string>)

Parse a sequence of S-expressions and lay it out in memory.
Can be called multiple times to lay out multiple sequences of
S-expressions one after another.

=item $asm->B<process>(I<$sexp>)

Given an already-parsed sexp (meaning a
L<Data::SExpression> object), lay it out in memory.
Can be called multiple times to lay out multiple sequences of
S-expressions one after another.

=item $asm->B<finish>

Move the last pointer to position 5, and put the free pointer at
position 4. After all sequences of S-expressions have been given to
B<parse>, this method should be called.

=item $asm->B<print_binary16>([I<$fh>])

Print the length of the memory (as a big-endian 16-bit value),
followed by the memory contents as a sequence of big-endian 16-bit
values to the given filehandle (default STDOUT). Dies if
C<addr_bits + type_bits> is more than 16.

Big-endian 16-bit values can be decoded with C<unpack 'n', $value>.

=item $asm->B<print_verilog>([I<$fh>])

Print a block of Verilog code assigning the memory contents to an
array named C<mem> to the given filehandle (default STDOUT).

=item $asm->B<parse_and_print_binary16>(I<$string>[, I<$fh>])

Convenience method that calls B<parse>($string), B<finish>, and then
B<print_binary16>($fh).

=item $asm->B<parse_and_print_verilog>(I<$string>[, I<$fh>])

Convenience method that calls B<parse>($string), B<finish>, and then
B<print_verilog>($fh).

=back

=head1 SEE ALSO

L<http://repository.readscheme.org/ftp/papers/ai-lab-pubs/AIM-514.pdf>

=head1 AUTHOR

Marius Gavrilescu, E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2018 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.24.3 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
509643aa MG	1	package App::Scheme79asm;
	2
	3	use 5.014000;
	4	use strict;
	5	use warnings;
	6
4a9c3fa9	7	use Data::Dumper qw/Dumper/;
509643aa MG	8	use Data::SExpression qw/consp scalarp/;
	9	use Scalar::Util qw/looks_like_number/;
	10
3fff77b7	11	our $VERSION = '0.004';
509643aa MG	12
	13	our %TYPES = (
	14	LIST => 0,
	15	SYMBOL => 1,
4a9c3fa9	16	NUMBER => 1,
509643aa MG	17	VAR => 2,
	18	VARIABLE => 2,
	19	CLOSURE => 3,
	20	PROC => 4,
	21	PROCEDURE => 4,
4a9c3fa9	22	IF => 5,
509643aa MG	23	COND => 5,
	24	CONDITIONAL => 5,
	25	CALL => 6,
509643aa MG	26	QUOTE => 7,
509643aa MG	27	QUOTED => 7,
4a9c3fa9 MG	28
	29	MORE => 0,
	30	CAR => 1,
	31	CDR => 2,
	32	CONS => 3,
	33	ATOM => 4,
	34	PROGN => 5,
f0289d3d	35	'REVERSE-LIST' => 6,
4a9c3fa9	36	FUNCALL => 7,
509643aa MG	37	);
	38
	39	consp = Data::SExpression::consp;
	40	scalarp = Data::SExpression::scalarp;
	41
	42	sub process {
4a9c3fa9 MG	43	my ($self, $sexp, $location) = @_;
	44	die 'Toplevel is not a list: ', Dumper($sexp), "\n" unless ref $sexp eq 'ARRAY';
	45	my ($type, @addrs) = @$sexp;
	46	my $addr;
	47
	48	die 'Type of toplevel is not atom: '. Dumper($type), "\n" unless scalarp($type);
	49
	50	if (@addrs > 1) {
	51	$addr = $self->{freeptr} + 1;
	52	$self->{freeptr} += @addrs;
	53	$self->process($addrs[$_], $addr + $_) for 0 .. $#addrs;
	54	} else {
	55	$addr = $addrs[0];
	56	}
	57
	58	$addr = $self->process($addr) if ref $addr eq 'ARRAY';
	59	die 'Addr of toplevel is not atom: ', Dumper($addr), "\n" unless scalarp($addr);
34073a4a	60	my ($comment_type, $comment_addr) = ($type, $addr);
4a9c3fa9	61	die 'Computed addr is not a number: ', Dumper($addr), "\n" unless looks_like_number $addr;
509643aa	62
ab8f838f	63	if (!looks_like_number $type) {
509643aa MG	64	die "No such type: $type\n" unless exists $TYPES{$type};
509643aa MG	65	$type = $TYPES{$type};
509643aa MG	66	}
509643aa MG	67
f0289d3d	68	$addr += (1 << $self->{addr_bits}) if $addr < 0;
509643aa MG	69	die "Type too large: $type\n" unless $type < (1 << $self->{type_bits});
	70	die "Addr too large: $addr\n" unless $addr < (1 << $self->{addr_bits});
	71	my $result = ($type << $self->{addr_bits}) + $addr;
4a9c3fa9 MG	72	unless ($location) {
	73	$self->{freeptr}++;
	74	$location = $self->{freeptr}
	75	}
	76	$self->{memory}[$location] = $result;
34073a4a	77	$self->{comment}[$location] = "$comment_type $comment_addr";
4a9c3fa9	78	$location
509643aa MG	79	}
	80
	81	sub parse {
	82	my ($self, $string) = @_;
4a9c3fa9	83	my $ds = Data::SExpression->new({symbol_case => 'up', use_symbol_class => 1, fold_lists => 1});
509643aa MG	84
	85	my $sexp;
	86	while () {
	87	last if $string =~ /^\s*$/;
	88	($sexp, $string) = $ds->read($string);
	89	$self->process($sexp)
	90	}
	91	}
	92
	93	sub finish {
	94	my ($self) = @_;
	95	$self->{memory}[5] = $self->{memory}[$self->{freeptr}];
34073a4a	96	$self->{comment}[5] = $self->{comment}[$self->{freeptr}];
509643aa MG	97	$self->{memory}[4] = $self->{freeptr};
	98	delete $self->{memory}[$self->{freeptr}]
	99	}
	100
	101	sub new {
	102	my ($class, %args) = @_;
	103	$args{type_bits} //= 3;
	104	$args{addr_bits} //= 8;
	105	$args{freeptr} //= 6;
	106	$args{memory} //= [0, 0, (1<<$args{addr_bits}), (1<<$args{addr_bits}), 0, 0, 0];
34073a4a	107	$args{comment} = ['(cdr part of NIL)', '(car part of NIL)', '(cdr part of T)', '(car part of T)', '(free storage pointer)', '', '(result of computation)'];
509643aa MG	108	bless \%args, $class
	109	}
	110
f0289d3d MG	111	sub print_binary16 {
f0289d3d MG	112	my ($self, $fh) = @_;
744f5c2a	113	$fh //= \*STDOUT; # uncoverable condition right
f0289d3d	114
26bb1344 MG	115	die "addr_bits + type_bits >= 16\n"if $self->{addr_bits} + $self->{type_bits} > 16;
26bb1344 MG	116
f0289d3d MG	117	my $length = @{$self->{memory}};
	118	print $fh pack('n', $length);
	119	for (@{$self->{memory}}) {
	120	print $fh pack('n', $_)
	121	}
	122	}
	123
	124	sub print_verilog {
509643aa	125	my ($self, $fh) = @_;
744f5c2a	126	$fh //= \*STDOUT; # uncoverable condition right
509643aa MG	127
509643aa MG	128	my $bits = $self->{type_bits} + $self->{addr_bits};
34073a4a MG	129	my $index_length = length $#{$self->{memory}};
34073a4a MG	130	my $index_format = '%' . $index_length . 'd';
509643aa MG	131	for my $index (0 .. $#{$self->{memory}}) {
509643aa MG	132	my $val = $self->{memory}[$index];
34073a4a	133	my $comment = $self->{comment}[$index];
509643aa MG	134	if ($index == 4) {
	135	$val = "${bits}'d$val"
	136	} else {
	137	$val = $val ? sprintf "%d'b%0${bits}b", $bits, $val : '0';
	138	}
34073a4a MG	139	my $spaces = ' ' x ($bits + 5 - (length $val));
34073a4a MG	140	$index = sprintf $index_format, $index;
744f5c2a MG	141
	142	print $fh "mem[$index] <= $val;";
	143	print $fh "$spaces // $comment" if defined $comment;
	144	print $fh "\n";
509643aa	145	}
f0289d3d MG	146
	147	}
	148	sub parse_and_print_binary16 {
	149	my ($self, $string, $fh) = @_;
	150	$self->parse($string);
	151	$self->finish;
	152	$self->print_binary16($fh);
509643aa MG	153	}
509643aa MG	154
f0289d3d	155	sub parse_and_print_verilog {
509643aa MG	156	my ($self, $string, $fh) = @_;
	157	$self->parse($string);
	158	$self->finish;
f0289d3d	159	$self->print_verilog($fh);
509643aa MG	160	}
	161
	162	1;
	163	__END__
	164
	165	=encoding utf-8
	166
	167	=head1 NAME
	168
	169	App::Scheme79asm - assemble sexp to Verilog ROM for SIMPLE processor
	170
	171	=head1 SYNOPSIS
	172
	173	use App::Scheme79asm;
	174	my $asm = App::Scheme79asm->new(type_bits => 3, addr_bits => 5);
f0289d3d	175	$asm->parse_and_print_verilog('(number 70)');
509643aa MG	176
	177	=head1 DESCRIPTION
	178
509643aa MG	179	SIMPLE is a LISP processor defined in the 1979
	180	B<Design of LISP-Based Processors> paper by Steele and Sussman.
	181
	182	The SIMPLE processor expects input in a particular tagged-pointer
	183	format. This module takes a string containing a sequence of
9924aa7b MG	184	S-expressions. Each S-expression is a list of one of three types:
9924aa7b MG	185
744f5c2a	186	C<(tag value)>, for example C<(symbol 2)>, represents a value to be
9924aa7b MG	187	put in memory (for example a number, or a symbol, or a variable
	188	reference).
	189
	190	C<(tag list)>, where C<list> is of one of these three types,
	191	represents a tagged pointer. In this case, C<list> is (recursively)
	192	laid out in memory as per these rules, and a pointer to that location
	193	(and tagged C<tag>) is put somewhere in memory.
	194
	195	C<(tag list1 list2)>, where C<list1> and C<list2> are of one of these
	196	three types (not necessarily the same type). In this case, C<list1>
	197	and C<list2> are (recursively) laid out in memory such that C<list1>
	198	is at position X and C<list2> is at position X+1, and a pointer of
	199	type tag and value X is put somewhere in memory.
	200
	201	After this process the very last pointer placed in memory is moved to
	202	the special location 5 (which is where SIMPLE expects to find the
	203	expression to be evaluated).
	204
	205	In normal use a single S-expression will be supplied, representing an
	206	entire program.
	207
68367057 MG	208	The C<tag> is either a number, a type, or a primitive.
68367057 MG	209	The available types are:
509643aa	210
68367057 MG	211	=over
	212
	213	=item LIST
	214
	215	=item SYMBOL (syn. NUMBER)
	216
	217	=item VAR (syn. VARIABLE)
	218
	219	=item CLOSURE
	220
	221	=item PROC (syn. PROCEDURE)
	222
	223	=item IF (syn. COND, CONDITIONAL)
	224
	225	=item CALL
	226
	227	=item QUOTE (syn. QUOTED)
	228
	229	=back
	230
	231	The available primitives are:
	232
	233	=over
	234
	235	=item MORE
	236
	237	=item CAR
	238
	239	=item CDR
	240
	241	=item CONS
	242
	243	=item ATOM
	244
	245	=item PROGN
	246
f0289d3d	247	=item REVERSE-LIST
68367057 MG	248
	249	=item FUNCALL
	250
	251	=back
	252
	253	The following methods are available:
	254
	255	=over
	256
	257	=item App::Scheme79asm->B<new>([key => value, key => value, ...])
	258
	259	Create a new assembler object. Takes a list of keys and values, here
	260	are the possible keys:
	261
	262	=over
	263
	264	=item type_bits
	265
	266	=item address_bits
	267
	268	A word is made of a type and an address, with the type occupying the
	269	most significant C<type_bits> (default 3) bits, and the address
	270	occupying the least significant C<address_bits> (default 8) bits.
	271	Therefore the word size is C<type_bits + address_bits> (default 13).
	272
	273	=item freeptr
	274
	275	A pointer to the last used byte in memory (default 6). The program
	276	will be laid out starting with location C<freeptr + 1>.
	277
	278	=item memory
	279
	280	The initial contents of the memory. Note that locations 4, 5, 6 will
	281	be overwritten, as will every location larger than the value of
	282	C<freeptr>.
	283
	284	=item comment
	285
	286	The initial comments for memory entries. C<< $comment->[$i] >> is the
	287	comment for C<< $memory->[$i] >>.
	288
68367057 MG	289	=back
	290
	291	=item $asm->B<parse>(I<$string>)
	292
	293	Parse a sequence of S-expressions and lay it out in memory.
	294	Can be called multiple times to lay out multiple sequences of
	295	S-expressions one after another.
	296
8ff4c670 MG	297	=item $asm->B<process>(I<$sexp>)
	298
	299	Given an already-parsed sexp (meaning a
	300	L<Data::SExpression> object), lay it out in memory.
	301	Can be called multiple times to lay out multiple sequences of
	302	S-expressions one after another.
	303
68367057 MG	304	=item $asm->B<finish>
	305
	306	Move the last pointer to position 5, and put the free pointer at
	307	position 4. After all sequences of S-expressions have been given to
	308	B<parse>, this method should be called.
	309
f0289d3d MG	310	=item $asm->B<print_binary16>([I<$fh>])
	311
	312	Print the length of the memory (as a big-endian 16-bit value),
	313	followed by the memory contents as a sequence of big-endian 16-bit
	314	values to the given filehandle (default STDOUT). Dies if
	315	C<addr_bits + type_bits> is more than 16.
	316
	317	Big-endian 16-bit values can be decoded with C<unpack 'n', $value>.
	318
	319	=item $asm->B<print_verilog>([I<$fh>])
68367057 MG	320
	321	Print a block of Verilog code assigning the memory contents to an
	322	array named C<mem> to the given filehandle (default STDOUT).
	323
f0289d3d MG	324	=item $asm->B<parse_and_print_binary16>(I<$string>[, I<$fh>])
	325
	326	Convenience method that calls B<parse>($string), B<finish>, and then
	327	B<print_binary16>($fh).
	328
	329	=item $asm->B<parse_and_print_verilog>(I<$string>[, I<$fh>])
68367057 MG	330
68367057 MG	331	Convenience method that calls B<parse>($string), B<finish>, and then
f0289d3d	332	B<print_verilog>($fh).
68367057 MG	333
68367057 MG	334	=back
509643aa MG	335
	336	=head1 SEE ALSO
	337
	338	L<http://repository.readscheme.org/ftp/papers/ai-lab-pubs/AIM-514.pdf>
	339
	340	=head1 AUTHOR
	341
	342	Marius Gavrilescu, E<lt>marius@ieval.roE<gt>
	343
	344	=head1 COPYRIGHT AND LICENSE
	345
	346	Copyright (C) 2018 by Marius Gavrilescu
	347
	348	This library is free software; you can redistribute it and/or modify
	349	it under the same terms as Perl itself, either Perl version 5.24.3 or,
	350	at your option, any later version of Perl 5 you may have available.
	351
	352
	353	=cut