lib/App/XMMS2/Notifier.pm

   1 package App::XMMS2::Notifier;
   2 use v5.14;
   3 use strict;
   4 use warnings;
   5 our $VERSION = 0.001001;
   6
   7 use Audio::XMMSClient 0.03;
   8 use Gtk2::Notify 0.05 -init,'xmms2-notifyd';
   9
  10 use Getopt::Long;
  11
  12 use constant CONVERSION_SPECIFIERS => qw/bitrate date sample_format url id channels samplerate tracknr genre artist album title/;
  13
  14 ##################################################
  15
  16 my $format = '$artist - $title';
  17
  18 GetOptions (
  19         "format=s" => \$format,
  20 );
  21
  22 my $xmms = Audio::XMMSClient->new('xmms2-notifyd');
  23 my $notify = Gtk2::Notify->new('');
  24
  25 $notify->set_timeout(3000);
  26
  27 ##################################################
  28
  29 sub notify_libnotify{
  30         $notify->update($_[0]);
  31         $notify->show;
  32 }
  33
  34 sub notify{
  35         my $id=$xmms->playback_current_id->wait->value or return;
  36         my $minfo=$xmms->medialib_get_info($id)->wait->value;
  37
  38         my %metadata = map { $_ => exists $minfo->{$_} ? (values $minfo->{$_})[0] : undef } CONVERSION_SPECIFIERS;
  39         my $str=$format;
  40         $str =~ s/\$$_/$metadata{$_}/g for keys %metadata;
  41
  42         notify_libnotify $str
  43 }
  44
  45 sub on_playback_current_id {
  46         notify;
  47         $xmms->broadcast_playback_current_id->notifier_set(\&on_playback_current_id);
  48 }
  49
  50 sub on_playback_status {
  51         notify if $xmms->playback_status->wait->value == 1; # 1 means playing, 2 means paused
  52         $xmms->broadcast_playback_status->notifier_set(\&on_playback_status);
  53 }
  54
  55 sub run {
  56         while (1) {
  57                 last if ($xmms->connect);
  58                 sleep 1
  59         }
  60
  61         $xmms->broadcast_playback_current_id->notifier_set(\&on_playback_current_id);
  62         $xmms->broadcast_playback_status->notifier_set(\&on_playback_status);
  63         $xmms->loop
  64 }
  65
  66 1
  67
  68 __END__
  69
  70 =head1 NAME
  71
  72 App::XMMS2::Notifier - script which notifies you what xmms2 is playing
  73
  74 =head1 SYNOPSIS
  75
  76   # Shows libnotify notifications e.g. "Silence - Cellule"
  77   xmms2-notifier
  78
  79   # Shows libnotify notifications e.g. "Cellule by Silence (L'autre endroit), year 2005, genre Electro"
  80   xmms2-notifier --format="$title by $artist ($album), year $date, genre $genre"
  81
  82 =head1 DESCRIPTION
  83
  84 xmms2-notifier is a script which shows libnotify notifications when
  85 the song is changed and when the playback is started/resumed.
  86
  87 You can control the notification format with the B<--format> argument.
  88 The following strings are replaced:
  89
  90 =over
  91
  92 =item $bitrate
  93
  94 The song bitrate, in bits/s. Example: 785104
  95
  96 =item $date
  97
  98 Usually the year the song was published. Example: 2005
  99
 100 =item $sample_format
 101
 102 The format of each sample. Example: S16
 103
 104 =item $url
 105
 106 An URL that points to the song. Example: file:///ext/Music/Silence+-+Cellule.flac
 107
 108 =item $id
 109
 110 The XMMS2 id of the song. Example: 498
 111
 112 =item $channels
 113
 114 The number of channels the song has. Example: 2
 115
 116 =item $samplerate
 117
 118 The sample rate of the song, in Hz. Example: 44100
 119
 120 =item $tracknr
 121
 122 The track number in the album. Example: 1
 123
 124 =item $genre
 125
 126 The genre of the song. Example: Electro
 127
 128 =item $artist
 129
 130 The artist/band. Example: Silence
 131
 132 =item $album
 133
 134 The album the song is from. Example: L'autre endroit
 135
 136 =item $title
 137
 138 The song title. Example: Cellule
 139
 140 =back
 141
 142 =head1 SEE ALSO
 143
 144 L<xmms2(1)>
 145
 146 =head1 AUTHOR
 147
 148 Marius Gavrilescu, E<lt>marius@ieval.roE<gt>
 149
 150 =head1 COPYRIGHT AND LICENSE
 151
 152 Copyright (C) 2013 by Marius Gavrilescu
 153
 154 This library is free software; you can redistribute it and/or modify
 155 it under the same terms as Perl itself, either Perl version 5.14.2 or,
 156 at your option, any later version of Perl 5 you may have available.
 157
 158
 159 =cut