Make gruntmasterd use Redis

[gruntmaster-daemon.git] / lib / Gruntmaster / Daemon.pm

package Gruntmaster::Daemon;

use 5.014000;
use strict;
use warnings;

our $VERSION = '0.001';

use Gruntmaster::Daemon::Constants qw/ERR/;
use Gruntmaster::Daemon::Format qw/mkrun/;
use Gruntmaster::Page qw/generate/;
use Gruntmaster::Data qw/job_inmeta job_problem problem_meta set_job_daemon set_job_result set_job_result_text set_job_results/;

use Cwd qw/cwd/;
use File::Basename qw/fileparse/;
use File::Slurp qw/write_file/;
use File::Spec::Functions qw/devnull/;
use File::Temp qw/tempdir/;
use IO::File;
use IPC::Open3 qw/open3/;
use Redis;
use Sys::Hostname qw/hostname/;
use Time::HiRes qw/time/;
use Try::Tiny;
use YAML::Any qw/LoadFile DumpFile/;
use Log::Log4perl qw/get_logger/;
use Data::Dumper qw/Dumper/;

##################################################

sub safe_can_nodie {
  my ($type, $sub, $name) = @_;

  return unless $name =~ /^\w+$/;
  no strict 'refs';
  my $pkg = __PACKAGE__ . "::${type}::${name}";
  eval "require $pkg" or get_logger->warn("Error while requiring $pkg: $@");
  $pkg->can($sub);
}

sub safe_can {
  my ($type, $sub, $name) = @_;

  safe_can_nodie @_ or get_logger->logdie("No such \l$type: '$name'");
}

sub prepare{
  my ($name, $format) = @_;
  my $basename = fileparse $name, qr/\.[^.]*/;
  get_logger->trace("Preparing file $name...");

  open my $devnull, devnull;
  open my $errors, '>>compile-error';
  my $ret = open3 $devnull, $errors, undef, 'gruntmaster-compile', $format => $basename, $name;
  waitpid $ret, 0;
  close $devnull;
  close $errors;
  die 'Compile error' if $?
}

sub prepare_files{
  my $meta = shift;

  for my $file (values $meta->{files}) {
	my ($format, $name, $content) = @{$file}{qw/format name content/};

	$file->{run} = mkrun($format);
	write_file $name, $content;
	prepare $name, $format;
  }
}

my $tempdir;

sub process{
  my $job = shift;
  my $rootdir = cwd;
  chdir $tempdir;

  my @results;
  my @full_results = ();
  my $meta = {};
  try {
	$meta = job_inmeta $job;
	if (job_problem $job) {
	  my $pbmeta = problem_meta job_problem $job;
	  my %files = %{$meta->{files}};
	  $meta = {%$meta, %$pbmeta};
	  $meta->{files} = {%files, %{$pbmeta->{files}}} if exists $pbmeta->{files};
	}

	prepare_files $meta;
	say Dumper $meta;

	my ($files, $generator, $runner, $judge, $testcnt) = map { $meta->{$_} or die "Required parameter missing: $_"} qw/files generator runner judge testcnt/;

	$generator = safe_can Generator => generate => $generator;
	$runner = safe_can Runner => run => $runner;
	$judge = safe_can Judge => judge => $judge;

	for my $test (1 .. $testcnt) {
	  my $start_time = time;
	  my $result;
	  try {
		$generator->($test, $meta);
		$result = $runner->($test, $meta);
	  } catch {
		$result = $_;
		unless (ref $result) {
		  chomp $result;
		  $result = [ERR, $result];
		}
	  };

	  if (ref $result) {
		get_logger->trace("Test $test result is " . $result->[1]);
		push @full_results, {id => $test, result => $result->[0], result_text => $result->[1], time => time - $start_time}
	  } else {
		get_logger->trace("Test $test result is $result");
		push @full_results, {id => $test, result => 0, result_text => $result, time => time - $start_time}
	  }
	  push @results, $result;
	  last if $meta->{judge} eq 'Absolute' && ref $result
	}

	my %results = $judge->(@results);
	$meta->{$_} = $results{$_} for keys %results;
  } catch {
	s,(.*) at .*,$1,;
	chomp;
	$meta->{result} = -1;
	$meta->{result_text} = $_;
  };

  get_logger->info("Job result: " . $meta->{result_text});
  set_job_result $job, $meta->{result};
  set_job_result_text $job, $meta->{result_text};
  set_job_results $job, \@full_results if scalar @full_results;

  chdir $rootdir;
  my $log = $meta->{contest} ? "ct/$meta->{contest}/log" : 'log';
  write_file "$log/src/$job." . Gruntmaster::Page::Log::FORMAT_EXTENSION->{$meta->{files}{prog}{format}}, $meta->{files}{prog}{content};
  generate "$log/job/$job.html";
  my $page = ($job + Gruntmaster::Page::Log::PAGE_SIZE - 1) / Gruntmaster::Page::Log::PAGE_SIZE;
  generate "$log/$page.html"
}

sub got_job{
	my $job = shift;
	get_logger->debug("Taking job $job...");
	if (set_job_daemon $job, hostname . ":$$") {
		get_logger->debug("Succesfully taken job $job");
		process $job;
		get_logger->debug("Job $job done");
	} else {
		get_logger->debug("Job $job already taken");
	}
}

sub run{
  Log::Log4perl->init('log.conf');
  get_logger->info("gruntmasterd $VERSION started");
  $tempdir = tempdir 'gruntmasterd.XXXX', CLEANUP => 1, TMPDIR => 1;
  my $redis = Redis->new;
  $redis->subscribe('jobs', \&got_job);
  $redis->wait_for_messages(0) while 1
}

1;
__END__
# Below is stub documentation for your module. You'd better edit it!

=head1 NAME

Gruntmaster::Daemon - Perl extension for blah blah blah

=head1 SYNOPSIS

  use Gruntmaster::Daemon;
  blah blah blah

=head1 DESCRIPTION

Stub documentation for Gruntmaster::Daemon, created by h2xs. It looks like the
author of the extension was negligent enough to leave the stub
unedited.

Blah blah blah.


=head1 SEE ALSO

Mention other useful documentation such as the documentation of
related modules or operating system documentation (such as man pages
in UNIX), or any relevant external documentation such as RFCs or
standards.

If you have a mailing list set up for your module, mention it here.

If you have a web site set up for your module, mention it here.

=head1 AUTHOR

Marius Gavrilescu, E<lt>marius@E<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2013 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.18.1 or,
at your option, any later version of Perl 5 you may have available.


=cut