[gruntmaster-daemon.git] / gruntmaster-exec

#!/usr/bin/perl
use v5.14;
use strict;
use warnings;

use constant +{
	# Accepted
	AC => 0,

	# Internal server error
	ERR => -1,

	# All other errors
	WA => 1,
	NZX => 2,
	TLE => 3,
	OLE => 4,
	DIED => 5,
	REJ => 10,
};

use BSD::Resource qw/setrlimit RLIMIT_AS RLIMIT_FSIZE/;
use IPC::Signal qw/sig_name sig_num/;
use sigtrap qw/XFSZ/;

use Getopt::Long;
use POSIX qw//;
use Time::HiRes qw/alarm/;

my (@fds, $timeout, $mlimit, $olimit);
my $close = 1;

GetOptions(
	"fd=s"      => \@fds,
	"timeout=f" => \$timeout,
	"mlimit=i"  => \$mlimit,
	"olimit=i"  => \$olimit,
	"close!"    => \$close,
);

my $ret = fork // die 'Cannot fork';
if ($ret) {
	my $tle;
	local $SIG{ALRM} = sub { kill KILL => $ret; $tle = 1};
	alarm ($timeout || 5);
	waitpid $ret, 0;
	alarm 0;
	my $sig = $? & 127;
	my $signame = sig_name $sig;
	exit !say TLE,  "\nTime Limit Exceeded"   if $tle;
	exit !say OLE,  "\nOutput Limit Exceeded" if $sig && $signame eq 'XFSZ';
	exit !say DIED, "\nCrash (SIG$signame)"   if $sig && $signame ne 'PIPE';
	exit !say NZX,  "\nNon-zero exit status: " . ($? >> 8) if $? >> 8;
	exit !say AC,   "\nAll OK";
} else {
	$^F = 50;
	if ($close) {
		POSIX::close $_ for 0 .. $^F;
	}
	for my $fdstring (@fds) {
		my ($fd, $file) = split ' ', $fdstring, 2;
		open my $fh, $file or die $!;
		my $oldfd = fileno $fh;
		if ($oldfd != $fd) {
			POSIX::dup2 $oldfd, $fd or die $!;
			POSIX::close $oldfd or die $!;
		}
	}
	%ENV = (ONLINE_JUDGE => 1, PATH => $ENV{PATH}, HOME => $ENV{HOME});
	setrlimit RLIMIT_AS, $mlimit, $mlimit or die $! if $mlimit;
	setrlimit RLIMIT_FSIZE, $olimit, $olimit or die $! if $olimit;
	POSIX::setgid 65534; # Set group id to nogroup
	POSIX::setuid 65534; # Set user id to nobody
	exec @ARGV;
}

1;
__END__

=encoding utf-8

=head1 NAME

gruntmaster-exec - Gruntmaster 6000 executor

=head1 SYNOPSIS

  gruntmaster-exec 20000000 111 echo 'Hello, world!'

=head1 DESCRIPTION

gruntmaster-exec is the script used by gruntmasterd to run programs.

The first argument is the address space limit (in bytes), the second argument is the output limit (also in bytes). The rest of the arguments are the command that should be run and its arguments.

gruntmaster-exec sets the resource limits, cleans the environment (except for PATH and HOME), adds the ONLINE_JUDGE environment variable with value 1, and finally C<exec>s the given command.

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU Affero General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
Commit	Line	Data
	1	#!/usr/bin/perl
	2	use v5.14;
	3	use strict;
	4	use warnings;
	5
	6	use constant +{
	7	# Accepted
	8	AC => 0,
	9
	10	# Internal server error
	11	ERR => -1,
	12
	13	# All other errors
	14	WA => 1,
	15	NZX => 2,
	16	TLE => 3,
	17	OLE => 4,
	18	DIED => 5,
	19	REJ => 10,
	20	};
	21
	22	use BSD::Resource qw/setrlimit RLIMIT_AS RLIMIT_FSIZE/;
	23	use IPC::Signal qw/sig_name sig_num/;
	24	use sigtrap qw/XFSZ/;
	25
	26	use Getopt::Long;
	27	use POSIX qw//;
	28	use Time::HiRes qw/alarm/;
	29
	30	my (@fds, $timeout, $mlimit, $olimit);
	31	my $close = 1;
	32
	33	GetOptions(
	34	"fd=s" => \@fds,
	35	"timeout=f" => \$timeout,
	36	"mlimit=i" => \$mlimit,
	37	"olimit=i" => \$olimit,
	38	"close!" => \$close,
	39	);
	40
	41	my $ret = fork // die 'Cannot fork';
	42	if ($ret) {
	43	my $tle;
	44	local $SIG{ALRM} = sub { kill KILL => $ret; $tle = 1};
	45	alarm ($timeout \|\| 5);
	46	waitpid $ret, 0;
	47	alarm 0;
	48	my $sig = $? & 127;
	49	my $signame = sig_name $sig;
	50	exit !say TLE, "\nTime Limit Exceeded" if $tle;
	51	exit !say OLE, "\nOutput Limit Exceeded" if $sig && $signame eq 'XFSZ';
	52	exit !say DIED, "\nCrash (SIG$signame)" if $sig && $signame ne 'PIPE';
	53	exit !say NZX, "\nNon-zero exit status: " . ($? >> 8) if $? >> 8;
	54	exit !say AC, "\nAll OK";
	55	} else {
	56	$^F = 50;
	57	if ($close) {
	58	POSIX::close $_ for 0 .. $^F;
	59	}
	60	for my $fdstring (@fds) {
	61	my ($fd, $file) = split ' ', $fdstring, 2;
	62	open my $fh, $file or die $!;
	63	my $oldfd = fileno $fh;
	64	if ($oldfd != $fd) {
	65	POSIX::dup2 $oldfd, $fd or die $!;
	66	POSIX::close $oldfd or die $!;
	67	}
	68	}
	69	%ENV = (ONLINE_JUDGE => 1, PATH => $ENV{PATH}, HOME => $ENV{HOME});
	70	setrlimit RLIMIT_AS, $mlimit, $mlimit or die $! if $mlimit;
	71	setrlimit RLIMIT_FSIZE, $olimit, $olimit or die $! if $olimit;
	72	POSIX::setgid 65534; # Set group id to nogroup
	73	POSIX::setuid 65534; # Set user id to nobody
	74	exec @ARGV;
	75	}
	76
	77	1;
	78	__END__
	79
	80	=encoding utf-8
	81
	82	=head1 NAME
	83
	84	gruntmaster-exec - Gruntmaster 6000 executor
	85
	86	=head1 SYNOPSIS
	87
	88	gruntmaster-exec 20000000 111 echo 'Hello, world!'
	89
	90	=head1 DESCRIPTION
	91
	92	gruntmaster-exec is the script used by gruntmasterd to run programs.
	93
	94	The first argument is the address space limit (in bytes), the second argument is the output limit (also in bytes). The rest of the arguments are the command that should be run and its arguments.
	95
	96	gruntmaster-exec sets the resource limits, cleans the environment (except for PATH and HOME), adds the ONLINE_JUDGE environment variable with value 1, and finally C<exec>s the given command.
	97
	98	=head1 AUTHOR
	99
	100	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	101
	102	=head1 COPYRIGHT AND LICENSE
	103
	104	Copyright (C) 2014 by Marius Gavrilescu
	105
	106	This program is free software: you can redistribute it and/or modify
	107	it under the terms of the GNU Affero General Public License as published by
	108	the Free Software Foundation, either version 3 of the License, or
	109	(at your option) any later version.