lib/Gruntmaster/Daemon.pm

   1 package Gruntmaster::Daemon;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '5999.000_004';
   8
   9 use Gruntmaster::Daemon::Constants qw/ERR/;
  10 use Gruntmaster::Daemon::Format qw/prepare_files stopvms/;
  11
  12 use File::Basename qw/fileparse/;
  13 use File::Temp qw/tempdir/;
  14 use JSON qw/decode_json encode_json/;
  15 use Sys::Hostname qw/hostname/;
  16 use Time::HiRes qw/time/;
  17 use Try::Tiny;
  18 use Log::Log4perl qw/get_logger/;
  19
  20 use constant PAGE_SIZE => 10;
  21 use constant FORMAT_EXTENSION => {
  22         C => 'c',
  23         CPP => 'cpp',
  24         GCCGO => 'go',
  25         GOLANG => 'go',
  26         HASKELL => 'hs',
  27         MONO => 'cs',
  28         JAVA => 'java',
  29         PASCAL => 'pas',
  30         PERL => 'pl',
  31         PYTHON => 'py',
  32 };
  33
  34 ##################################################
  35
  36 my $db;
  37
  38 sub safe_can {
  39         my ($type, $sub, $name) = @_;
  40
  41         get_logger->logdie("Invalid \l$type: '$name'") unless $name =~ /^\w+$/s;
  42         my $pkg = __PACKAGE__ . "::${type}::${name}";
  43         eval "require $pkg" or get_logger->warn("Error while requiring $pkg: $@");
  44         $pkg->can($sub) or get_logger->logdie("No such \l$type: '$name'");
  45 }
  46
  47 sub process{
  48         my ($meta) = @_;
  49
  50         my @results;
  51         my @full_results = ();
  52         our $errors = '';
  53         try {
  54                 prepare_files $meta;
  55                 chomp $errors;
  56
  57                 my ($files, $generator, $runner, $judge, $testcnt) = map { $meta->{$_} or die "Required parameter missing: $_\n"} qw/files generator runner judge testcnt/;
  58
  59                 $generator = safe_can Generator => generate => $generator;
  60                 $runner = safe_can Runner => run => $runner;
  61                 $judge = safe_can Judge => judge => $judge;
  62
  63                 for my $test (1 .. $testcnt) {
  64                         my $start_time = time;
  65                         my $result;
  66                         try {
  67                                 $generator->($test, $meta);
  68                                 $result = $runner->($test, $meta);
  69                         } catch {
  70                                 $result = $_;
  71                                 unless (ref $result) {
  72                                         chomp $result;
  73                                         $result = [ERR, $result];
  74                                 }
  75                         };
  76
  77                         if (ref $result) {
  78                                 get_logger->trace("Test $test result is " . $result->[1]);
  79                                 push @full_results, {id => $test, result => $result->[0], result_text => $result->[1], time => time - $start_time}
  80                         } else {
  81                                 get_logger->trace("Test $test result is $result");
  82                                 push @full_results, {id => $test, result => 0, result_text => $result, time => time - $start_time}
  83                         }
  84                         push @results, $result;
  85                         last if $meta->{judge} eq 'Absolute' && ref $result
  86                 }
  87
  88                 my %results = $judge->(@results);
  89                 $meta->{$_} = $results{$_} for keys %results;
  90                 $meta->{results} = \@full_results
  91         } catch {
  92                 s/(.*) at .*/$1/s;
  93                 chomp;
  94                 $meta->{result} = -1;
  95                 $meta->{result_text} = $_;
  96         };
  97         stopvms;
  98         $meta->{errors} = $errors;
  99
 100         get_logger->info('Job result: ' . $meta->{result_text});
 101 }
 102
 103 sub process_job {
 104         my ($job) = @_;
 105         my $meta = {
 106                 problem => $job->problem->id,
 107                 files => {
 108                         prog => {
 109                                 name => 'prog.' . $job->extension,
 110                                 format => $job->format,
 111                                 content => $job->source,
 112                         },
 113                 },
 114                 map { $_ => $job->problem->get_column($_) } qw/generator runner judge testcnt timeout olimit/
 115         };
 116         $meta->{tests} = decode_json $job->problem->tests if $meta->{runner} eq 'File';
 117
 118         $meta->{files}{ver} = {
 119                 name => 'ver.' . FORMAT_EXTENSION->{$job->problem->verformat},
 120                 format => $job->problem->verformat,
 121                 content => $job->problem->versource,
 122         } if $job->problem->verformat;
 123
 124         process $meta;
 125
 126         $job->update({
 127                 result => $meta->{result},
 128                 result_text => $meta->{result_text},
 129                 ($meta->{results} ? (results => encode_json $meta->{results}) : ()),
 130                 $meta->{errors} ? (errors => $meta->{errors}) : ()
 131         });
 132
 133         my $solved = $meta->{result} ? 0 : 1;
 134         my $status = $db->problem_statuses->find($job->owner, $job->problem);
 135         $db->problem_statuses->update_or_create({
 136                 problem => $job->problem,
 137                 owner   => $job->owner,
 138                 job     => $job->id,
 139                 solved  => $solved}) if !$job->problem->is_private;
 140 }
 141
 142 sub got_job{
 143         my $job = $_[0];
 144         my $id = $job->id;
 145         get_logger->debug("Taking job $id...");
 146         my $daemon = hostname . ":$$";
 147         $job->update({daemon => $daemon});
 148         #if (set_job_daemon $job, hostname . ":$$") {
 149         if (1) {
 150                 get_logger->debug("Succesfully taken job $id");
 151                 process_job $job;
 152                 get_logger->debug("Job $id done");
 153         } else {
 154                 get_logger->debug("Job $id already taken");
 155         }
 156 }
 157
 158 sub run{
 159         require Gruntmaster::Data;
 160         $db = Gruntmaster::Data->connect($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');
 161         Log::Log4perl->init('/etc/gruntmasterd/gruntmasterd-log.conf');
 162         get_logger->info("gruntmasterd $VERSION started");
 163         my $dir = tempdir 'gruntmasterd.XXXX', CLEANUP => 1, TMPDIR => 1;
 164         chmod 0711, $dir;
 165         chdir $dir;
 166         while (1) {
 167                 my $job = $db->jobs->search({daemon => undef}, {rows => 1})->first;
 168                 got_job $job if defined $job;
 169                 sleep 2 unless defined $job;
 170         }
 171 }
 172
 173 1;
 174 __END__
 175
 176 =head1 NAME
 177
 178 Gruntmaster::Daemon - Gruntmaster 6000 Online Judge -- daemon
 179
 180 =head1 SYNOPSIS
 181
 182   use Gruntmaster::Daemon;
 183   Gruntmaster::Daemon->run;
 184
 185 =head1 DESCRIPTION
 186
 187 Gruntmaster::Daemon is the daemon component of the Gruntmaster 6000 online judge.
 188
 189 =head1 AUTHOR
 190
 191 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 192
 193 =head1 COPYRIGHT AND LICENSE
 194
 195 Copyright (C) 2014 by Marius Gavrilescu
 196
 197 This library is free software: you can redistribute it and/or modify
 198 it under the terms of the GNU Affero General Public License as published by
 199 the Free Software Foundation, either version 3 of the License, or
 200 (at your option) any later version.
 201
 202
 203 =cut