lib/Gruntmaster/Daemon.pm

   1 package Gruntmaster::Daemon;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '5999.000_004';
   8
   9 use Gruntmaster::Daemon::Constants qw/ERR/;
  10 use Gruntmaster::Daemon::Format qw/prepare_files stopvms/;
  11
  12 use File::Basename qw/fileparse/;
  13 use File::Temp qw/tempdir/;
  14 use JSON qw/decode_json encode_json/;
  15 use Sys::Hostname qw/hostname/;
  16 use Time::HiRes qw/time/;
  17 use Try::Tiny;
  18 use Log::Log4perl qw/get_logger/;
  19
  20 use constant PAGE_SIZE => 10;
  21 use constant FORMAT_EXTENSION => {
  22         C => 'c',
  23         CPP => 'cpp',
  24         GCCGO => 'go',
  25         GOLANG => 'go',
  26         HASKELL => 'hs',
  27         MONO => 'cs',
  28         JAVA => 'java',
  29         PASCAL => 'pas',
  30         PERL => 'pl',
  31         PYTHON => 'py',
  32 };
  33
  34 ##################################################
  35
  36 sub purge;
  37
  38 my $db;
  39
  40 sub safe_can_nodie {
  41         my ($type, $sub, $name) = @_;
  42
  43         return unless $name =~ /^\w+$/s;
  44         my $pkg = __PACKAGE__ . "::${type}::${name}";
  45         eval "require $pkg" or get_logger->warn("Error while requiring $pkg: $@");
  46         $pkg->can($sub);
  47 }
  48
  49 sub safe_can {
  50         my ($type, $sub, $name) = @_;
  51
  52         safe_can_nodie @_ or get_logger->logdie("No such \l$type: '$name'");
  53 }
  54
  55 sub process{
  56         my ($job, $jobr) = @_;
  57
  58         my @results;
  59         my @full_results = ();
  60         my $meta;
  61         our $errors = '';
  62         try {
  63                 if (ref $job) {
  64                         $meta = $job;
  65                 } else {
  66                         $meta = {
  67                                 problem => $jobr->problem->id,
  68                                 files => {
  69                                         prog => {
  70                                                 name => 'prog.' . $jobr->extension,
  71                                                 format => $jobr->format,
  72                                                 content => $jobr->source,
  73                                         },
  74                                 },
  75                                 map { $_ => $jobr->problem->get_column($_) } qw/generator runner judge testcnt timeout olimit/
  76                         };
  77                         $meta->{tests} = decode_json $jobr->problem->tests if $meta->{runner} eq 'File';
  78
  79                         $meta->{files}{ver} = {
  80                                 name => 'ver.' . FORMAT_EXTENSION->{$jobr->problem->verformat},
  81                                 format => $jobr->problem->verformat,
  82                                 content => $jobr->problem->versource,
  83                         } if $jobr->problem->verformat;
  84                 }
  85
  86                 prepare_files $meta;
  87                 chomp $errors;
  88
  89                 my ($files, $generator, $runner, $judge, $testcnt) = map { $meta->{$_} or die "Required parameter missing: $_\n"} qw/files generator runner judge testcnt/;
  90
  91                 $generator = safe_can Generator => generate => $generator;
  92                 $runner = safe_can Runner => run => $runner;
  93                 $judge = safe_can Judge => judge => $judge;
  94
  95                 for my $test (1 .. $testcnt) {
  96                         my $start_time = time;
  97                         my $result;
  98                         try {
  99                                 $generator->($test, $meta);
 100                                 $result = $runner->($test, $meta);
 101                         } catch {
 102                                 $result = $_;
 103                                 unless (ref $result) {
 104                                         chomp $result;
 105                                         $result = [ERR, $result];
 106                                 }
 107                         };
 108
 109                         if (ref $result) {
 110                                 get_logger->trace("Test $test result is " . $result->[1]);
 111                                 push @full_results, {id => $test, result => $result->[0], result_text => $result->[1], time => time - $start_time}
 112                         } else {
 113                                 get_logger->trace("Test $test result is $result");
 114                                 push @full_results, {id => $test, result => 0, result_text => $result, time => time - $start_time}
 115                         }
 116                         push @results, $result;
 117                         last if $meta->{judge} eq 'Absolute' && ref $result
 118                 }
 119
 120                 my %results = $judge->(@results);
 121                 $meta->{$_} = $results{$_} for keys %results;
 122                 $meta->{results} = \@full_results
 123         } catch {
 124                 s/(.*) at .*/$1/s;
 125                 chomp;
 126                 $meta->{result} = -1;
 127                 $meta->{result_text} = $_;
 128         };
 129         stopvms;
 130
 131         get_logger->info('Job result: ' . $meta->{result_text});
 132         return unless $jobr;
 133         $jobr->update({
 134                 result => $meta->{result},
 135                 result_text => $meta->{result_text},
 136                 ($meta->{results} ? (results => encode_json $meta->{results}) : ()),
 137                 $errors ? (errors => $errors) : ()
 138         });
 139
 140         my $solved = $meta->{result} ? 0 : 1;
 141         my $status = $db->problem_statuses->find($jobr->owner, $jobr->problem);
 142         $db->problem_statuses->update_or_create({
 143                 problem => $jobr->problem,
 144                 owner   => $jobr->owner,
 145                 job     => $jobr->id,
 146                 solved  => $solved});
 147
 148         purge '/log/';
 149         purge "/log/$job";
 150         purge '/st/' . $jobr->contest if $jobr->contest;
 151         purge '/us/';
 152         purge '/us/' . $jobr->owner;
 153 }
 154
 155 sub got_job{
 156         my $job = $_[0];
 157         my $id = $job->id;
 158         get_logger->debug("Taking job $id...");
 159         my $daemon = hostname . ":$$";
 160         $job->update({daemon => $daemon});
 161         #if (set_job_daemon $job, hostname . ":$$") {
 162         if (1) {
 163                 get_logger->debug("Succesfully taken job $id");
 164                 process $id, $job;
 165                 get_logger->debug("Job $id done");
 166         } else {
 167                 get_logger->debug("Job $id already taken");
 168         }
 169 }
 170
 171 sub run{
 172         warn "No GRUNTMASTER_VM environment variable. Running without a VM is a security risk.\n"  unless $ENV{GRUNTMASTER_VM};
 173         require Gruntmaster::Data;
 174         $db = Gruntmaster::Data->connect('dbi:Pg:');
 175         Log::Log4perl->init('/etc/gruntmasterd/gruntmasterd-log.conf');
 176         get_logger->info("gruntmasterd $VERSION started");
 177         chdir tempdir 'gruntmasterd.XXXX', CLEANUP => 1, TMPDIR => 1;
 178         while (1) {
 179                 my $job = $db->jobs->search({daemon => undef}, {rows => 1})->first;
 180                 got_job $job if defined $job;
 181                 sleep 2 unless defined $job;
 182         }
 183 }
 184
 185 1;
 186 __END__
 187
 188 =head1 NAME
 189
 190 Gruntmaster::Daemon - Gruntmaster 6000 Online Judge -- daemon
 191
 192 =head1 SYNOPSIS
 193
 194   use Gruntmaster::Daemon;
 195   Gruntmaster::Daemon->run;
 196
 197 =head1 DESCRIPTION
 198
 199 Gruntmaster::Daemon is the daemon component of the Gruntmaster 6000 online judge.
 200
 201 =head1 AUTHOR
 202
 203 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 204
 205 =head1 COPYRIGHT AND LICENSE
 206
 207 Copyright (C) 2014 by Marius Gavrilescu
 208
 209 This library is free software: you can redistribute it and/or modify
 210 it under the terms of the GNU Affero General Public License as published by
 211 the Free Software Foundation, either version 3 of the License, or
 212 (at your option) any later version.
 213
 214
 215 =cut