lib/Gruntmaster/Daemon.pm

   1 package Gruntmaster::Daemon;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '5999.000_005';
   8
   9 use Gruntmaster::Daemon::Constants qw/ERR/;
  10 use Gruntmaster::Daemon::Format qw/prepare_files stopvms/;
  11
  12 use File::Slurp qw/read_file/;
  13 use File::Temp qw/tempdir/;
  14 use JSON qw/decode_json encode_json/;
  15 use Sys::Hostname qw/hostname/;
  16 use Time::HiRes qw/time/;
  17 use Try::Tiny;
  18 use Log::Log4perl qw/get_logger/;
  19
  20 use constant FORMAT_EXTENSION => {
  21         BRAINFUCK => 'bf',
  22         C => 'c',
  23         CPP => 'cpp',
  24         D => 'd',
  25         GCCGO => 'go',
  26         GOLANG => 'go',
  27         GOLFSCRIPT => 'gs',
  28         HASKELL => 'hs',
  29         JAVA => 'java',
  30         JULIA => 'jl',
  31         MONO => 'cs',
  32         OCAML => 'ml',
  33         PASCAL => 'pas',
  34         PERL => 'pl',
  35         PHP => 'php',
  36         PYTHON => 'py',
  37         RUBY => 'rb',
  38         RUST => 'rs',
  39         SBCL => 'l',
  40 };
  41
  42 ##################################################
  43
  44 sub safe_can {
  45         my ($type, $sub, $name) = @_;
  46
  47         get_logger->logdie("Invalid \l$type: '$name'") unless $name =~ /^\w+$/s;
  48         my $pkg = __PACKAGE__ . "::${type}::${name}";
  49         eval "require $pkg" or get_logger->warn("Error while requiring $pkg: $@");
  50         $pkg->can($sub) or get_logger->logdie("No such \l$type: '$name'");
  51 }
  52
  53 sub process{
  54         my ($meta) = @_;
  55
  56         my @results;
  57         my @full_results = ();
  58         our $errors = '';
  59         try {
  60                 prepare_files $meta;
  61                 chomp $errors;
  62
  63                 my ($files, $generator, $runner, $judge, $testcnt) = map { $meta->{$_} or die "Required parameter missing: $_\n"} qw/files generator runner judge testcnt/;
  64
  65                 $generator = safe_can Generator => generate => $generator;
  66                 $runner = safe_can Runner => run => $runner;
  67                 $judge = safe_can Judge => judge => $judge;
  68
  69                 for my $test (1 .. $testcnt) {
  70                         my $start_time = time;
  71                         my $result;
  72                         unlink 'result';
  73                         try {
  74                                 $generator->($test, $meta);
  75                                 $result = $runner->($test, $meta);
  76                         } catch {
  77                                 $result = $_;
  78                                 unless (ref $result) {
  79                                         chomp $result;
  80                                         $result = [ERR, $result];
  81                                 }
  82                         };
  83
  84                         if (ref $result) {
  85                                 my $result_text = $result->[1];
  86                                 $result_text .= ': ' . read_file 'result' if -s 'result';
  87                                 get_logger->trace("Test $test result is " . $result_text);
  88                                 push @full_results, {id => $test, result => $result->[0], result_text => $result_text, time => time - $start_time}
  89                         } else {
  90                                 get_logger->trace("Test $test result is $result");
  91                                 push @full_results, {id => $test, result => 0, result_text => $result, time => time - $start_time}
  92                         }
  93                         push @results, $result;
  94                         last if $meta->{judge} eq 'Absolute' && ref $result
  95                 }
  96
  97                 my %results = $judge->(@results);
  98                 $meta->{$_} = $results{$_} for keys %results;
  99                 $meta->{results} = \@full_results
 100         } catch {
 101                 s/(.*) at .*/$1/s;
 102                 chomp;
 103                 $meta->{result} = -1;
 104                 $meta->{result_text} = $_;
 105         };
 106         stopvms;
 107         $meta->{errors} = $errors;
 108
 109         get_logger->info('Job result: ' . $meta->{result_text});
 110 }
 111
 112 sub process_job {
 113         my ($job) = @_;
 114         my $pb = db()->select('problems', '*', {id => $job->{problem}})->hash;
 115         my $meta = {
 116                 problem => $job->{problem},
 117                 files => {
 118                         prog => {
 119                                 name => 'prog.' . $job->{extension},
 120                                 format => $job->{format},
 121                                 content => $job->{source},
 122                         },
 123                 },
 124                 map { $_ => $pb->{$_} } qw/generator runner judge precnt testcnt timeout olimit/
 125         };
 126         my $timeout_override = db()->query('SELECT timeout FROM limits WHERE problem=? AND format=?', $job->{problem}, $job->{format})->list;
 127         $meta->{timeout} = $timeout_override if defined $timeout_override;
 128         $meta->{tests} = decode_json $pb->{tests} if $meta->{runner} eq 'File';
 129         $job->{contest} &&= contest_entry($job->{contest});
 130         delete $meta->{precnt} unless $job->{contest} && $job->{contest}{started} && !$job->{contest}{finished}; ## no critic (ProhibitNegativeExpressionsInUnlessAndUntilConditions)
 131         $meta->{testcnt} = $meta->{precnt} if $meta->{precnt};
 132
 133         $meta->{files}{ver} = {
 134                 name => 'ver.' . FORMAT_EXTENSION->{$pb->{verformat}},
 135                 format => $pb->{verformat},
 136                 content => $pb->{versource},
 137         } if $pb->{verformat};
 138
 139         process $meta;
 140
 141         $meta->{result_text} .= ' (pretests)' if $meta->{precnt};
 142         finish_job($job, $job->{private} || $pb->{private},
 143           result => $meta->{result},
 144           result_text => $meta->{result_text},
 145           ($meta->{results} ? (results => encode_json $meta->{results}) : ()),
 146           $meta->{errors} ? (errors => $meta->{errors}) : ());
 147 }
 148
 149 sub got_job{
 150         my $job = $_[0];
 151         my $id = $job->{id};
 152         get_logger->debug("Processing job $id...");
 153         process_job $job;
 154         get_logger->debug("Job $id done");
 155 }
 156
 157 my $daemon = hostname . ":$$";
 158
 159 sub run{
 160         require Gruntmaster::Data;
 161         Gruntmaster::Data->import;
 162         dbinit($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');
 163         Log::Log4perl->init('/etc/gruntmasterd/gruntmasterd-log.conf');
 164         get_logger->info("gruntmasterd $VERSION started ($daemon)");
 165         my $dir = tempdir 'gruntmasterd.XXXX', CLEANUP => 1, TMPDIR => 1;
 166         chmod 0711, $dir;
 167         chdir $dir;
 168         while (1) {
 169                 my $job = take_job($daemon);
 170                 got_job $job if defined $job;
 171                 sleep 2 unless defined $job;
 172         }
 173 }
 174
 175 1;
 176 __END__
 177
 178 =head1 NAME
 179
 180 Gruntmaster::Daemon - Gruntmaster 6000 Online Judge -- daemon
 181
 182 =head1 SYNOPSIS
 183
 184   use Gruntmaster::Daemon;
 185   Gruntmaster::Daemon->run;
 186
 187 =head1 DESCRIPTION
 188
 189 Gruntmaster::Daemon is the daemon component of the Gruntmaster 6000 online judge.
 190
 191 =head1 AUTHOR
 192
 193 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 194
 195 =head1 COPYRIGHT AND LICENSE
 196
 197 Copyright (C) 2014 by Marius Gavrilescu
 198
 199 This library is free software: you can redistribute it and/or modify
 200 it under the terms of the GNU Affero General Public License as published by
 201 the Free Software Foundation, either version 3 of the License, or
 202 (at your option) any later version.
 203
 204
 205 =cut