lib/Gruntmaster/Daemon.pm

   1 package Gruntmaster::Daemon;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '5999.000_005';
   8
   9 use Gruntmaster::Daemon::Constants qw/ERR/;
  10 use Gruntmaster::Daemon::Format qw/prepare_files stopvms/;
  11
  12 use File::Slurp qw/read_file/;
  13 use File::Temp qw/tempdir/;
  14 use JSON qw/decode_json encode_json/;
  15 use Sys::Hostname qw/hostname/;
  16 use Time::HiRes qw/time/;
  17 use Try::Tiny;
  18 use Log::Log4perl qw/get_logger/;
  19
  20 use constant FORMAT_EXTENSION => {
  21         BRAINFUCK => 'bf',
  22         C => 'c',
  23         CPP => 'cpp',
  24         D => 'd',
  25         GCCGO => 'go',
  26         GOLANG => 'go',
  27         GOLFSCRIPT => 'gs',
  28         HASKELL => 'hs',
  29         JAVA => 'java',
  30         JULIA => 'jl',
  31         MONO => 'cs',
  32         OBERON => 'm',
  33         OCAML => 'ml',
  34         PASCAL => 'pas',
  35         PERL => 'pl',
  36         PHP => 'php',
  37         PYTHON => 'py',
  38         RUBY => 'rb',
  39         RUST => 'rs',
  40         SBCL => 'l',
  41 };
  42
  43 ##################################################
  44
  45 sub safe_can {
  46         my ($type, $sub, $name) = @_;
  47
  48         get_logger->logdie("Invalid \l$type: '$name'") unless $name =~ /^\w+$/s;
  49         my $pkg = __PACKAGE__ . "::${type}::${name}";
  50         eval "require $pkg" or get_logger->warn("Error while requiring $pkg: $@");
  51         $pkg->can($sub) or get_logger->logdie("No such \l$type: '$name'");
  52 }
  53
  54 sub process{
  55         my ($meta) = @_;
  56
  57         my @results;
  58         my @full_results = ();
  59         our $errors = '';
  60         try {
  61                 prepare_files $meta;
  62                 chomp $errors;
  63
  64                 my ($files, $generator, $runner, $judge, $testcnt) = map { $meta->{$_} or die "Required parameter missing: $_\n"} qw/files generator runner judge testcnt/;
  65
  66                 $generator = safe_can Generator => generate => $generator;
  67                 $runner = safe_can Runner => run => $runner;
  68                 $judge = safe_can Judge => judge => $judge;
  69
  70                 for my $test (1 .. $testcnt) {
  71                         my $start_time = time;
  72                         my $result;
  73                         unlink 'result';
  74                         try {
  75                                 $generator->($test, $meta);
  76                                 $result = $runner->($test, $meta);
  77                         } catch {
  78                                 $result = $_;
  79                                 unless (ref $result) {
  80                                         chomp $result;
  81                                         $result = [ERR, $result];
  82                                 }
  83                         };
  84
  85                         if (ref $result) {
  86                                 my $result_text = $result->[1];
  87                                 $result_text .= ': ' . read_file 'result' if -s 'result';
  88                                 get_logger->trace("Test $test result is " . $result_text);
  89                                 push @full_results, {id => $test, result => $result->[0], result_text => $result_text, time => time - $start_time}
  90                         } else {
  91                                 get_logger->trace("Test $test result is $result");
  92                                 push @full_results, {id => $test, result => 0, result_text => $result, time => time - $start_time}
  93                         }
  94                         push @results, $result;
  95                         last if $meta->{judge} eq 'Absolute' && ref $result
  96                 }
  97
  98                 my %results = $judge->(@results);
  99                 $meta->{$_} = $results{$_} for keys %results;
 100                 $meta->{results} = \@full_results
 101         } catch {
 102                 s/(.*) at .*/$1/s;
 103                 chomp;
 104                 $meta->{result} = -1;
 105                 $meta->{result_text} = $_;
 106         };
 107         stopvms;
 108         $meta->{errors} = $errors;
 109
 110         get_logger->info('Job result: ' . $meta->{result_text});
 111 }
 112
 113 sub process_job {
 114         my ($job) = @_;
 115         my $pb = db()->select('problems', '*', {id => $job->{problem}})->hash;
 116         my $meta = {
 117                 problem => $job->{problem},
 118                 files => {
 119                         prog => {
 120                                 name => 'prog.' . $job->{extension},
 121                                 format => $job->{format},
 122                                 content => $job->{source},
 123                         },
 124                 },
 125                 map { $_ => $pb->{$_} } qw/generator runner judge precnt testcnt timeout olimit/
 126         };
 127         my $timeout_override = db()->query('SELECT timeout FROM limits WHERE problem=? AND format=?', $job->{problem}, $job->{format})->list;
 128         $meta->{timeout} = $timeout_override if defined $timeout_override;
 129         $meta->{tests} = decode_json $pb->{tests} if $meta->{runner} eq 'File';
 130         $job->{contest} &&= contest_entry($job->{contest});
 131         delete $meta->{precnt} unless $job->{contest} && $job->{contest}{started} && !$job->{contest}{finished}; ## no critic (ProhibitNegativeExpressionsInUnlessAndUntilConditions)
 132         $meta->{testcnt} = $meta->{precnt} if $meta->{precnt};
 133
 134         $meta->{files}{ver} = {
 135                 name => 'ver.' . FORMAT_EXTENSION->{$pb->{verformat}},
 136                 format => $pb->{verformat},
 137                 content => $pb->{versource},
 138         } if $pb->{verformat};
 139
 140         process $meta;
 141
 142         $meta->{result_text} .= ' (pretests)' if $meta->{precnt};
 143         finish_job($job, $job->{private} || $pb->{private},
 144           result => $meta->{result},
 145           result_text => $meta->{result_text},
 146           ($meta->{results} ? (results => encode_json $meta->{results}) : ()),
 147           $meta->{errors} ? (errors => $meta->{errors}) : ());
 148 }
 149
 150 sub got_job{
 151         my $job = $_[0];
 152         my $id = $job->{id};
 153         get_logger->debug("Processing job $id...");
 154         process_job $job;
 155         get_logger->debug("Job $id done");
 156 }
 157
 158 my $daemon = hostname . ":$$";
 159
 160 sub run{
 161         require Gruntmaster::Data;
 162         Gruntmaster::Data->import;
 163         dbinit($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');
 164         Log::Log4perl->init('/etc/gruntmasterd/gruntmasterd-log.conf');
 165         get_logger->info("gruntmasterd $VERSION started ($daemon)");
 166         my $dir = tempdir 'gruntmasterd.XXXX', CLEANUP => 1, TMPDIR => 1;
 167         chmod 0711, $dir;
 168         chdir $dir;
 169         while (1) {
 170                 my $job = take_job($daemon);
 171                 got_job $job if defined $job;
 172                 sleep 2 unless defined $job;
 173         }
 174 }
 175
 176 1;
 177 __END__
 178
 179 =head1 NAME
 180
 181 Gruntmaster::Daemon - Gruntmaster 6000 Online Judge -- daemon
 182
 183 =head1 SYNOPSIS
 184
 185   use Gruntmaster::Daemon;
 186   Gruntmaster::Daemon->run;
 187
 188 =head1 DESCRIPTION
 189
 190 Gruntmaster::Daemon is the daemon component of the Gruntmaster 6000 online judge.
 191
 192 =head1 AUTHOR
 193
 194 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 195
 196 =head1 COPYRIGHT AND LICENSE
 197
 198 Copyright (C) 2014 by Marius Gavrilescu
 199
 200 This library is free software: you can redistribute it and/or modify
 201 it under the terms of the GNU Affero General Public License as published by
 202 the Free Software Foundation, either version 3 of the License, or
 203 (at your option) any later version.
 204
 205
 206 =cut