lib/Gruntmaster/Daemon.pm

   1 package Gruntmaster::Daemon;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '5999.000_004';
   8
   9 use Gruntmaster::Daemon::Constants qw/ERR/;
  10 use Gruntmaster::Daemon::Format qw/prepare_files stopvms/;
  11
  12 use File::Temp qw/tempdir/;
  13 use JSON qw/decode_json encode_json/;
  14 use Sys::Hostname qw/hostname/;
  15 use Time::HiRes qw/time/;
  16 use Try::Tiny;
  17 use Log::Log4perl qw/get_logger/;
  18
  19 use constant FORMAT_EXTENSION => {
  20         C => 'c',
  21         CPP => 'cpp',
  22         GCCGO => 'go',
  23         GOLANG => 'go',
  24         HASKELL => 'hs',
  25         MONO => 'cs',
  26         JAVA => 'java',
  27         PASCAL => 'pas',
  28         PERL => 'pl',
  29         PYTHON => 'py',
  30 };
  31
  32 ##################################################
  33
  34 my $db;
  35
  36 sub safe_can {
  37         my ($type, $sub, $name) = @_;
  38
  39         get_logger->logdie("Invalid \l$type: '$name'") unless $name =~ /^\w+$/s;
  40         my $pkg = __PACKAGE__ . "::${type}::${name}";
  41         eval "require $pkg" or get_logger->warn("Error while requiring $pkg: $@");
  42         $pkg->can($sub) or get_logger->logdie("No such \l$type: '$name'");
  43 }
  44
  45 sub process{
  46         my ($meta) = @_;
  47
  48         my @results;
  49         my @full_results = ();
  50         our $errors = '';
  51         try {
  52                 prepare_files $meta;
  53                 chomp $errors;
  54
  55                 my ($files, $generator, $runner, $judge, $testcnt) = map { $meta->{$_} or die "Required parameter missing: $_\n"} qw/files generator runner judge testcnt/;
  56
  57                 $generator = safe_can Generator => generate => $generator;
  58                 $runner = safe_can Runner => run => $runner;
  59                 $judge = safe_can Judge => judge => $judge;
  60
  61                 for my $test (1 .. $testcnt) {
  62                         my $start_time = time;
  63                         my $result;
  64                         try {
  65                                 $generator->($test, $meta);
  66                                 $result = $runner->($test, $meta);
  67                         } catch {
  68                                 $result = $_;
  69                                 unless (ref $result) {
  70                                         chomp $result;
  71                                         $result = [ERR, $result];
  72                                 }
  73                         };
  74
  75                         if (ref $result) {
  76                                 get_logger->trace("Test $test result is " . $result->[1]);
  77                                 push @full_results, {id => $test, result => $result->[0], result_text => $result->[1], time => time - $start_time}
  78                         } else {
  79                                 get_logger->trace("Test $test result is $result");
  80                                 push @full_results, {id => $test, result => 0, result_text => $result, time => time - $start_time}
  81                         }
  82                         push @results, $result;
  83                         last if $meta->{judge} eq 'Absolute' && ref $result
  84                 }
  85
  86                 my %results = $judge->(@results);
  87                 $meta->{$_} = $results{$_} for keys %results;
  88                 $meta->{results} = \@full_results
  89         } catch {
  90                 s/(.*) at .*/$1/s;
  91                 chomp;
  92                 $meta->{result} = -1;
  93                 $meta->{result_text} = $_;
  94         };
  95         stopvms;
  96         $meta->{errors} = $errors;
  97
  98         get_logger->info('Job result: ' . $meta->{result_text});
  99 }
 100
 101 sub process_job {
 102         my ($job) = @_;
 103         my $meta = {
 104                 problem => $job->problem->id,
 105                 files => {
 106                         prog => {
 107                                 name => 'prog.' . $job->extension,
 108                                 format => $job->format,
 109                                 content => $job->source,
 110                         },
 111                 },
 112                 map { $_ => $job->problem->get_column($_) } qw/generator runner judge precnt testcnt timeout olimit/
 113         };
 114         $meta->{tests} = decode_json $job->problem->tests if $meta->{runner} eq 'File';
 115         delete $meta->{precnt} if $job->problem->is_in_archive;
 116         $meta->{testcnt} = $meta->{precnt} if $meta->{precnt};
 117
 118         $meta->{files}{ver} = {
 119                 name => 'ver.' . FORMAT_EXTENSION->{$job->problem->verformat},
 120                 format => $job->problem->verformat,
 121                 content => $job->problem->versource,
 122         } if $job->problem->verformat;
 123
 124         process $meta;
 125
 126         $meta->{result_text} .= ' (pretests)' if $meta->{precnt};
 127         $job->update({
 128                 result => $meta->{result},
 129                 result_text => $meta->{result_text},
 130                 ($meta->{results} ? (results => encode_json $meta->{results}) : ()),
 131                 $meta->{errors} ? (errors => $meta->{errors}) : ()
 132         });
 133
 134         my $solved = $meta->{result} ? 0 : 1;
 135         my $status = $db->problem_statuses->find($job->owner, $job->problem);
 136         $db->problem_statuses->update_or_create({
 137                 problem => $job->problem,
 138                 owner   => $job->owner,
 139                 job     => $job->id,
 140                 solved  => $solved}) if !$job->problem->is_private;
 141 }
 142
 143 sub got_job{
 144         my $job = $_[0];
 145         my $id = $job->id;
 146         get_logger->debug("Taking job $id...");
 147         my $daemon = hostname . ":$$";
 148         $job->update({daemon => $daemon}, {where => {daemon => undef}})->discard_changes;
 149         if ($job->daemon eq $daemon) {
 150                 get_logger->debug("Succesfully taken job $id");
 151                 process_job $job;
 152                 get_logger->debug("Job $id done");
 153         } else {
 154                 get_logger->debug("Job $id already taken by " . $job->daemon);
 155         }
 156 }
 157
 158 sub run{
 159         require Gruntmaster::Data;
 160         $db = Gruntmaster::Data->connect($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');
 161         Log::Log4perl->init('/etc/gruntmasterd/gruntmasterd-log.conf');
 162         get_logger->info("gruntmasterd $VERSION started");
 163         my $dir = tempdir 'gruntmasterd.XXXX', CLEANUP => 1, TMPDIR => 1;
 164         chmod 0711, $dir;
 165         chdir $dir;
 166         while (1) {
 167                 my $job = $db->jobs->search({daemon => undef}, {rows => 1})->first;
 168                 got_job $job if defined $job;
 169                 sleep 2 unless defined $job;
 170         }
 171 }
 172
 173 1;
 174 __END__
 175
 176 =head1 NAME
 177
 178 Gruntmaster::Daemon - Gruntmaster 6000 Online Judge -- daemon
 179
 180 =head1 SYNOPSIS
 181
 182   use Gruntmaster::Daemon;
 183   Gruntmaster::Daemon->run;
 184
 185 =head1 DESCRIPTION
 186
 187 Gruntmaster::Daemon is the daemon component of the Gruntmaster 6000 online judge.
 188
 189 =head1 AUTHOR
 190
 191 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 192
 193 =head1 COPYRIGHT AND LICENSE
 194
 195 Copyright (C) 2014 by Marius Gavrilescu
 196
 197 This library is free software: you can redistribute it and/or modify
 198 it under the terms of the GNU Affero General Public License as published by
 199 the Free Software Foundation, either version 3 of the License, or
 200 (at your option) any later version.
 201
 202
 203 =cut