lib/Gruntmaster/Daemon/Format.pm

   1 package Gruntmaster::Daemon::Format;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6 use parent qw/Exporter/;
   7 no if $] > 5.017011, warnings => 'experimental::smartmatch';
   8
   9 use POSIX qw//;
  10 use File::Basename qw/fileparse/;
  11 use Gruntmaster::Daemon::Constants qw/TLE OLE DIED NZX/;
  12 use Time::HiRes qw/alarm/;
  13 use List::MoreUtils qw/natatime/;
  14 use IPC::Signal qw/sig_name sig_num/;
  15
  16 our $VERSION = '0.001';
  17 our @EXPORT_OK = qw/mkrun/;
  18
  19 ##################################################
  20
  21 sub command_and_args{
  22         my ($format, $basename) = @_;
  23
  24         given($format) {
  25                 "./$basename" when [qw/C CPP PASCAL/];
  26                 "./$basename.exe" when 'MONO';
  27                 "java $basename" when 'JAVA';
  28                 "perl $basename" when 'PERL';
  29                 "python $basename" when 'PYTHON';
  30                 default { die "Don't know how to execute format $format" }
  31         }
  32 }
  33
  34 sub mkrun{
  35         my $format = shift;
  36         sub{
  37                 my ($name, %args) = @_;
  38                 my $basename = fileparse $name, qr/\.[^.]*/;
  39                 my $ret = fork // die 'Cannot fork';
  40                 if ($ret) {
  41                         my $tle;
  42                         local $SIG{ALRM} = sub { kill KILL => $ret; $tle = 1};
  43                         alarm $args{timeout} if exists $args{timeout};
  44                         wait;
  45                         alarm 0;
  46                         my $sig = $? & 127;
  47                         my $signame = sig_name $sig;
  48                         die [TLE, "Time Limit Exceeded"] if $tle;
  49                         die [OLE, 'Output Limit Exceeded'] if $sig && $signame eq 'XFSZ';
  50                         die [DIED, "Crash (SIG$signame)"] if $sig;
  51                         die [NZX, "Non-zero exit status: " . ($? >> 8)] if $?;
  52                 } else {
  53                         my @fds = exists $args{fds} ? @{$args{fds}} : ();
  54                         $^F = 50;
  55                         POSIX::close $_ for 0 .. $^F;
  56                         my $it = natatime 2, @fds;
  57                         while (my ($fd, $file) = $it->()) {
  58                                 open my $fh, $file or die $!;
  59                                 my $oldfd = fileno $fh;
  60                                 if ($oldfd != $fd) {
  61                                         POSIX::dup2 $oldfd, $fd or die $!;
  62                                         POSIX::close $oldfd or die $!;
  63                                 }
  64                         }
  65                         exec 'gruntmaster-exec', $args{mlimit} // 0, $args{olimit} // 0, command_and_args($format, $basename), exists $args{args} ? @{$args{args}} : ();
  66                         exit 42
  67                 }
  68         }
  69 }
  70
  71 1