[gruntmaster-data.git] / gruntmaster-problem

#!/usr/bin/perl -w
use v5.14;

use Gruntmaster::Data;

use File::Temp qw/tempfile/;

use IO::Prompter [ -style => 'bold', '-stdio', '-verbatim' ];
use File::Slurp qw/read_file write_file/;
use JSON qw/decode_json encode_json/;
use List::Util qw/max min/;
use Term::ANSIColor qw/RED RESET/;
use Getopt::Long qw/:config require_order/;

use constant LEVEL_VALUES => {
	beginner => 100,
	easy => 250,
	medium => 500,
	hard => 1000,
};

##################################################

my $dsn = $ENV{GRUNTMASTER_DSN} // 'dbi:Pg:';
my $db = Gruntmaster::Data->connect($dsn);

sub cmd_help{
	exec perldoc => $0
}

sub cmd_add{
	my $id = shift;
	my $name = prompt 'Problem name';
	my $private = prompt('Private?', '-yn') eq 'y';
	my $contest = prompt 'Contest';
	my $author = prompt 'Problem author (full name)';
	my $writer = prompt 'Problem statement writer (full name)';
	my $owner = prompt 'Problem owner (username)';
	my $level = prompt 'Problem level', -menu => "beginner\neasy\nmedium\nhard";
	my $value = LEVEL_VALUES->{$level};
	my $statement = read_file prompt 'File with problem statement', -complete => 'filenames';
	my $generator = prompt 'Generator', -menu => "File\nRun\nUndef";
	my $runner = prompt 'Runner', -menu => "File\nVerifier\nInteractive";
	my $judge = prompt 'Judge', -menu => "Absolute\nPoints";
	my $testcnt = prompt 'Test count', '-i';

	my $timeout = prompt 'Time limit (seconds)', '-n';
	my $olimit = prompt 'Output limit (bytes)', '-i';
	say 'Memory limits are broken, so I won\'t ask you for one';

	my (@tests, $gensource, $genformat, $versource, $verformat);

	if ($generator eq 'Run') {
		$gensource = read_file prompt, '[Generator::Run] Generator file name', -complete => 'filenames';
		$genformat = prompt '[Generator::Run] Generator format', -menu => [qw/C CPP MONO JAVA PASCAL PERL PYTHON/];
	}

	if ($runner eq 'File') {
		my $default = $judge eq 'Points' ? 10 : 'Ok';
		$tests[$_ - 1] = prompt "[Runner::File] Score for test ${_} [$default]", -default => $default for 1 .. $testcnt;
	}

	if ($runner eq 'Verifier' || $runner eq 'Interactive') {
		say RED, 'WARNING: Runner::Interactive is experimental', RESET if $runner eq 'Interactive';
		$versource = prompt "[Runner::$runner] Verifier file name", -complete => 'filenames';
		$verformat = prompt "[Runner::$runner] Verifier format", -menu => [qw/C CPP MONO JAVA PASCAL PERL PYTHON/];
	}

	my %options = (
		id => $id,
		name => $name,
		level => $level,
		value => $value,
		statement => $statement,
		author => $author,
		writer => $writer,
		owner => $owner,
		generator => $generator,
		runner => $runner,
		judge => $judge,
		testcnt => $testcnt,
	);
	$options{private} = $private if $private;
	$options{timeout} = $timeout if $timeout;
	$options{olimit} = $olimit if $olimit;
	$options{tests} = encode_json \@tests if @tests;
	$options{gensource} = $gensource if $gensource;
	$options{genformat} = $genformat if $genformat;
	$options{versource} = $versource if $versource;
	$options{verformat} = $verformat if $verformat;
	$db->problems->create (\%options);

	$db->contest_problems->create({problem => $id, contest => $contest}) if $contest;
}

sub cmd_set{
	my $file;
	GetOptions ( 'file!' => \$file );
	my ($id, %values) = @ARGV;
	%values = map { $_ => scalar read_file $values{$_} } keys %values if $file;
	$db->problem($id)->update(\%values);
}

sub cmd_get{
	my ($id, $col) = @_;
	say $db->problem($id)->get_column($col)
}

sub cmd_edit{
	my ($id, $col) = @_;
	my ($fh, $file) = tempfile 'gruntmaster-problem-editXXXX', TMPDIR => 1, UNLINK => 1;
	write_file $fh, $db->problem($id)->get_column($col);
	close $fh;
	my $editor = $ENV{EDITOR} // 'editor';
	system $editor, $file;
	$db->problem($id)->update({$col => scalar read_file $file}) or die "$!";
}

sub cmd_list{
	local $, = "\n";
	say map {$_->id} $db->problems->all
}

sub cmd_rm{
	my ($id) = @_;
	$db->problem($id)->delete;
}

sub cmd_show{
	my %columns = $db->problem(shift)->get_columns;
	print <<END
Name: $columns{name}
Author: $columns{author}
Statement written by: $columns{writer}
Owner: $columns{owner}
Level: $columns{level}
Output limit: $columns{olimit}
Time limit: $columns{timeout}
Test count: $columns{testcnt}
Generator: $columns{generator}
Runner: $columns{runner}
Judge: $columns{judge}
Private: $columns{private}
END
}

sub cmd_check {
	my ($id) = @_;
	my @jobs = $db->jobs->search({problem => $id, reference => { '!=', undef }})->all;
	say 'Rerunning ' . @jobs . ' reference jobs...';
	$_->rerun for @jobs;
	sleep 1 while $db->jobs->search({problem => $id, result_text => undef})->count;

	my (@good_times, @fail_times, $fail);

	for (@jobs) {
		$_->discard_changes;
		my @times = map { $_->{time} } @{decode_json $_->results};
		push @good_times, @times if $_->reference == 0;
		push @fail_times, @times if $_->reference == 3;
		if ($_->result == $_->reference) {
			say 'Job ' . $_->id . ' OK'
		} else {
			say 'Job ' . $_->id . ' got ' . $_->result . ' instead of ' . $_->reference;
			$fail = 1;
		}
	}

	say 'Max time for AC: ' . max @good_times if @good_times;
	say 'Min time for TLE: ' . min @fail_times if @fail_times;
	say $fail ? 'Test failed' : 'Test successful';
	exit $fail if $fail;
}

##################################################

my $cmd = 'cmd_' . shift;
cmd_help unless exists $main::{$cmd};
no strict 'refs';
$cmd->(@ARGV);

1;
__END__

=encoding utf-8

=head1 NAME

gruntmaster-problem - shell interface to Gruntmaster 6000 problems

=head1 SYNOPSIS

  gruntmaster-problem add problem_id
  gruntmaster-problem list
  gruntmaster-problem rm problem_id
  gruntmaster-problem show problem_id
  gruntmaster-problem set [--file] problem_id key value
  gruntmaster-problem get problem_id key
  gruntmaster-problem edit problem_id key

=head1 DESCRIPTION

gruntmaster-problem is a tool for managing problems.

=over

=item B<list>

Prints the list of problems in the selected contest.

=item B<show> I<id>

Prints detailed information about problem I<id>.

=item B<add> I<id>

Adds a new problem with id I<id>.

=item B<rm> I<id>

Removes the problem with id I<id>.

=item B<set> I<id> I<key> I<value>

Sets the I<key> configuration option of problem I<id> to I<value>.

=item B<get> I<id> I<key>

Get the value of the I<key> configuration option of problem I<id>

=item B<edit> I<id> I<key>

Opens an editor with the value of the I<key> configuration option. After the editor exits, the option is updated to the value of the file.

=item B<set> --file I<id> I<key> I<file>

Sets the I<key> configuration option of problem I<id> to the contents of the file I<file>.

=back

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.18.1 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
014ee8a6 MG	1	#!/usr/bin/perl -w
	2	use v5.14;
	3
	4	use Gruntmaster::Data;
014ee8a6	5
ca77adce MG	6	use File::Temp qw/tempfile/;
ca77adce MG	7
014ee8a6	8	use IO::Prompter [ -style => 'bold', '-stdio', '-verbatim' ];
ca77adce	9	use File::Slurp qw/read_file write_file/;
a8d27955 MG	10	use JSON qw/decode_json encode_json/;
a8d27955 MG	11	use List::Util qw/max min/;
014ee8a6	12	use Term::ANSIColor qw/RED RESET/;
0d2f8987	13	use Getopt::Long qw/:config require_order/;
014ee8a6	14
aaa9eb7d MG	15	use constant LEVEL_VALUES => {
	16	beginner => 100,
	17	easy => 250,
	18	medium => 500,
	19	hard => 1000,
	20	};
	21
014ee8a6 MG	22	##################################################
014ee8a6 MG	23
30e287c3 MG	24	my $dsn = $ENV{GRUNTMASTER_DSN} // 'dbi:Pg:';
30e287c3 MG	25	my $db = Gruntmaster::Data->connect($dsn);
014ee8a6 MG	26
	27	sub cmd_help{
	28	exec perldoc => $0
	29	}
	30
014ee8a6 MG	31	sub cmd_add{
	32	my $id = shift;
	33	my $name = prompt 'Problem name';
646feed4	34	my $private = prompt('Private?', '-yn') eq 'y';
756368d0	35	my $contest = prompt 'Contest';
014ee8a6	36	my $author = prompt 'Problem author (full name)';
6544497e	37	my $writer = prompt 'Problem statement writer (full name)';
014ee8a6 MG	38	my $owner = prompt 'Problem owner (username)';
014ee8a6 MG	39	my $level = prompt 'Problem level', -menu => "beginner\neasy\nmedium\nhard";
aaa9eb7d	40	my $value = LEVEL_VALUES->{$level};
014ee8a6	41	my $statement = read_file prompt 'File with problem statement', -complete => 'filenames';
cd25d613 MG	42	my $generator = prompt 'Generator', -menu => "File\nRun\nUndef";
	43	my $runner = prompt 'Runner', -menu => "File\nVerifier\nInteractive";
	44	my $judge = prompt 'Judge', -menu => "Absolute\nPoints";
	45	my $testcnt = prompt 'Test count', '-i';
014ee8a6	46
cd25d613 MG	47	my $timeout = prompt 'Time limit (seconds)', '-n';
cd25d613 MG	48	my $olimit = prompt 'Output limit (bytes)', '-i';
014ee8a6 MG	49	say 'Memory limits are broken, so I won\'t ask you for one';
014ee8a6 MG	50
756368d0	51	my (@tests, $gensource, $genformat, $versource, $verformat);
014ee8a6	52
756368d0 MG	53	if ($generator eq 'Run') {
	54	$gensource = read_file prompt, '[Generator::Run] Generator file name', -complete => 'filenames';
	55	$genformat = prompt '[Generator::Run] Generator format', -menu => [qw/C CPP MONO JAVA PASCAL PERL PYTHON/];
014ee8a6 MG	56	}
014ee8a6 MG	57
756368d0 MG	58	if ($runner eq 'File') {
	59	my $default = $judge eq 'Points' ? 10 : 'Ok';
	60	$tests[$_ - 1] = prompt "[Runner::File] Score for test ${_} [$default]", -default => $default for 1 .. $testcnt;
	61	}
014ee8a6	62
756368d0 MG	63	if ($runner eq 'Verifier' \|\| $runner eq 'Interactive') {
	64	say RED, 'WARNING: Runner::Interactive is experimental', RESET if $runner eq 'Interactive';
	65	$versource = prompt "[Runner::$runner] Verifier file name", -complete => 'filenames';
	66	$verformat = prompt "[Runner::$runner] Verifier format", -menu => [qw/C CPP MONO JAVA PASCAL PERL PYTHON/];
014ee8a6 MG	67	}
014ee8a6 MG	68
4af36605	69	my %options = (
756368d0	70	id => $id,
646feed4 MG	71	name => $name,
646feed4 MG	72	level => $level,
aaa9eb7d	73	value => $value,
646feed4 MG	74	statement => $statement,
646feed4 MG	75	author => $author,
6544497e	76	writer => $writer,
646feed4 MG	77	owner => $owner,
	78	generator => $generator,
	79	runner => $runner,
	80	judge => $judge,
	81	testcnt => $testcnt,
4af36605 MG	82	);
	83	$options{private} = $private if $private;
	84	$options{timeout} = $timeout if $timeout;
	85	$options{olimit} = $olimit if $olimit;
	86	$options{tests} = encode_json \@tests if @tests;
	87	$options{gensource} = $gensource if $gensource;
	88	$options{genformat} = $genformat if $genformat;
	89	$options{versource} = $versource if $versource;
	90	$options{verformat} = $verformat if $verformat;
	91	$db->problems->create (\%options);
756368d0 MG	92
756368d0 MG	93	$db->contest_problems->create({problem => $id, contest => $contest}) if $contest;
014ee8a6 MG	94	}
	95
	96	sub cmd_set{
	97	my $file;
	98	GetOptions ( 'file!' => \$file );
866602c7	99	my ($id, %values) = @ARGV;
014ee8a6	100	%values = map { $_ => scalar read_file $values{$_} } keys %values if $file;
edfc5928	101	$db->problem($id)->update(\%values);
014ee8a6 MG	102	}
014ee8a6 MG	103
5214523a	104	sub cmd_get{
4af36605	105	my ($id, $col) = @_;
5214523a MG	106	say $db->problem($id)->get_column($col)
	107	}
	108
ca77adce MG	109	sub cmd_edit{
	110	my ($id, $col) = @_;
	111	my ($fh, $file) = tempfile 'gruntmaster-problem-editXXXX', TMPDIR => 1, UNLINK => 1;
	112	write_file $fh, $db->problem($id)->get_column($col);
	113	close $fh;
	114	my $editor = $ENV{EDITOR} // 'editor';
	115	system $editor, $file;
91f4171d	116	$db->problem($id)->update({$col => scalar read_file $file}) or die "$!";
ca77adce MG	117	}
ca77adce MG	118
014ee8a6 MG	119	sub cmd_list{
014ee8a6 MG	120	local $, = "\n";
4af36605	121	say map {$_->id} $db->problems->all
014ee8a6 MG	122	}
	123
	124	sub cmd_rm{
edfc5928 MG	125	my ($id) = @_;
edfc5928 MG	126	$db->problem($id)->delete;
014ee8a6 MG	127	}
	128
	129	sub cmd_show{
4af36605 MG	130	my %columns = $db->problem(shift)->get_columns;
	131	print <<END
	132	Name: $columns{name}
	133	Author: $columns{author}
	134	Statement written by: $columns{writer}
	135	Owner: $columns{owner}
	136	Level: $columns{level}
	137	Output limit: $columns{olimit}
	138	Time limit: $columns{timeout}
	139	Test count: $columns{testcnt}
	140	Generator: $columns{generator}
	141	Runner: $columns{runner}
	142	Judge: $columns{judge}
	143	Private: $columns{private}
	144	END
014ee8a6 MG	145	}
014ee8a6 MG	146
a8d27955 MG	147	sub cmd_check {
	148	my ($id) = @_;
	149	my @jobs = $db->jobs->search({problem => $id, reference => { '!=', undef }})->all;
	150	say 'Rerunning ' . @jobs . ' reference jobs...';
	151	$_->rerun for @jobs;
	152	sleep 1 while $db->jobs->search({problem => $id, result_text => undef})->count;
	153
	154	my (@good_times, @fail_times, $fail);
	155
	156	for (@jobs) {
	157	$_->discard_changes;
	158	my @times = map { $_->{time} } @{decode_json $_->results};
	159	push @good_times, @times if $_->reference == 0;
	160	push @fail_times, @times if $_->reference == 3;
	161	if ($_->result == $_->reference) {
	162	say 'Job ' . $_->id . ' OK'
	163	} else {
	164	say 'Job ' . $_->id . ' got ' . $_->result . ' instead of ' . $_->reference;
	165	$fail = 1;
	166	}
	167	}
	168
1cdb31fc MG	169	say 'Max time for AC: ' . max @good_times if @good_times;
1cdb31fc MG	170	say 'Min time for TLE: ' . min @fail_times if @fail_times;
a8d27955	171	say $fail ? 'Test failed' : 'Test successful';
1cdb31fc	172	exit $fail if $fail;
a8d27955 MG	173	}
a8d27955 MG	174
014ee8a6 MG	175	##################################################
014ee8a6 MG	176
014ee8a6 MG	177	my $cmd = 'cmd_' . shift;
	178	cmd_help unless exists $main::{$cmd};
	179	no strict 'refs';
756368d0	180	$cmd->(@ARGV);
014ee8a6 MG	181
	182	1;
	183	__END__
	184
	185	=encoding utf-8
	186
	187	=head1 NAME
	188
	189	gruntmaster-problem - shell interface to Gruntmaster 6000 problems
	190
	191	=head1 SYNOPSIS
	192
5214523a MG	193	gruntmaster-problem add problem_id
	194	gruntmaster-problem list
	195	gruntmaster-problem rm problem_id
	196	gruntmaster-problem show problem_id
	197	gruntmaster-problem set [--file] problem_id key value
	198	gruntmaster-problem get problem_id key
ca77adce	199	gruntmaster-problem edit problem_id key
014ee8a6 MG	200
	201	=head1 DESCRIPTION
	202
e90402be MG	203	gruntmaster-problem is a tool for managing problems.
e90402be MG	204
e90402be MG	205	=over
	206
	207	=item B<list>
	208
	209	Prints the list of problems in the selected contest.
	210
	211	=item B<show> I<id>
	212
	213	Prints detailed information about problem I<id>.
	214
	215	=item B<add> I<id>
	216
	217	Adds a new problem with id I<id>.
	218
	219	=item B<rm> I<id>
	220
	221	Removes the problem with id I<id>.
	222
	223	=item B<set> I<id> I<key> I<value>
	224
	225	Sets the I<key> configuration option of problem I<id> to I<value>.
	226
5214523a MG	227	=item B<get> I<id> I<key>
	228
	229	Get the value of the I<key> configuration option of problem I<id>
	230
ca77adce MG	231	=item B<edit> I<id> I<key>
	232
	233	Opens an editor with the value of the I<key> configuration option. After the editor exits, the option is updated to the value of the file.
	234
e90402be MG	235	=item B<set> --file I<id> I<key> I<file>
	236
	237	Sets the I<key> configuration option of problem I<id> to the contents of the file I<file>.
	238
	239	=back
	240
	241	=head1 AUTHOR
	242
	243	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	244
	245	=head1 COPYRIGHT AND LICENSE
	246
	247	Copyright (C) 2014 by Marius Gavrilescu
	248
4af36605 MG	249	This library is free software; you can redistribute it and/or modify
	250	it under the same terms as Perl itself, either Perl version 5.18.1 or,
	251	at your option, any later version of Perl 5 you may have available.
014ee8a6 MG	252
	253
	254	=cut