[gruntmaster-data.git] / lib / Gruntmaster / Data.pm

use utf8;
package Gruntmaster::Data;

# Created by DBIx::Class::Schema::Loader
# DO NOT MODIFY THE FIRST PART OF THIS FILE

use strict;
use warnings;

use base 'DBIx::Class::Schema';

__PACKAGE__->load_namespaces;


# Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg

our $VERSION = '5999.000_011';

use Lingua::EN::Inflect qw/PL_N/;
use JSON::MaybeXS qw/decode_json/;
use List::Util qw/sum/;
use PerlX::Maybe qw/maybe/;
use Sub::Name qw/subname/;

use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private statement timeout olimit value/];
use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
use constant JOBS_PER_PAGE => 10;

sub dynsub{
	our ($name, $sub) = @_;
	no strict 'refs'; ## no critic (Strict)
	*$name = subname $name => $sub
}

BEGIN {
	for my $rs (qw/contest contest_problem job open problem user/) {
		my $rsname = ucfirst $rs;
		$rsname =~ s/_([a-z])/\u$1/gs;
		dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
		dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
	}
}

sub calc_score{
	my ($mxscore, $time, $tries, $totaltime) = @_;
	my $score = $mxscore;
	$time = 0 if $time < 0;
	$time = 300 if $time > $totaltime;
	$score = ($totaltime - $time) / $totaltime * $score;
	$score -= $tries / 10 * $mxscore;
	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
	int $score + 0.5
}

sub standings {
	my ($self, $ct) = @_;
	$ct &&= $self->contest($ct);

	my @problems = map { $_->problem } $self->contest_problems->search({contest => $ct && $ct->id}, {qw/join problem order_by problem.level/});
	my (%scores, %tries);
	for my $job ($self->jobs->search({contest => $ct && $ct->id}, {order_by => 'id'})) {
		if ($ct) {
			my $open = $self->opens->find($ct->id, $job->problem->id, $job->owner->id);
			my $time = $job->date - ($open ? $open->time : $ct->start);
			next if $time < 0;
			my $value = $job->problem->value;
			my $factor = $job->result ? 0 : 1;
			$factor = $1 / 100 if $job->result_text =~ /^(\d+ )/s;
			$scores{$job->owner->id}{$job->problem->id} = int ($factor * calc_score ($value, $time, $tries{$job->owner->id}{$job->problem->id}++, $ct->stop - $ct->start));
		} else {
			no warnings 'numeric'; ## no critic (ProhibitNoWarnings)
			$scores{$job->owner->id}{$job->problem->id} = 0 + $job->result_text || ($job->result ? 0 : 100)
		}
	}

	my @st = sort { $b->{score} <=> $a->{score} or $a->{user}->id cmp $b->{user}->id} map { ## no critic (ProhibitReverseSortBlock)
		my $user = $_;
		+{
			user => $self->user($user),
			score => sum (values %{$scores{$user}}),
			scores => [map { $scores{$user}{$_->id} // '-'} @problems],
			problems => $ct,
		}
	} keys %scores;

	$st[0]->{rank} = 1;
	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
	@st
}

sub user_list {
	my $rs = $_[0]->users->search(undef, {order_by => 'name', columns => USER_PUBLIC_COLUMNS});
	[ map { { $_->get_columns } } $rs->all ]
}

sub user_entry {
	my ($self, $id) = @_;
	+{ $self->users->find($id, {columns => USER_PUBLIC_COLUMNS})->get_columns }
}

sub problem_list {
	my ($self, %args) = @_;
	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
	$rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest};
	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	my %params;
	$params{contest} = $args{contest} if $args{contest};
	for ($rs->all) {
		$params{$_->level} //= [];
		push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
	}
	\%params
}

sub problem_entry {
	my ($self, $id, $contest, $user) = @_;
	my $pb = $self->problems->find($id, {columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
	my $running = $contest && $self->contest($contest)->is_running;
	eval { ## no critic (RequireCheckingReturnValueOfEval)
		$self->opens->create({
			contest => $contest,
			problem => $id,
			owner => $user,
			time => time,
		})
	} if $running;
	$contest &&= $self->contest($contest);
	+{ $pb->get_columns, owner_name => $pb->owner->name, cansubmit => $contest ? $running : 1, $running ? (contest_start => $contest->start, contest_stop => $contest->stop) : () }
}

sub contest_list {
	my ($self, %args) = @_;
	my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
	my %params;
	for ($rs->all) {
		my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
		$params{$state} //= [];
		push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
	}
	\%params
}

sub contest_entry {
	my ($self, $id) = @_;
	my $ct = $self->contest($id);
	+{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
}

sub job_list {
	my ($self, %args) = @_;
	$args{page} //= 1;
	my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
	$rs = $rs->search({'me.owner' => $args{owner}})   if $args{owner};
	$rs = $rs->search({contest    => $args{contest}}) if $args{contest};
	$rs = $rs->search({problem    => $args{problem}}) if $args{problem};
	return {
		log => [map {
			my %params = $_->get_columns;
			$params{owner_name}   = $_->owner->name;
			$params{problem_name} = $_->problem->name;
			$params{results} &&= decode_json $params{results};
			$params{size}      = length $params{source};
			delete $params{source};
			\%params
		} $rs->all],
		current_page => $rs->pager->current_page,
		maybe previous_page => $rs->pager->previous_page,
		maybe next_page => $rs->pager->next_page,
		maybe last_page => $rs->pager->last_page,
	}
}

sub job_entry {
	my ($self, $id) = @_;
	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner']});
	my %params = $job->get_columns;
	$params{owner_name}   = $job->owner->name;
	$params{problem_name} = $job->problem->name;
	$params{results} &&= decode_json $params{results};
	$params{size}      = length $params{source};
	delete $params{source};
	\%params
}

1;

__END__

=encoding utf-8

=head1 NAME

Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools

=head1 SYNOPSIS

  my $db = Gruntmaster::Data->connect('dbi:Pg:');

  my $problem = $db->problem('my_problem');
  $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
  $problem->rerun; # And rerun all jobs for this problem

  # ...

  my $contest = $db->contests->create({ # Create a new contest
    id => 'my_contest',
    name => 'My Awesome Contest',
    start => time + 100,
    end => time + 1900,
  });
  $db->contest_problems->create({ # Add a problem to the contest
    contest => 'my_contest',
    problem => 'my_problem',
  });

  say 'The contest has not started yet' if $contest->is_pending;

  # ...

  my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
  $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest

=head1 DESCRIPTION

Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.

In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:

=over

=item contests

Equivalent to C<< $schema->resultset('Contest') >>

=item contest_problems

Equivalent to C<< $schema->resultset('ContestProblem') >>

=item jobs

Equivalent to C<< $schema->resultset('Job') >>

=item problems

Equivalent to C<< $schema->resultset('Problem') >>

=item users

Equivalent to C<< $schema->resultset('User') >>

=item contest($id)

Equivalent to C<< $schema->resultset('Contest')->find($id) >>

=item job($id)

Equivalent to C<< $schema->resultset('Job')->find($id) >>

=item problem($id)

Equivalent to C<< $schema->resultset('Problem')->find($id) >>

=item user($id)

Equivalent to C<< $schema->resultset('User')->find($id) >>

=item user_list

Returns a list of users as an arrayref containing hashrefs.

=item user_entry($id)

Returns a hashref with information about the user $id.

=item problem_list([%args])

Returns a list of problems grouped by level. A hashref with levels as keys.

Takes the following arguments:

=over

=item owner

Only show problems owned by this user

=item contest

Only show problems in this contest

=back

=item problem_entry($id, [$contest, $user])

Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.

=item contest_list([%args])

Returns a list of contests grouped by state. A hashref with the following keys:

=over

=item pending

An arrayref of hashrefs representing pending contests

=item running

An arrayref of hashrefs representing running contests

=item finished

An arrayref of hashrefs representing finished contests

=back

Takes the following arguments:

=over

=item owner

Only show contests owned by this user.

=back

=item contest_entry($id)

Returns a hashref with information about the contest $id.

=item job_list([%args])

Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:

=over

=item owner

Only show jobs submitted by this user.

=item contest

Only show jobs submitted in this contest.

=item problem

Only show jobs submitted for this problem.

=item page

Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.

=back

=item job_entry($id)

Returns a hashref with information about the job $id.

=back

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.18.1 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
4ed3f8e7	1	use utf8;
bbf8209c	2	package Gruntmaster::Data;
4ed3f8e7 MG	3
	4	# Created by DBIx::Class::Schema::Loader
	5	# DO NOT MODIFY THE FIRST PART OF THIS FILE
	6
	7	use strict;
bbf8209c	8	use warnings;
014ee8a6	9
4ed3f8e7 MG	10	use base 'DBIx::Class::Schema';
	11
	12	__PACKAGE__->load_namespaces;
014ee8a6	13
f7386aab	14
4ed3f8e7 MG	15	# Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
	16	# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
	17
347ea1e4	18	our $VERSION = '5999.000_011';
4ed3f8e7 MG	19
4ed3f8e7 MG	20	use Lingua::EN::Inflect qw/PL_N/;
91203bd5	21	use JSON::MaybeXS qw/decode_json/;
15a021b7	22	use List::Util qw/sum/;
3473324b	23	use PerlX::Maybe qw/maybe/;
4ed3f8e7	24	use Sub::Name qw/subname/;
014ee8a6	25
de625c9b MG	26	use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private statement timeout olimit value/];
	27	use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
	28	use constant JOBS_PER_PAGE => 10;
	29
014ee8a6	30	sub dynsub{
fb6a4e3d	31	our ($name, $sub) = @_;
dcd72991	32	no strict 'refs'; ## no critic (Strict)
fb6a4e3d	33	*$name = subname $name => $sub
014ee8a6 MG	34	}
	35
	36	BEGIN {
4ed3f8e7 MG	37	for my $rs (qw/contest contest_problem job open problem user/) {
4ed3f8e7 MG	38	my $rsname = ucfirst $rs;
dcd72991	39	$rsname =~ s/_([a-z])/\u$1/gs;
4ed3f8e7 MG	40	dynsub PL_N($rs) => sub { $_[0]->resultset($rsname) };
4ed3f8e7 MG	41	dynsub $rs => sub { $_[0]->resultset($rsname)->find($_[1]) };
014ee8a6 MG	42	}
	43	}
	44
15a021b7 MG	45	sub calc_score{
	46	my ($mxscore, $time, $tries, $totaltime) = @_;
	47	my $score = $mxscore;
	48	$time = 0 if $time < 0;
	49	$time = 300 if $time > $totaltime;
	50	$score = ($totaltime - $time) / $totaltime * $score;
	51	$score -= $tries / 10 * $mxscore;
	52	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
	53	int $score + 0.5
	54	}
	55
	56	sub standings {
	57	my ($self, $ct) = @_;
	58	$ct &&= $self->contest($ct);
	59
	60	my @problems = map { $_->problem } $self->contest_problems->search({contest => $ct && $ct->id}, {qw/join problem order_by problem.level/});
	61	my (%scores, %tries);
	62	for my $job ($self->jobs->search({contest => $ct && $ct->id}, {order_by => 'id'})) {
	63	if ($ct) {
	64	my $open = $self->opens->find($ct->id, $job->problem->id, $job->owner->id);
	65	my $time = $job->date - ($open ? $open->time : $ct->start);
	66	next if $time < 0;
aaa9eb7d	67	my $value = $job->problem->value;
15a021b7	68	my $factor = $job->result ? 0 : 1;
dcd72991	69	$factor = $1 / 100 if $job->result_text =~ /^(\d+ )/s;
15a021b7 MG	70	$scores{$job->owner->id}{$job->problem->id} = int ($factor * calc_score ($value, $time, $tries{$job->owner->id}{$job->problem->id}++, $ct->stop - $ct->start));
15a021b7 MG	71	} else {
dcd72991	72	no warnings 'numeric'; ## no critic (ProhibitNoWarnings)
15a021b7 MG	73	$scores{$job->owner->id}{$job->problem->id} = 0 + $job->result_text \|\| ($job->result ? 0 : 100)
	74	}
	75	}
	76
dcd72991	77	my @st = sort { $b->{score} <=> $a->{score} or $a->{user}->id cmp $b->{user}->id} map { ## no critic (ProhibitReverseSortBlock)
15a021b7 MG	78	my $user = $_;
	79	+{
	80	user => $self->user($user),
35596ea8	81	score => sum (values %{$scores{$user}}),
15a021b7 MG	82	scores => [map { $scores{$user}{$_->id} // '-'} @problems],
	83	problems => $ct,
	84	}
	85	} keys %scores;
	86
	87	$st[0]->{rank} = 1;
	88	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
	89	@st
	90	}
	91
de625c9b MG	92	sub user_list {
de625c9b MG	93	my $rs = $_[0]->users->search(undef, {order_by => 'name', columns => USER_PUBLIC_COLUMNS});
dcd72991	94	[ map { { $_->get_columns } } $rs->all ]
de625c9b MG	95	}
	96
	97	sub user_entry {
	98	my ($self, $id) = @_;
	99	+{ $self->users->find($id, {columns => USER_PUBLIC_COLUMNS})->get_columns }
	100	}
	101
	102	sub problem_list {
	103	my ($self, %args) = @_;
	104	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
	105	$rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest};
	106	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
	107	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	108	my %params;
	109	$params{contest} = $args{contest} if $args{contest};
	110	for ($rs->all) {
	111	$params{$_->level} //= [];
35596ea8	112	push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
de625c9b MG	113	}
	114	\%params
	115	}
	116
	117	sub problem_entry {
	118	my ($self, $id, $contest, $user) = @_;
	119	my $pb = $self->problems->find($id, {columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
	120	my $running = $contest && $self->contest($contest)->is_running;
dcd72991	121	eval { ## no critic (RequireCheckingReturnValueOfEval)
de625c9b MG	122	$self->opens->create({
	123	contest => $contest,
	124	problem => $id,
	125	owner => $user,
	126	time => time,
	127	})
	128	} if $running;
2431260b MG	129	$contest &&= $self->contest($contest);
2431260b MG	130	+{ $pb->get_columns, owner_name => $pb->owner->name, cansubmit => $contest ? $running : 1, $running ? (contest_start => $contest->start, contest_stop => $contest->stop) : () }
de625c9b MG	131	}
	132
	133	sub contest_list {
	134	my ($self, %args) = @_;
	135	my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
	136	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
	137	my %params;
	138	for ($rs->all) {
	139	my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
	140	$params{$state} //= [];
35596ea8	141	push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
de625c9b MG	142	}
	143	\%params
	144	}
	145
	146	sub contest_entry {
	147	my ($self, $id) = @_;
	148	my $ct = $self->contest($id);
	149	+{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
	150	}
	151
	152	sub job_list {
	153	my ($self, %args) = @_;
	154	$args{page} //= 1;
3473324b	155	my $rs = $self->jobs->search(undef, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
526b9e80 MG	156	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	157	$rs = $rs->search({contest => $args{contest}}) if $args{contest};
	158	$rs = $rs->search({problem => $args{problem}}) if $args{problem};
3473324b MG	159	return {
	160	log => [map {
	161	my %params = $_->get_columns;
	162	$params{owner_name} = $_->owner->name;
	163	$params{problem_name} = $_->problem->name;
	164	$params{results} &&= decode_json $params{results};
	165	$params{size} = length $params{source};
	166	delete $params{source};
	167	\%params
	168	} $rs->all],
	169	current_page => $rs->pager->current_page,
	170	maybe previous_page => $rs->pager->previous_page,
	171	maybe next_page => $rs->pager->next_page,
	172	maybe last_page => $rs->pager->last_page,
	173	}
de625c9b MG	174	}
	175
	176	sub job_entry {
	177	my ($self, $id) = @_;
	178	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner']});
	179	my %params = $job->get_columns;
	180	$params{owner_name} = $job->owner->name;
	181	$params{problem_name} = $job->problem->name;
	182	$params{results} &&= decode_json $params{results};
	183	$params{size} = length $params{source};
	184	delete $params{source};
	185	\%params
	186	}
	187
f7386aab	188	1;
4a8747ef MG	189
	190	__END__
	191
	192	=encoding utf-8
	193
	194	=head1 NAME
	195
	196	Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
	197
	198	=head1 SYNOPSIS
	199
	200	my $db = Gruntmaster::Data->connect('dbi:Pg:');
cbb36c78 MG	201
	202	my $problem = $db->problem('my_problem');
	203	$problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
	204	$problem->rerun; # And rerun all jobs for this problem
	205
	206	# ...
	207
	208	my $contest = $db->contests->create({ # Create a new contest
	209	id => 'my_contest',
	210	name => 'My Awesome Contest',
	211	start => time + 100,
	212	end => time + 1900,
	213	});
	214	$db->contest_problems->create({ # Add a problem to the contest
	215	contest => 'my_contest',
	216	problem => 'my_problem',
	217	});
	218
	219	say 'The contest has not started yet' if $contest->is_pending;
	220
	221	# ...
	222
	223	my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
	224	$_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
4a8747ef MG	225
	226	=head1 DESCRIPTION
	227
cbb36c78 MG	228	Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
	229
	230	In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
	231
	232	=over
	233
	234	=item contests
	235
	236	Equivalent to C<< $schema->resultset('Contest') >>
	237
	238	=item contest_problems
	239
	240	Equivalent to C<< $schema->resultset('ContestProblem') >>
	241
	242	=item jobs
	243
	244	Equivalent to C<< $schema->resultset('Job') >>
	245
	246	=item problems
	247
	248	Equivalent to C<< $schema->resultset('Problem') >>
	249
	250	=item users
	251
	252	Equivalent to C<< $schema->resultset('User') >>
	253
	254	=item contest($id)
	255
	256	Equivalent to C<< $schema->resultset('Contest')->find($id) >>
	257
	258	=item job($id)
	259
	260	Equivalent to C<< $schema->resultset('Job')->find($id) >>
	261
	262	=item problem($id)
	263
	264	Equivalent to C<< $schema->resultset('Problem')->find($id) >>
	265
	266	=item user($id)
	267
	268	Equivalent to C<< $schema->resultset('User')->find($id) >>
	269
de625c9b MG	270	=item user_list
	271
	272	Returns a list of users as an arrayref containing hashrefs.
	273
	274	=item user_entry($id)
	275
	276	Returns a hashref with information about the user $id.
	277
	278	=item problem_list([%args])
	279
	280	Returns a list of problems grouped by level. A hashref with levels as keys.
	281
	282	Takes the following arguments:
	283
	284	=over
	285
	286	=item owner
	287
	288	Only show problems owned by this user
	289
	290	=item contest
	291
	292	Only show problems in this contest
	293
	294	=back
	295
	296	=item problem_entry($id, [$contest, $user])
	297
	298	Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
	299
	300	=item contest_list([%args])
	301
	302	Returns a list of contests grouped by state. A hashref with the following keys:
	303
	304	=over
	305
	306	=item pending
	307
	308	An arrayref of hashrefs representing pending contests
	309
	310	=item running
	311
	312	An arrayref of hashrefs representing running contests
	313
	314	=item finished
	315
	316	An arrayref of hashrefs representing finished contests
	317
	318	=back
	319
	320	Takes the following arguments:
	321
	322	=over
	323
	324	=item owner
	325
	326	Only show contests owned by this user.
	327
	328	=back
	329
	330	=item contest_entry($id)
	331
	332	Returns a hashref with information about the contest $id.
	333
334	=item job_list([%args])
335
336	Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
337
338	=over
339
340	=item owner
341
342	Only show jobs submitted by this user.
343
344	=item contest
345
346	Only show jobs submitted in this contest.
347
348	=item problem
349
350	Only show jobs submitted for this problem.
351
352	=item page
353
354	Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
355
356	=back
357
358	=item job_entry($id)
359
360	Returns a hashref with information about the job $id.
361
cbb36c78	362	=back
4a8747ef MG	363
	364	=head1 AUTHOR
	365
	366	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	367
	368	=head1 COPYRIGHT AND LICENSE
	369
	370	Copyright (C) 2014 by Marius Gavrilescu
	371
9d2e740e MG	372	This library is free software; you can redistribute it and/or modify
	373	it under the same terms as Perl itself, either Perl version 5.18.1 or,
	374	at your option, any later version of Perl 5 you may have available.
4a8747ef MG	375
	376
	377	=cut