[gruntmaster-data.git] / lib / Gruntmaster / Data.pm

package Gruntmaster::Data;
use 5.014;
use warnings;

use parent qw/Exporter/;
our $VERSION = '5999.000_015';
our @EXPORT = qw/dbinit purge db user_list user_entry problem_list problem_entry contest_list contest_entry contest_has_problem job_list job_entry create_job standings update_status rerun_job take_job finish_job open_problem/;
our @EXPORT_OK = @EXPORT;

use JSON::MaybeXS qw/decode_json/;
use HTTP::Tiny;
use PerlX::Maybe qw/maybe/;

use DBI;
use DBIx::Simple;
use List::Util qw/sum/;
use SQL::Abstract;

use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
use constant JOBS_PER_PAGE => 50;

my %statements = (
	user_list_sth => 'SELECT * FROM user_list LIMIT 200',
	user_entry_sth => 'SELECT * FROM user_data WHERE id = ?',

	problem_status_sth => 'SELECT problem,solved FROM problem_status WHERE owner = ?',
	contest_status_sth => 'SELECT contest,score,rank FROM contest_status WHERE owner = ?',

	contest_list_sth => 'SELECT * FROM contest_entry',
	contest_entry_sth => 'SELECT * FROM contest_entry WHERE id = ?',
	contest_has_problem_sth => 'SELECT EXISTS(SELECT 1 FROM contest_problems WHERE contest = ? AND problem = ?)',
	opens_sth => 'SELECT problem,owner,time FROM opens WHERE contest = ?',

	problem_entry_sth => 'SELECT ' . (join ',', @{PROBLEM_PUBLIC_COLUMNS()}, 'statement', 'solution') . ' FROM problems WHERE id = ?',
	limits_sth => 'SELECT format,timeout FROM limits WHERE problem = ?',

	job_entry_sth => 'SELECT * FROM job_entry WHERE id = ?',

	rerun_problem_sth => 'UPDATE jobs SET daemon=NULL,result=-2,result_text=NULL,results=NULL,errors=NULL WHERE problem = ?',
	rerun_job_sth => 'UPDATE jobs SET daemon=NULL,result=-2,result_text=NULL,results=NULL,errors=NULL WHERE id = ?',
	take_job_sth => 'UPDATE jobs SET daemon=? WHERE id = (SELECT id FROM jobs WHERE daemon IS NULL LIMIT 1 FOR UPDATE) RETURNING id',
);

our $db;
sub db () { $db }

sub dbinit {
	$db = DBIx::Simple->new(@_);
	$db->keep_statements = 100;
};

sub purge;

sub _query {
	my ($stat, @extra) = @_;
	$db->query($statements{$stat}, @extra)
}

my (%name_cache, %name_cache_time);
use constant NAME_CACHE_MAX_AGE => 5;

sub _object_name {
	my ($table, $id) = @_;
	$name_cache_time{$table} //= 0;
	if (time - $name_cache_time{$table} > NAME_CACHE_MAX_AGE) {
		$name_cache_time{$table} = time;
		$name_cache{$table} = {};
		$name_cache{$table} = $db->select($table, 'id,name')->map;
	}

	$name_cache{$table}{$id}
}


sub _add_names ($) { ## no critic (ProhibitSubroutinePrototypes)
	my ($el) = @_;
	return unless defined $el;
	if (ref $el eq 'ARRAY') {
		&_add_names ($_) for @$el ## no critic (ProhibitAmpersandSigils)
	} else {
		for my $object (qw/contest owner problem/) {
			my $table = $object eq 'owner' ? 'users' : "${object}s";
			$el->{"${object}_name"} = _object_name $table, $el->{$object} if defined $el->{$object}
		}
	}

	$el
}

sub user_list { scalar _query('user_list_sth')->hashes }

sub user_entry {
	my ($id) = @_;
	my $ret = _query('user_entry_sth', $id)->hash;
	$ret->{problems} = _add_names _query('problem_status_sth', $id)->hashes;
	$ret->{contests} = _add_names _query('contest_status_sth', $id)->hashes;

	$ret;
}

sub problem_list {
	my (%args) = @_;
	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	push @columns, 'solution' if $args{solution};
	my %where;
	$where{private} = 0 unless $args{contest} || $args{private};
	$where{'cp.contest'} = $args{contest} if $args{contest};
	$where{owner} = $args{owner} if $args{owner};

	my $table = $args{contest} ? 'problems JOIN contest_problems cp ON cp.problem = id' : 'problems';
	_add_names $db->select(\$table, \@columns, \%where, 'name')->hashes
}

sub problem_entry {
	my ($id, $contest) = @_;
	$contest = contest_entry ($contest) if $contest;
	my $ret = _add_names _query(problem_entry_sth => $id)->hash;
	my $limits = _query(limits_sth => $id)->hashes;
	$ret->{limits} = $limits if @$limits;

	if ($contest) {
		$ret->{contest_start} = $contest->{start};
		$ret->{contest_stop}  = $contest->{stop};
		delete $ret->{solution}
	}

	$ret
}

sub contest_list { _add_names _query('contest_list_sth')->hashes }

sub contest_entry { _add_names _query(contest_entry_sth => $_[0])->hash }

sub contest_has_problem { _query('contest_has_problem_sth', @_[0, 1])->flat }

sub job_list {
	my (%args) = @_;
	$args{page} = int ($args{page} // 1);
	my %where = (
		maybe contest => $args{contest},
		maybe owner => $args{owner},
		maybe problem => $args{problem},
		maybe result => $args{result},
	);
	$where{private} = 0 unless $args{private};

	my $rows = $db->select('job_entry', 'COUNT(*)', \%where)->list;
	my $pages = int (($rows + JOBS_PER_PAGE - 1) / JOBS_PER_PAGE);
	my ($stmt, @bind) = $db->abstract->select('job_entry', '*', \%where, {-desc => 'id'});
	my $jobs = _add_names $db->query("$stmt LIMIT " . JOBS_PER_PAGE . ' OFFSET ' . ($args{page} - 1) * JOBS_PER_PAGE, @bind)->hashes;
	my $pageinfo = {
		current_page => $args{page},
		last_page    => $pages,
		($args{page} - 1) ? (previous_page => $args{page} - 1) : (),
		($args{page} < $pages) ? (next_page => $args{page} + 1) : (),
	};
	wantarray ? ($jobs, $pageinfo) : $jobs;
}

sub job_entry {
	my $ret = _add_names _query(job_entry_sth => $_[0])->hash;
	$ret->{results} = decode_json $ret->{results} if $ret->{results};
	$ret
}

sub create_job {
	my (%args) = @_;
	$db->update('users', {lastjob => time}, {id => $args{owner}});
	purge '/log/';
	scalar $db->insert('jobs', \%args, {returning => 'id'})->list
}

sub _calc_score {
	my ($mxscore, $time, $tries, $totaltime) = @_;
	my $score = $mxscore;
	$time = 300 if $time > $totaltime; # uncoverable branch true does not happen anymore (only possible if opens are broken)
	$score = ($totaltime - $time) / $totaltime * $score;
	$score -= $tries / 10 * $mxscore;
	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
	int $score + 0.5
}

sub standings {
	my ($ct) = @_;
	my @problems = sort { $a->{value} <=> $b->{value} } @{problem_list contest => $ct};
	my %values = map { $_->{id} => $_->{value} } @problems;
	$ct = contest_entry $ct;

	my (%scores, %tries, %opens);
	my $opens = _query(opens_sth => $ct->{id});
	while ($opens->into(my ($problem, $owner, $time))) {
		$opens{$problem, $owner} = $time;
	}

	my $jobs = $db->select('job_entry', '*', {contest => $ct->{id}}, 'id');

	while (my $job = $jobs->hash) {
		my $open = $opens{$job->{problem}, $job->{owner}} // $ct->{start};
		my $time = $job->{date} - $open;
		next if $time < 0; # uncoverable branch true job sent before contest is deprecated
		my $value = $values{$job->{problem}};
		my $factor = $job->{result} ? 0 : 1;
		$factor = $1 / 100 if $job->{result_text} =~ /^(\d+ )/s;
		$scores{$job->{owner}}{$job->{problem}} = int ($factor * _calc_score ($value, $time, $tries{$job->{owner}}{$job->{problem}}++, $ct->{stop} - $ct->{start}));
	}

	my @st = sort { $b->{score} <=> $a->{score} or $a->{user} cmp $b->{user} } map { ## no critic (ProhibitReverseSortBlock)
		my $user = $_;
		+{
			user => $user,
			user_name => _object_name(users => $user),
			score => sum (values %{$scores{$user}}),
			scores => [map { $scores{$user}{$_->{id}} // '-'} @problems],
		}
	} keys %scores;

	$st[0]->{rank} = 1 if @st;
	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;

	\@st
}

sub update_status {
	my $jobs = $db->select('jobs', 'id,owner,problem,result', {-not_bool => 'private'}, 'id');

	my %hash;
	while ($jobs->into(my ($id, $owner, $problem, $result))) {
		$hash{$problem, $owner} = [$id, $result ? 0 : 1];
	}

	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;

	my @contest_statuses = map {
		my $ct = $_;
		map { [$ct, $_->{user}, $_->{score}, $_->{rank}] } @{standings $ct}
	} $db->select('contests', 'id')->flat;

	$db->begin;
	$db->delete('problem_status');
	$db->query('INSERT INTO problem_status (problem,owner,job,solved) VALUES (??)', @$_) for @problem_statuses;
	$db->delete('contest_status');
	$db->query('INSERT INTO contest_status (contest,owner,score,rank) VALUES (??)', @$_) for @contest_statuses;
	$db->commit
}

sub rerun_problem {
	my ($problem) = @_;
	_query rerun_problem_sth => $problem;
	purge '/log/';
}

sub rerun_job {
	my ($id) = @_;
	_query rerun_job_sth => $id;
	purge '/log/';
	purge "/log/$id";
}

sub take_job {
	my ($daemon) = @_;
	my $id = _query(take_job_sth => $daemon)->list;
	return unless $id;
	purge '/log/';
	purge "/log/$id";
	db->select(jobs => '*', {id => $id})->hash
}

sub finish_job {
	my ($job, $private, %args) = @_;
	db->update(jobs => \%args, {id => $job->{id}});
	purge '/log/';
	purge '/log/' . $job->{id};
	return if $private;
	my $status = {
		problem => $job->{problem},
		owner   => $job->{owner},
		job     => $job->{id},
		solved  => ($args{result} ? 0 : 1),
	};
	eval {
		db->insert(problem_status => $status)
	} or db->update(problem_status => $status, {owner => $job->{owner}, problem => $job->{problem}});
	purge '/us/' . $job->{owner};
}

sub open_problem {
	my ($contest, $problem, $owner, $time) = @_;
	my $ct = contest_entry($contest);
	return unless $ct->{id} && $time >= $ct->{start} && $time < $ct->{stop}; ## no critic (ProhibitNegativeExpressionsInUnlessAndUntilConditions)
	eval { db->insert(opens => { ## no critic (RequireCheckingReturnValueOfEval)
		contest => $contest,
		problem => $problem,
		owner => $owner,
		time => $time}) };
}

my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
my $ht = HTTP::Tiny->new;

sub purge {
	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
}

1;

__END__

=encoding utf-8

=head1 NAME

Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools

=head1 SYNOPSIS


=head1 DESCRIPTION

Gruntmaster::Data is the interface to the Gruntmaster 6000 database.

All functions are exported by default.

=over

=item B<dbinit>(I<@args>)

This function connects to the database. I<@args> are the arguments
passed to the L<DBIx::Simple> constructor.

=item B<purge>(I<$url_path>)

Purges a relative URL from the Varnish Cache by sending PURGE
$url_path requests to all hosts in the PURGE_HOSTS environment
variable.

=item B<db>

Returns a L<DBIx::Simple> object for interacting with the database
directly. Use this when no other function in this module is suitable.

=item B<user_list>

Returns an arrayref of the top 200 users.

=item B<user_entry>(I<$id>)

Returns a hashref describing the user I<$id>.

=item B<problem_list>([I<%args>])

Returns an arrayref of problems.

Takes the following named arguments:

=over

=item owner

Only show problems owned by this user

=item contest

Only show problems in this contest

=item private

If true, include private problems. Always true if contest is present.

=item solution

If true, include problem solutions

=back

=item B<problem_entry>(i<$id>, [I<$contest>])

Returns a hashref describing the problem I<$id>. If $contest is
present, contest start and stop times are included, and the solution
is deleted.

=item B<contest_list>

Returns an arrayref of contests.

=item B<contest_entry>(I<$id>)

Returns a hashref describing the contest I<$id>.

=item B<contest_has_problem>(I<$contest>, I<$problem>)

Returns true if the contest I<$contest> includes the problem
I<$problem>, false otherwise.

=item B<job_list>([I<%args>])

In scalar context, returns an arrayref of jobs. In list context,
returns an arrayref of jobs and a hashref of information about pages.

Takes the following named arguments:

=over

=item page

Show this page of the job log. Defaults to 1.

=item owner

Only show jobs submitted by this user.

=item contest

Only show jobs submitted in this contest.

=item problem

Only show jobs submitted for this problem.

=item result

Only show jobs with this result (see the constants in
L<Gruntmaster::Daemon::Constants>).

=item private

If true, include private jobs. Defaults to false.

=back

=item B<job_entry>(I<$id>)

Returns a hashref describing the job I<$id>.

=item B<create_job>(I<%args>)

Insert a new job into the database. This function also updates the
lastjob field for the job's owner.

=item B<standings>(I<$ct>)

Returns an arrayref of the standings of contest I<$ct>.

=item B<update_status>

Rebuilds the problem_status and contest_status tables.

=item B<rerun_job>(I<$id>)

Marks the job $id as pending and clears its results, so that it will
be run again by the daemon.

=item B<take_job>(I<$daemon>)

Marks a random job as being run by I<$daemon>. Returns a hashref
describing the job, or undef if no job was available.

=item B<finish_job>(I<$job>, I<$private>, I<%results>)

Updates the job $job with the results in %results. If $private is
false, also updates the problem_status table.

=item B<open_problem>(I<$contest>, I<$problem>, I<$owner>, I<$time>)

Notes that I<$owner> has opened the problem I<$problem> of contest
I<$contest> at time I<$time>. If the C<opens> table already contains
this (I<$contest>, I<$problem>, I<$owner>) triplet, this function does
nothing.

=back

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014-2015 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.20.1 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
	1	package Gruntmaster::Data;
	2	use 5.014;
	3	use warnings;
	4
	5	use parent qw/Exporter/;
	6	our $VERSION = '5999.000_015';
	7	our @EXPORT = qw/dbinit purge db user_list user_entry problem_list problem_entry contest_list contest_entry contest_has_problem job_list job_entry create_job standings update_status rerun_job take_job finish_job open_problem/;
	8	our @EXPORT_OK = @EXPORT;
	9
	10	use JSON::MaybeXS qw/decode_json/;
	11	use HTTP::Tiny;
	12	use PerlX::Maybe qw/maybe/;
	13
	14	use DBI;
	15	use DBIx::Simple;
	16	use List::Util qw/sum/;
	17	use SQL::Abstract;
	18
	19	use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
	20	use constant JOBS_PER_PAGE => 50;
	21
	22	my %statements = (
	23	user_list_sth => 'SELECT * FROM user_list LIMIT 200',
	24	user_entry_sth => 'SELECT * FROM user_data WHERE id = ?',
	25
	26	problem_status_sth => 'SELECT problem,solved FROM problem_status WHERE owner = ?',
	27	contest_status_sth => 'SELECT contest,score,rank FROM contest_status WHERE owner = ?',
	28
	29	contest_list_sth => 'SELECT * FROM contest_entry',
	30	contest_entry_sth => 'SELECT * FROM contest_entry WHERE id = ?',
	31	contest_has_problem_sth => 'SELECT EXISTS(SELECT 1 FROM contest_problems WHERE contest = ? AND problem = ?)',
	32	opens_sth => 'SELECT problem,owner,time FROM opens WHERE contest = ?',
	33
	34	problem_entry_sth => 'SELECT ' . (join ',', @{PROBLEM_PUBLIC_COLUMNS()}, 'statement', 'solution') . ' FROM problems WHERE id = ?',
	35	limits_sth => 'SELECT format,timeout FROM limits WHERE problem = ?',
	36
	37	job_entry_sth => 'SELECT * FROM job_entry WHERE id = ?',
	38
	39	rerun_problem_sth => 'UPDATE jobs SET daemon=NULL,result=-2,result_text=NULL,results=NULL,errors=NULL WHERE problem = ?',
	40	rerun_job_sth => 'UPDATE jobs SET daemon=NULL,result=-2,result_text=NULL,results=NULL,errors=NULL WHERE id = ?',
	41	take_job_sth => 'UPDATE jobs SET daemon=? WHERE id = (SELECT id FROM jobs WHERE daemon IS NULL LIMIT 1 FOR UPDATE) RETURNING id',
	42	);
	43
	44	our $db;
	45	sub db () { $db }
	46
	47	sub dbinit {
	48	$db = DBIx::Simple->new(@_);
	49	$db->keep_statements = 100;
	50	};
	51
	52	sub purge;
	53
	54	sub _query {
	55	my ($stat, @extra) = @_;
	56	$db->query($statements{$stat}, @extra)
	57	}
	58
	59	my (%name_cache, %name_cache_time);
	60	use constant NAME_CACHE_MAX_AGE => 5;
	61
	62	sub _object_name {
	63	my ($table, $id) = @_;
	64	$name_cache_time{$table} //= 0;
	65	if (time - $name_cache_time{$table} > NAME_CACHE_MAX_AGE) {
	66	$name_cache_time{$table} = time;
	67	$name_cache{$table} = {};
	68	$name_cache{$table} = $db->select($table, 'id,name')->map;
	69	}
	70
	71	$name_cache{$table}{$id}
	72	}
	73
	74
	75	sub _add_names ($) { ## no critic (ProhibitSubroutinePrototypes)
	76	my ($el) = @_;
	77	return unless defined $el;
	78	if (ref $el eq 'ARRAY') {
	79	&_add_names ($_) for @$el ## no critic (ProhibitAmpersandSigils)
	80	} else {
	81	for my $object (qw/contest owner problem/) {
	82	my $table = $object eq 'owner' ? 'users' : "${object}s";
	83	$el->{"${object}_name"} = _object_name $table, $el->{$object} if defined $el->{$object}
	84	}
	85	}
	86
	87	$el
	88	}
	89
	90	sub user_list { scalar _query('user_list_sth')->hashes }
	91
	92	sub user_entry {
	93	my ($id) = @_;
	94	my $ret = _query('user_entry_sth', $id)->hash;
	95	$ret->{problems} = _add_names _query('problem_status_sth', $id)->hashes;
	96	$ret->{contests} = _add_names _query('contest_status_sth', $id)->hashes;
	97
	98	$ret;
	99	}
	100
	101	sub problem_list {
	102	my (%args) = @_;
	103	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	104	push @columns, 'solution' if $args{solution};
	105	my %where;
	106	$where{private} = 0 unless $args{contest} \|\| $args{private};
	107	$where{'cp.contest'} = $args{contest} if $args{contest};
	108	$where{owner} = $args{owner} if $args{owner};
	109
	110	my $table = $args{contest} ? 'problems JOIN contest_problems cp ON cp.problem = id' : 'problems';
	111	_add_names $db->select(\$table, \@columns, \%where, 'name')->hashes
	112	}
	113
	114	sub problem_entry {
	115	my ($id, $contest) = @_;
	116	$contest = contest_entry ($contest) if $contest;
	117	my $ret = _add_names _query(problem_entry_sth => $id)->hash;
	118	my $limits = _query(limits_sth => $id)->hashes;
	119	$ret->{limits} = $limits if @$limits;
	120
	121	if ($contest) {
	122	$ret->{contest_start} = $contest->{start};
	123	$ret->{contest_stop} = $contest->{stop};
	124	delete $ret->{solution}
	125	}
	126
	127	$ret
	128	}
	129
	130	sub contest_list { _add_names _query('contest_list_sth')->hashes }
	131
	132	sub contest_entry { _add_names _query(contest_entry_sth => $_[0])->hash }
	133
	134	sub contest_has_problem { _query('contest_has_problem_sth', @_[0, 1])->flat }
	135
	136	sub job_list {
	137	my (%args) = @_;
	138	$args{page} = int ($args{page} // 1);
	139	my %where = (
	140	maybe contest => $args{contest},
	141	maybe owner => $args{owner},
	142	maybe problem => $args{problem},
	143	maybe result => $args{result},
	144	);
	145	$where{private} = 0 unless $args{private};
	146
	147	my $rows = $db->select('job_entry', 'COUNT(*)', \%where)->list;
	148	my $pages = int (($rows + JOBS_PER_PAGE - 1) / JOBS_PER_PAGE);
	149	my ($stmt, @bind) = $db->abstract->select('job_entry', '*', \%where, {-desc => 'id'});
	150	my $jobs = _add_names $db->query("$stmt LIMIT " . JOBS_PER_PAGE . ' OFFSET ' . ($args{page} - 1) * JOBS_PER_PAGE, @bind)->hashes;
	151	my $pageinfo = {
	152	current_page => $args{page},
	153	last_page => $pages,
	154	($args{page} - 1) ? (previous_page => $args{page} - 1) : (),
	155	($args{page} < $pages) ? (next_page => $args{page} + 1) : (),
	156	};
	157	wantarray ? ($jobs, $pageinfo) : $jobs;
	158	}
	159
	160	sub job_entry {
	161	my $ret = _add_names _query(job_entry_sth => $_[0])->hash;
	162	$ret->{results} = decode_json $ret->{results} if $ret->{results};
	163	$ret
	164	}
	165
	166	sub create_job {
	167	my (%args) = @_;
	168	$db->update('users', {lastjob => time}, {id => $args{owner}});
	169	purge '/log/';
	170	scalar $db->insert('jobs', \%args, {returning => 'id'})->list
	171	}
	172
	173	sub _calc_score {
	174	my ($mxscore, $time, $tries, $totaltime) = @_;
	175	my $score = $mxscore;
	176	$time = 300 if $time > $totaltime; # uncoverable branch true does not happen anymore (only possible if opens are broken)
	177	$score = ($totaltime - $time) / $totaltime * $score;
	178	$score -= $tries / 10 * $mxscore;
	179	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
	180	int $score + 0.5
	181	}
	182
	183	sub standings {
	184	my ($ct) = @_;
	185	my @problems = sort { $a->{value} <=> $b->{value} } @{problem_list contest => $ct};
	186	my %values = map { $_->{id} => $_->{value} } @problems;
	187	$ct = contest_entry $ct;
	188
	189	my (%scores, %tries, %opens);
	190	my $opens = _query(opens_sth => $ct->{id});
	191	while ($opens->into(my ($problem, $owner, $time))) {
	192	$opens{$problem, $owner} = $time;
	193	}
	194
	195	my $jobs = $db->select('job_entry', '*', {contest => $ct->{id}}, 'id');
	196
	197	while (my $job = $jobs->hash) {
	198	my $open = $opens{$job->{problem}, $job->{owner}} // $ct->{start};
	199	my $time = $job->{date} - $open;
	200	next if $time < 0; # uncoverable branch true job sent before contest is deprecated
	201	my $value = $values{$job->{problem}};
	202	my $factor = $job->{result} ? 0 : 1;
	203	$factor = $1 / 100 if $job->{result_text} =~ /^(\d+ )/s;
	204	$scores{$job->{owner}}{$job->{problem}} = int ($factor * _calc_score ($value, $time, $tries{$job->{owner}}{$job->{problem}}++, $ct->{stop} - $ct->{start}));
	205	}
	206
	207	my @st = sort { $b->{score} <=> $a->{score} or $a->{user} cmp $b->{user} } map { ## no critic (ProhibitReverseSortBlock)
	208	my $user = $_;
	209	+{
	210	user => $user,
	211	user_name => _object_name(users => $user),
	212	score => sum (values %{$scores{$user}}),
	213	scores => [map { $scores{$user}{$_->{id}} // '-'} @problems],
	214	}
	215	} keys %scores;
	216
	217	$st[0]->{rank} = 1 if @st;
	218	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
	219
	220	\@st
	221	}
	222
	223	sub update_status {
	224	my $jobs = $db->select('jobs', 'id,owner,problem,result', {-not_bool => 'private'}, 'id');
	225
	226	my %hash;
	227	while ($jobs->into(my ($id, $owner, $problem, $result))) {
	228	$hash{$problem, $owner} = [$id, $result ? 0 : 1];
	229	}
	230
	231	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
	232
	233	my @contest_statuses = map {
	234	my $ct = $_;
	235	map { [$ct, $_->{user}, $_->{score}, $_->{rank}] } @{standings $ct}
	236	} $db->select('contests', 'id')->flat;
	237
	238	$db->begin;
	239	$db->delete('problem_status');
	240	$db->query('INSERT INTO problem_status (problem,owner,job,solved) VALUES (??)', @$_) for @problem_statuses;
	241	$db->delete('contest_status');
	242	$db->query('INSERT INTO contest_status (contest,owner,score,rank) VALUES (??)', @$_) for @contest_statuses;
	243	$db->commit
	244	}
	245
	246	sub rerun_problem {
	247	my ($problem) = @_;
	248	_query rerun_problem_sth => $problem;
	249	purge '/log/';
	250	}
	251
	252	sub rerun_job {
	253	my ($id) = @_;
	254	_query rerun_job_sth => $id;
	255	purge '/log/';
	256	purge "/log/$id";
	257	}
	258
	259	sub take_job {
	260	my ($daemon) = @_;
	261	my $id = _query(take_job_sth => $daemon)->list;
	262	return unless $id;
	263	purge '/log/';
	264	purge "/log/$id";
	265	db->select(jobs => '*', {id => $id})->hash
	266	}
	267
	268	sub finish_job {
	269	my ($job, $private, %args) = @_;
	270	db->update(jobs => \%args, {id => $job->{id}});
	271	purge '/log/';
	272	purge '/log/' . $job->{id};
	273	return if $private;
	274	my $status = {
	275	problem => $job->{problem},
	276	owner => $job->{owner},
	277	job => $job->{id},
	278	solved => ($args{result} ? 0 : 1),
	279	};
	280	eval {
	281	db->insert(problem_status => $status)
	282	} or db->update(problem_status => $status, {owner => $job->{owner}, problem => $job->{problem}});
	283	purge '/us/' . $job->{owner};
	284	}
	285
	286	sub open_problem {
	287	my ($contest, $problem, $owner, $time) = @_;
	288	my $ct = contest_entry($contest);
	289	return unless $ct->{id} && $time >= $ct->{start} && $time < $ct->{stop}; ## no critic (ProhibitNegativeExpressionsInUnlessAndUntilConditions)
	290	eval { db->insert(opens => { ## no critic (RequireCheckingReturnValueOfEval)
	291	contest => $contest,
	292	problem => $problem,
	293	owner => $owner,
	294	time => $time}) };
	295	}
	296
	297	my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
	298	my $ht = HTTP::Tiny->new;
	299
	300	sub purge {
	301	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
	302	}
	303
	304	1;
	305
	306	__END__
	307
	308	=encoding utf-8
	309
	310	=head1 NAME
	311
	312	Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
	313
	314	=head1 SYNOPSIS
	315
	316
	317	=head1 DESCRIPTION
	318
	319	Gruntmaster::Data is the interface to the Gruntmaster 6000 database.
	320
	321	All functions are exported by default.
	322
	323	=over
	324
	325	=item B<dbinit>(I<@args>)
	326
	327	This function connects to the database. I<@args> are the arguments
	328	passed to the L<DBIx::Simple> constructor.
	329
	330	=item B<purge>(I<$url_path>)
	331
	332	Purges a relative URL from the Varnish Cache by sending PURGE
	333	$url_path requests to all hosts in the PURGE_HOSTS environment
	334	variable.
	335
	336	=item B<db>
	337
	338	Returns a L<DBIx::Simple> object for interacting with the database
	339	directly. Use this when no other function in this module is suitable.
	340
	341	=item B<user_list>
	342
	343	Returns an arrayref of the top 200 users.
	344
	345	=item B<user_entry>(I<$id>)
	346
	347	Returns a hashref describing the user I<$id>.
	348
	349	=item B<problem_list>([I<%args>])
	350
	351	Returns an arrayref of problems.
	352
	353	Takes the following named arguments:
	354
	355	=over
	356
	357	=item owner
	358
	359	Only show problems owned by this user
	360
	361	=item contest
	362
	363	Only show problems in this contest
	364
	365	=item private
	366
	367	If true, include private problems. Always true if contest is present.
	368
	369	=item solution
	370
	371	If true, include problem solutions
	372
	373	=back
	374
	375	=item B<problem_entry>(i<$id>, [I<$contest>])
	376
	377	Returns a hashref describing the problem I<$id>. If $contest is
	378	present, contest start and stop times are included, and the solution
	379	is deleted.
	380
	381	=item B<contest_list>
	382
	383	Returns an arrayref of contests.
	384
	385	=item B<contest_entry>(I<$id>)
	386
	387	Returns a hashref describing the contest I<$id>.
	388
	389	=item B<contest_has_problem>(I<$contest>, I<$problem>)
	390
	391	Returns true if the contest I<$contest> includes the problem
	392	I<$problem>, false otherwise.
	393
	394	=item B<job_list>([I<%args>])
	395
	396	In scalar context, returns an arrayref of jobs. In list context,
	397	returns an arrayref of jobs and a hashref of information about pages.
	398
	399	Takes the following named arguments:
	400
	401	=over
	402
	403	=item page
	404
	405	Show this page of the job log. Defaults to 1.
	406
	407	=item owner
	408
	409	Only show jobs submitted by this user.
	410
	411	=item contest
	412
	413	Only show jobs submitted in this contest.
	414
	415	=item problem
	416
	417	Only show jobs submitted for this problem.
	418
	419	=item result
	420
	421	Only show jobs with this result (see the constants in
	422	L<Gruntmaster::Daemon::Constants>).
	423
	424	=item private
	425
	426	If true, include private jobs. Defaults to false.
	427
	428	=back
	429
	430	=item B<job_entry>(I<$id>)
	431
	432	Returns a hashref describing the job I<$id>.
	433
	434	=item B<create_job>(I<%args>)
	435
	436	Insert a new job into the database. This function also updates the
	437	lastjob field for the job's owner.
	438
	439	=item B<standings>(I<$ct>)
	440
	441	Returns an arrayref of the standings of contest I<$ct>.
	442
	443	=item B<update_status>
	444
	445	Rebuilds the problem_status and contest_status tables.
	446
	447	=item B<rerun_job>(I<$id>)
	448
	449	Marks the job $id as pending and clears its results, so that it will
	450	be run again by the daemon.
	451
	452	=item B<take_job>(I<$daemon>)
	453
	454	Marks a random job as being run by I<$daemon>. Returns a hashref
	455	describing the job, or undef if no job was available.
	456
	457	=item B<finish_job>(I<$job>, I<$private>, I<%results>)
	458
	459	Updates the job $job with the results in %results. If $private is
	460	false, also updates the problem_status table.
	461
	462	=item B<open_problem>(I<$contest>, I<$problem>, I<$owner>, I<$time>)
	463
	464	Notes that I<$owner> has opened the problem I<$problem> of contest
	465	I<$contest> at time I<$time>. If the C<opens> table already contains
	466	this (I<$contest>, I<$problem>, I<$owner>) triplet, this function does
	467	nothing.
	468
	469	=back
	470
	471	=head1 AUTHOR
	472
	473	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	474
	475	=head1 COPYRIGHT AND LICENSE
	476
	477	Copyright (C) 2014-2015 by Marius Gavrilescu
	478
	479	This library is free software; you can redistribute it and/or modify
	480	it under the same terms as Perl itself, either Perl version 5.20.1 or,
	481	at your option, any later version of Perl 5 you may have available.
	482
	483
	484	=cut