Remove generators which are now articles

[gruntmaster-page.git] / gruntmaster-contest

#!/usr/bin/perl -w
use v5.14;

use Gruntmaster::Data qw/contests insert_contest remove_contest contest_name contest_owner contest_start contest_end/;

use IO::Prompter [ -style => 'bold', '-stdio', '-verbatim' ];
use File::Slurp qw/read_file/;
use Term::ANSIColor qw/RED RESET/;
use POSIX qw/strftime/;
use Date::Parse qw/str2time/;

##################################################

sub cmd_help{
	exec perldoc => $0
}

sub cmd_list{
	local $, = "\n";
	say contests;
}

sub cmd_show{
	local $_ = shift or goto &cmd_list;
	say "Name: ", contest_name;
	say "Owner: ", contest_owner;
	say "Start: ", strftime '%c', localtime contest_start;
	say "End: ", strftime '%c', localtime contest_end;
}

sub cmd_add{
	my $id = shift;
	my $name = prompt 'Contest name';
	my $owner = prompt 'Owner';
	my $start = str2time prompt 'Start time' or die 'Cannot parse time';
	my $end = str2time prompt 'End time' or die 'Cannot parse time';

	insert_contest $id => name => $name, owner => $owner, start => $start, end => $end;
}

sub cmd_rm{
	remove_contest shift;
}

##################################################

no strict 'refs';
my $cmd = 'cmd_' . shift;
cmd_help unless exists $main::{$cmd};
$cmd->(@ARGV) if exists $main::{$cmd};

1;
__END__

=encoding utf-8

=head1 NAME

gruntmaster-contest - shell interface to Gruntmaster 6000 contests

=head1 SYNOPSIS

  gruntmaster-contest list
  gruntmaster-contest show id
  gruntmaster-contest add id
  gruntmaster-contest rm id

=head1 DESCRIPTION



=cut