| 1 | #!/usr/bin/perl -w |
| 2 | use v5.14; |
| 3 | no if $] >= 5.017011, warnings => 'experimental::smartmatch'; |
| 4 | |
| 5 | use Apache2::Authen::Passphrase qw/pwcheck/; |
| 6 | use Apache2::AuthzCaps qw/hascaps/; |
| 7 | use Gruntmaster::Data; |
| 8 | use Plack::App::Gruntmaster; |
| 9 | use Plack::Builder; |
| 10 | use Plack::Request; |
| 11 | use Digest::SHA qw/sha256/; |
| 12 | use Log::Log4perl; |
| 13 | |
| 14 | use constant ACCESSLOG_FORMAT => '%{X-Forwarded-For}i|%h %u "%r" %>s %b "%{Referer}i" "%{User-agent}i"'; |
| 15 | use constant CONTENT_SECURITY_POLICY => q,default-src 'none'; script-src 'self' www.google-analytics.com; style-src 'self'; img-src 'self' www.google-analytics.com; connect-src 'self',; |
| 16 | |
| 17 | $Apache2::AuthzCaps::rootdir = $Apache2::Authen::Passphrase::rootdir; |
| 18 | my $word = qr,(\w+),a; |
| 19 | my $number = qr,(\d+),a; |
| 20 | my $db = Gruntmaster::Data->connect('dbi:Pg:'); |
| 21 | |
| 22 | sub debug { |
| 23 | local $Log::Log4perl::caller_depth = $Log::Log4perl::caller_depth + 1; |
| 24 | $_[0]->{'psgix.logger'}->({qw/level debug message/ => $_[1]}) |
| 25 | } |
| 26 | |
| 27 | sub some_auth_required { |
| 28 | my $r = Plack::Request->new($_[0]); |
| 29 | return 1 if $_[0]->{'gruntmaster.reqadmin'} || $r->path eq '/action/passwd' || $r->path eq '/submit'; |
| 30 | return 1 if $r->path =~ m,^/pb/$word, && $_[0]->{'gruntmaster.contest'} && time < $db->contest($_[0]->{'gruntmaster.contest'})->stop; |
| 31 | '' |
| 32 | } |
| 33 | |
| 34 | sub is_problem_private { |
| 35 | my $pb = $_[0]; |
| 36 | return 1 if $db->problem($pb)->private; |
| 37 | my $prv = 0; |
| 38 | for my $cp ($db->problem($pb)->contest_problems) { |
| 39 | $prv = 1; |
| 40 | return '' if $cp->contest->start <= time; |
| 41 | } |
| 42 | |
| 43 | $prv |
| 44 | } |
| 45 | |
| 46 | sub is_problem_in_contest { |
| 47 | my ($pb, $ct) = @_; |
| 48 | return 1 if $db->contest_problems->find($ct, $pb); |
| 49 | return '' if defined $ct; |
| 50 | for my $cp ($db->problem($pb)->contest_problems) { |
| 51 | return '' if $cp->contest->stop >= time; |
| 52 | } |
| 53 | 1 |
| 54 | } |
| 55 | |
| 56 | sub admin_required { |
| 57 | local $_ = $_[0]; |
| 58 | my $env = $_[1]; |
| 59 | return $db->contest($env->{'gruntmaster.contest'})->owner->id if $env->{'gruntmaster.contest'} && $db->contest($env->{'gruntmaster.contest'})->start > time; |
| 60 | return $db->problem($1)->owner->id if m,^/pb/$word, && is_problem_private $1; |
| 61 | return $db->problem($1)->owner->id if m,^/pb/$word, && !is_problem_in_contest $1, $env->{'gruntmaster.contest'}; |
| 62 | return $db->problem($env->{'gruntmaster.problem'}) if $env->{'gruntmaster.problem'} && is_problem_private $env->{'gruntmaster.problem'}; |
| 63 | return $db->problem($env->{'gruntmaster.problem'}) if $env->{'gruntmaster.problem'} && !is_problem_in_contest $env->{'gruntmaster.problem'}, $env->{'gruntmaster.contest'}; |
| 64 | return $db->job ($1)->owner->id if m,^/log/(?:src/)?$number, && $db->job($1)->private; |
| 65 | return $db->job ($1)->owner->id if m,^/log/(?:src/)?$number, && is_problem_private $db->job($1)->problem->id; |
| 66 | return $db->job ($1)->owner->id if m,^/log/(?:src/)?$number, && $db->job($1)->contest && $db->job($1)->contest->stop > time; |
| 67 | '' |
| 68 | } |
| 69 | |
| 70 | sub require_admin { |
| 71 | my $app = $_[0]; |
| 72 | sub { |
| 73 | local *__ANON__ = "require_admin_middleware"; |
| 74 | my $env = $_[0]; |
| 75 | my $r = Plack::Request->new($env); |
| 76 | $env->{'gruntmaster.reqadmin'} = admin_required $r->path, $env; |
| 77 | $app->($env) |
| 78 | } |
| 79 | } |
| 80 | |
| 81 | sub mangle_request { |
| 82 | my $app = $_[0]; |
| 83 | sub { |
| 84 | local *__ANON__ = 'mangle_request_middleware'; |
| 85 | my $env = $_[0]; |
| 86 | my ($number, $word) = (qr,(\d+),a, qr,(\w+),a); |
| 87 | for ($env->{PATH_INFO}) { |
| 88 | $env->{'gruntmaster.page'} = $1 if s,/page/$number$,/,; |
| 89 | $env->{'gruntmaster.contest'} = $1 if s,^/ct/$word/,/,; |
| 90 | $env->{'gruntmaster.problem'} = $1 if s,^/pb/$word/,/,; |
| 91 | $env->{'gruntmaster.user'} = $1 if s,^/us/$word/,/,; |
| 92 | $env->{'gruntmaster.page'} //= -1 if m,^/log/$,; |
| 93 | } |
| 94 | $app->($env); |
| 95 | } |
| 96 | } |
| 97 | |
| 98 | my %authen_cache; |
| 99 | |
| 100 | sub authenticate { |
| 101 | my ($user, $pass, $env) = @_; |
| 102 | my $cache_key = sha256 "$user:$pass"; |
| 103 | my $time = $authen_cache{$cache_key} // 0; |
| 104 | if ($time >= time - 300) { |
| 105 | return 1; |
| 106 | } else { |
| 107 | delete $authen_cache{$cache_key}; |
| 108 | } |
| 109 | |
| 110 | return unless eval { |
| 111 | pwcheck $user, $pass; |
| 112 | 1 |
| 113 | }; |
| 114 | $authen_cache{$cache_key} = time; |
| 115 | |
| 116 | return if $env->{'gruntmaster.reqadmin'} && $env->{'gruntmaster.reqadmin'} ne $user && !hascaps $user, 'gmadm'; |
| 117 | 1 |
| 118 | } |
| 119 | |
| 120 | Log::Log4perl->init('log.conf'); |
| 121 | my $access_logger = Log::Log4perl->get_logger('access'); |
| 122 | $ENV{DBIC_NULLABLE_KEY_NOWARN} = 1; |
| 123 | |
| 124 | builder { |
| 125 | enable_if { $_[0]->{PATH_INFO} eq '/ok' } sub { sub{ [200, [], []] }}; |
| 126 | enable 'AccessLog', format => ACCESSLOG_FORMAT, logger => sub { $access_logger->info(@_) }; |
| 127 | enable 'ContentLength'; |
| 128 | enable Header => set => ['Content-Security-Policy', CONTENT_SECURITY_POLICY]; |
| 129 | enable_if { $_[0]->{PATH_INFO} =~ qr,^/static/,} Header => set => ['Cache-Control', 'public, max-age=604800']; |
| 130 | enable 'Static', path => qr,^/static/,; |
| 131 | enable 'Log4perl', category => 'plack'; |
| 132 | enable \&mangle_request; |
| 133 | enable \&require_admin; |
| 134 | enable_if \&some_auth_required, 'Auth::Basic', authenticator => \&authenticate, realm => 'Gruntmaster 6000'; |
| 135 | enable sub { my $app = $_[0]; sub { $_[0]->{'gruntmaster.dbic'} = $db; $app->($_[0]) } }; |
| 136 | Plack::App::Gruntmaster->to_app |
| 137 | } |