#!/usr/bin/perl
use v5.14;
use warnings;

use CSS::Minifier::XS qw//;
use CSS::SpriteMaker;

use Digest::SHA qw/sha256_base64/;
use IO::Compress::Gzip qw/gzip/;
use File::Slurp qw/read_file write_file edit_file_lines/;

mkdir 'static';
mkdir 'static/css';
mkdir 'static/js';

sub make_sprite {
	my $maker = Local::CSS::SpriteMaker->new(
		css_class_prefix => 'logo-',
		rc_override_classname => sub {
			my ($name) = @_;
			$name =~ s/-light/.logo-light/r;
		}
	);

	$maker->make_sprite(
		source_images     => ['logos/'],
		target_file       => 'static/logos.png',
		add_extra_padding => 10,
	);

	$maker->print_css(
		filename        => 'css/logos.css',
		sprite_filename => '/static/logos.png',
	);

	system 'pngnq-s9', '-s1', 'static/logos.png';
	system 'optipng', '-o7', '-zm1-9', 'static/logos-nq8.png';
	rename 'static/logos-nq8.png', 'static/logos.png';
}

sub gzip_file {
	my ($file) = @_;
	gzip $file => "$file.gz", -Level => 9, Minimal => 1;
}

sub make_css {
	my $common_css;
	$common_css .= read_file $_ for <css/*.css>;
	for (<css/themes/*>) {
		my ($theme) = m,themes/(.*)\.css,;
		my $css = read_file $_;
		$css .= $common_css;
		write_file "static/css/$theme.css", CSS::Minifier::XS::minify $css;
		gzip_file "static/css/$theme.css";
	}
}

sub make_js {
	system java => -jar => 'compiler.jar', qw,-O SIMPLE --create_source_map static/js/js.map --js_output_file static/js/all.js --language_in ECMASCRIPT6_STRICT --language_out ECMASCRIPT5_STRICT --source_map_location_mapping js/|/static/js/,, <js/*>;
	my $js = read_file 'static/js/all.js';
	write_file 'static/js/all.js', '//# sourceMappingURL=/static/js/js.map', "\n", $js;
	system 'cp', '-rp', 'js', 'static/';
	gzip_file 'static/js/all.js';
}

my $sprite_mtime = -M 'static/logos.png' // 0;
for (<logos/*>) {
	if (!$sprite_mtime || $sprite_mtime > -M) {
		make_sprite;
		last
	}
}

my $css_mtime = -M 'static/css/slate.css' // 0;
for (<css/*>, <css/themes/*>) {
	if (!$css_mtime || $css_mtime > -M) {
		make_css;
		last
	}
}

my $js_mtime = -M 'static/js.js' // 0;
for (<js/*>) {
	if (!$js_mtime || $js_mtime > -M) {
		make_js;
		last
	}
}

edit_file_lines {
	my ($file) = m,(static.*\.(?:css|js)),;
	return unless $file;
	my $hash = sha256_base64 scalar read_file $file;
	s/integrity=".*"/integrity="sha256-$hash="/;
} 'tmpl/skel.en';

package
  Local::CSS::SpriteMaker;

use parent qw/CSS::SpriteMaker/;

sub _get_stylesheet_string {
	my $self = shift;
	my @ret = split "\n", $self->SUPER::_get_stylesheet_string(@_);
	shift @ret;
	@ret = sort @ret;
	unshift @ret, <<EOF;
a.logo {
	background-image: url("/static/logos.png");
	background-repeat: no-repeat;
	display: inline-block;
	vertical-align: middle;
}
EOF
	join "\n", @ret;
}