#!/usr/bin/perl
use v5.14;
use warnings;

use CSS::Minifier::XS qw/minify/;
use Digest::SHA qw/sha256_base64/;
use IO::Compress::Gzip qw/gzip/;
use File::Slurp qw/read_file write_file edit_file_lines/;
use SVG::SpriteMaker;
use List::Util qw/first/;

mkdir 'static';
mkdir 'static/css';
mkdir 'static/js';
mkdir 'static/logos';

sub gzip_file {
	my ($file) = @_;
	gzip $file => "$file.gz", -Level => 9, Minimal => 1;
}

sub write_gzfile {
	my ($file, @content) = @_;
	write_file $file, @content;
	gzip_file $file
}

sub sprite_name {
	my ($name) = $_[0] =~ m,/(.*)\.svg,;
	"logo-$name"
}

sub make_logos {
	my @logos = <logos/*>;
	my $logos = make_sprite \&sprite_name, @logos;
	my @logos_light;
	for (<logos/*>) {
		my $light = s/logos/logos-light/r;
		push @logos_light, -f $light ? $light : $_;
	}
	my $logos_light = make_sprite \&sprite_name, @logos_light;

	write_gzfile 'static/logos/dark.svg', $logos->render;
	write_gzfile 'static/logos/light.svg', $logos_light->render;
}

sub read_css_into_blocks {
	my ($file) = @_;
	my (@blocks, $block);
	for (read_file $file) {
		$block .= $_;
		if (/^}/) {
			push @blocks, $block;
			$block = '';
		}
	}
	\@blocks
}

sub make_css {
	my %css;
	$css{common} .= read_file $_ for <css/*.css>;

	my (%themes, $rndtheme);
	for (<css/themes/*>) {
		($rndtheme) = m,themes/(.*)\.css,;
		$themes{$rndtheme} = read_css_into_blocks $_;
	}

	while (grep { scalar @$_ } values %themes) {
		my %blocks = map { $_ => (shift @{$themes{$_}}) // '' } keys %themes;
		if (grep { $_ ne $blocks{$rndtheme} } values %blocks) {
			$css{$_} .= $blocks{$_} for keys %themes;
		} else {
			$css{common} .= $blocks{$rndtheme};
		}
	}

	write_gzfile "static/css/$_.css", minify $css{$_} for keys %css
}

sub make_js {
	system java => -jar => 'compiler.jar', qw,-O SIMPLE --create_source_map static/js/js.map --js_output_file static/js/all.js --language_in ECMASCRIPT6_STRICT --language_out ECMASCRIPT5_STRICT --source_map_location_mapping js/|/static/js/,, <js/*>;
	my $js = read_file 'static/js/all.js';
	write_gzfile 'static/js/all.js', '//# sourceMappingURL=/static/js/js.map', "\n", $js;
	system 'cp', '-rp', 'js', 'static/';
}

my $sprite_mtime = -M 'static/logos/dark.svg' // 0;
for (<logos/*>, <logos-light/*>) {
	if (!$sprite_mtime || $sprite_mtime > -M) {
		make_logos;
		last
	}
}

my $css_mtime = -M 'static/css/slate.css' // 0;
for (<css/*>, <css/themes/*>) {
	if (!$css_mtime || $css_mtime > -M) {
		make_css;
		last
	}
}

my $js_mtime = -M 'static/js/all.js' // 0;
for (<js/*>) {
	if (!$js_mtime || $js_mtime > -M) {
		make_js;
		last
	}
}

edit_file_lines {
	my ($file) = m,(static.*\.(?:css|js)),;
	return unless $file;
	my $hash = sha256_base64 scalar read_file $file;
	s/integrity=".*"/integrity="sha256-$hash="/;
} 'tmpl/skel.en';