lib/App/MusicExpo.pm

   1 package App::MusicExpo 0.002;
   2 use v5.14;
   3 use strict;
   4 use warnings;
   5
   6 use Audio::FLAC::Header qw//;
   7 use HTML::Template::Compiled qw//;
   8 use Memoize qw/memoize/;
   9 use MP3::Tag qw//;
  10 use Ogg::Vorbis::Header::PurePerl;
  11
  12 use DB_File qw//;
  13 use File::Basename qw/fileparse/;
  14 use Fcntl qw/O_RDWR O_CREAT/;
  15 use Getopt::Long;
  16 use Storable qw/thaw freeze/;
  17
  18 ##################################################
  19
  20 my $default_template;
  21
  22 our $prefix='/music/';
  23 our $cache='';
  24 our $template='';
  25
  26 GetOptions (
  27   "template=s" => \$template,
  28   "prefix=s" => \$prefix,
  29   "cache=s" => \$cache,
  30 );
  31
  32
  33 sub fix{
  34   utf8::decode($_[0]);
  35   $_[0]
  36 }
  37
  38 sub flacinfo{
  39   my $file=$_[0];
  40   my $flac=Audio::FLAC::Header->new($file);
  41   $file = $prefix . scalar fileparse $file;
  42
  43   freeze +{
  44         format => 'FLAC',
  45         title => fix ($flac->tags('TITLE') // '?'),
  46         artist => fix ($flac->tags('ARTIST') // '?'),
  47         year => fix ($flac->tags('DATE') // '?'),
  48         album => fix ($flac->tags('ALBUM') // '?'),
  49         tracknumber => fix ($flac->tags('TRACKNUMBER') // '?'),
  50         tracktotal => fix ($flac->tags('TRACKTOTAL') // '?'),
  51         genre => fix ($flac->tags('GENRE') // '?'),
  52         path => $file,
  53   }
  54 }
  55
  56 sub mp3info{
  57   my $file=$_[0];
  58   my $mp3=MP3::Tag->new($file);
  59   $file = $prefix . scalar fileparse $file;
  60
  61   freeze +{
  62         format => 'MP3',
  63         title => fix ($mp3->title || '?'),
  64         artist => fix ($mp3->artist || '?'),
  65         year => fix ($mp3->year || '?'),
  66         album => fix ($mp3->album || '?'),
  67         tracknumber => fix ($mp3->track1 || '?'),
  68         tracktotal => fix ($mp3->track2 || '?'),
  69         genre => fix ($mp3->genre) || '?',
  70         path => $file,
  71   }
  72 }
  73
  74 sub vorbisinfo{
  75   my $file=$_[0];
  76   my $ogg=Ogg::Vorbis::Header::PurePerl->new($file);
  77
  78   freeze +{
  79         format => 'Vorbis',
  80         title => fix($ogg->comment('TITLE') || '?'),
  81         artist => fix ($ogg->comment('artist') || '?'),
  82         year => fix ($ogg->comment('DATE') || '?'),
  83         album => fix ($ogg->comment('ALBUM') || '?'),
  84         tracknumber => fix ($ogg->comment('TRACKNUMBER') || '?'),
  85         tracktotal => fix ($ogg->comment('TRACKTOTAL') || '?'),
  86         genre => fix ($ogg->comment('GENRE')) || '?',
  87         path => $file,
  88   }
  89 }
  90
  91 sub normalizer{
  92   "$_[0]|".(stat $_[0])[9]
  93 }
  94
  95 sub run {
  96   tie my %cache, 'DB_File', $cache, O_RDWR|O_CREAT, 0644 unless $cache eq '';
  97   memoize 'flacinfo', NORMALIZER => \&normalizer, LIST_CACHE => 'MERGE', SCALAR_CACHE => [HASH => \%cache] unless $cache eq '';
  98   memoize 'mp3info' , NORMALIZER => \&normalizer, LIST_CACHE => 'MERGE', SCALAR_CACHE => [HASH => \%cache] unless $cache eq '';
  99   memoize 'vorbisinfo' , NORMALIZER => \&normalizer, LIST_CACHE => 'MERGE', SCALAR_CACHE => [HASH => \%cache] unless $cache eq '';
 100
 101   my @files;
 102   for my $file (@ARGV) {
 103         push @files, thaw flacinfo $file if $file =~ /.flac$/i;
 104         push @files, thaw mp3info $file if $file =~ /.mp3$/i;
 105         push @files, thaw vorbisinfo $file if $file =~ /.og(?:g|a)$/i;
 106   }
 107
 108   my $ht=HTML::Template::Compiled->new(
 109         default_escape => 'HTML',
 110         $template eq '' ? (scalarref => \$default_template) : (filename => $template),
 111   );
 112   $ht->param(files=>[sort { $a->{title} cmp $b->{title} } @files]);
 113   print $ht->output;
 114 }
 115
 116 $default_template = <<'HTML';
 117 <!DOCTYPE html>
 118 <title>Music</title>
 119 <meta charset="utf-8">
 120 <link rel="stylesheet" href="/music.css">
 121
 122 <table border>
 123 <thead>
 124 <tr><th>Title<th>Artist<th>Album<th>Genre<th>Track<th>Year<th>Type
 125 <tbody><tmpl_loop files>
 126 <tr><td><a href="<tmpl_var ESCAPE=URL path>"><tmpl_var title></a><td><tmpl_var artist><td><tmpl_var album><td><tmpl_var genre><td><tmpl_var tracknumber>/<tmpl_var tracktotal><td><tmpl_var year><td><tmpl_var format></tmpl_loop>
 127 </table>
 128 HTML
 129
 130 1;
 131
 132 __END__
 133
 134 =head1 NAME
 135
 136 App::MusicExpo - script which generates a HTML table of music tags
 137
 138 =head1 SYNOPSIS
 139
 140   use App::MusicExpo;
 141   App::MusicExpo->run;
 142
 143 =head1 DESCRIPTION
 144
 145 App::MusicExpo creates a HTML table from a list of songs.
 146
 147 The default template looks like:
 148
 149     | Title   | Artist  | Album           | Genre   | Track | Year | Type |
 150     |---------+---------+-----------------+---------+-------+------+------|
 151     | Cellule | Silence | L'autre endroit | Electro | 01/09 | 2005 | FLAC |
 152
 153 where the title is a download link.
 154
 155 =head1 OPTIONS
 156
 157 =over
 158
 159 =item B<--template> I<template>
 160
 161 Path to the HTML::Template::Compiled template used for generating the music table. If '' (empty), uses the default format. Is empty by default.
 162
 163 =item B<--prefix> I<prefix>
 164
 165 Prefix for download links. Defaults to '/music/'.
 166
 167 =item B<--cache> I<filename>
 168
 169 Path to the cache file. Created if it does not exist. If '' (empty), disables caching. Is empty by default.
 170
 171 =back
 172
 173 =head1 AUTHOR
 174
 175 Marius Gavrilescu, E<lt>marius@ieval.roE<gt>
 176
 177 =head1 COPYRIGHT AND LICENSE
 178
 179 Copyright (C) 2013 by Marius Gavrilescu
 180
 181 This library is free software; you can redistribute it and/or modify
 182 it under the same terms as Perl itself, either Perl version 5.14.2 or,
 183 at your option, any later version of Perl 5 you may have available.