lib/App/MusicExpo.pm

   1 package App::MusicExpo;
   2 use v5.14;
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION = '0.003003';
   7
   8 use Audio::FLAC::Header qw//;
   9 use HTML::Template::Compiled qw//;
  10 use Memoize qw/memoize/;
  11 use MP3::Tag qw//;
  12 use Ogg::Vorbis::Header::PurePerl;
  13
  14 use DB_File qw//;
  15 use File::Basename qw/fileparse/;
  16 use Fcntl qw/O_RDWR O_CREAT/;
  17 use Getopt::Long;
  18 use JSON::MaybeXS;
  19 use Storable qw/thaw freeze/;
  20
  21 ##################################################
  22
  23 my $default_template;
  24
  25 our $prefix='/music/';
  26 our $cache='';
  27 our $template='';
  28
  29 GetOptions (
  30         "template:s" => \$template,
  31         "prefix:s" => \$prefix,
  32         "cache:s" => \$cache,
  33 );
  34
  35
  36 sub fix{
  37         my $copy = $_[0];
  38         utf8::decode($copy);
  39         $copy
  40 }
  41
  42 sub flacinfo{
  43         my $file=$_[0];
  44         my $flac=Audio::FLAC::Header->new($file);
  45         $file = scalar fileparse $file;
  46
  47         freeze +{
  48                 format => 'FLAC',
  49                 title => fix ($flac->tags('TITLE') // '?'),
  50                 artist => fix ($flac->tags('ARTIST') // '?'),
  51                 year => fix ($flac->tags('DATE') // '?'),
  52                 album => fix ($flac->tags('ALBUM') // '?'),
  53                 tracknumber => fix ($flac->tags('TRACKNUMBER') // '?'),
  54                 tracktotal => fix ($flac->tags('TRACKTOTAL') // '?'),
  55                 genre => fix ($flac->tags('GENRE') // '?'),
  56                 file => $file,
  57         }
  58 }
  59
  60 sub mp3info{
  61         my $file=$_[0];
  62         my $mp3=MP3::Tag->new($file);
  63         $file = scalar fileparse $file;
  64
  65         freeze +{
  66                 format => 'MP3',
  67                 title => fix ($mp3->title || '?'),
  68                 artist => fix ($mp3->artist || '?'),
  69                 year => fix ($mp3->year || '?'),
  70                 album => fix ($mp3->album || '?'),
  71                 tracknumber => fix ($mp3->track1 || '?'),
  72                 tracktotal => fix ($mp3->track2 || '?'),
  73                 genre => fix ($mp3->genre) || '?',
  74                 file => $file,
  75         }
  76 }
  77
  78 sub vorbisinfo{
  79         my $file=$_[0];
  80         my $ogg=Ogg::Vorbis::Header::PurePerl->new($file);
  81         $file = scalar fileparse $file;
  82
  83         freeze +{
  84                 format => 'Vorbis',
  85                 title => fix($ogg->comment('TITLE') || '?'),
  86                 artist => fix ($ogg->comment('artist') || '?'),
  87                 year => fix ($ogg->comment('DATE') || '?'),
  88                 album => fix ($ogg->comment('ALBUM') || '?'),
  89                 tracknumber => fix ($ogg->comment('TRACKNUMBER') || '?'),
  90                 tracktotal => fix ($ogg->comment('TRACKTOTAL') || '?'),
  91                 genre => fix ($ogg->comment('GENRE')) || '?',
  92                 file => $file,
  93         }
  94 }
  95
  96 sub normalizer{
  97         "$_[0]|".(stat $_[0])[9]
  98 }
  99
 100 sub run {
 101         if ($cache) {
 102                 tie my %cache, 'DB_File', $cache, O_RDWR|O_CREAT, 0644;
 103                 memoize $_, NORMALIZER => \&normalizer, LIST_CACHE => 'MERGE', SCALAR_CACHE => [HASH => \%cache] for qw/flacinfo mp3info vorbisinfo/;
 104         }
 105
 106         my %files;
 107         for my $file (@ARGV) {
 108                 my $info;
 109                 $info = thaw flacinfo $file if $file =~ /\.flac$/i;
 110                 $info = thaw mp3info $file if $file =~ /\.mp3$/i;
 111                 $info = thaw vorbisinfo $file if $file =~ /\.og(?:g|a)$/i;
 112                 next unless defined $info;
 113                 my $basename = fileparse $file, '.flac', '.mp3', '.ogg', '.oga';
 114                 $files{$basename} //= [];
 115                 push $files{$basename}, $info;
 116         }
 117
 118         my $ht=HTML::Template::Compiled->new(
 119                 default_escape => 'HTML',
 120                 global_vars => 2,
 121                 $template eq '' ? (scalarref => \$default_template) : (filename => $template),
 122         );
 123
 124         my @files;
 125         for (values %files) {
 126                 my @versions = @$_;
 127                 my %entry = (%{$versions[0]}, formats => []);
 128                 push $entry{formats}, {format => $_->{format}, file => $_->{file}} for @versions;
 129                 push @files, \%entry
 130         }
 131
 132         my $json = JSON::MaybeXS->new(canonical => 1)->encode({files => \@files, prefix => $prefix});
 133         $json =~ s/</&lt;/g;
 134         $json =~ s/>/&gt;/g;
 135         $ht->param(files=>[sort { $a->{title} cmp $b->{title} } @files], prefix => $prefix, json => $json);
 136         print $ht->output;
 137 }
 138
 139 $default_template = <<'HTML';
 140 <!DOCTYPE html>
 141 <title>Music</title>
 142 <meta charset="utf-8">
 143 <link rel="stylesheet" href="/music.css">
 144
 145 <table border>
 146 <thead>
 147 <tr><th>Title<th>Artist<th>Album<th>Genre<th>Track<th>Year<th>Type
 148 <tbody><tmpl_loop files>
 149 <tr><td><tmpl_var title><td><tmpl_var artist><td><tmpl_var album><td><tmpl_var genre><td><tmpl_var tracknumber>/<tmpl_var tracktotal><td><tmpl_var year><td><tmpl_loop formats><a href="<tmpl_var ...prefix><tmpl_var ESCAPE=URL file>"><tmpl_var format></a> </tmpl_loop></tmpl_loop>
 150 </table>
 151
 152 <pre id="json" style="display: none"><tmpl_var ESCAPE=0 json></pre>
 153 HTML
 154
 155 1;
 156
 157 __END__
 158
 159 =encoding utf-8
 160
 161 =head1 NAME
 162
 163 App::MusicExpo - script which generates a HTML table of music tags
 164
 165 =head1 SYNOPSIS
 166
 167   use App::MusicExpo;
 168   App::MusicExpo->run;
 169
 170 =head1 DESCRIPTION
 171
 172 App::MusicExpo creates a HTML table from a list of songs.
 173
 174 The default template looks like:
 175
 176     | Title   | Artist  | Album           | Genre   | Track | Year | Type |
 177     |---------+---------+-----------------+---------+-------+------+------|
 178     | Cellule | Silence | L'autre endroit | Electro | 01/09 | 2005 | FLAC |
 179
 180 where the type is a download link. If you have multiple files with the same
 181 basename (such as C<cellule.flac> and C<cellule.ogg>), they will be treated
 182 as two versions of the same file, so a row will be created with two download
 183 links, one for each format.
 184
 185 =head1 OPTIONS
 186
 187 =over
 188
 189 =item B<--template> I<template>
 190
 191 Path to the HTML::Template::Compiled template used for generating the music table. If '' (empty), uses the default format. Is empty by default.
 192
 193 =item B<--prefix> I<prefix>
 194
 195 Prefix for download links. Defaults to '/music/'.
 196
 197 =item B<--cache> I<filename>
 198
 199 Path to the cache file. Created if it does not exist. If '' (empty), disables caching. Is empty by default.
 200
 201 =back
 202
 203 =head1 AUTHOR
 204
 205 Marius Gavrilescu, E<lt>marius@ieval.roE<gt>
 206
 207 =head1 COPYRIGHT AND LICENSE
 208
 209 Copyright (C) 2013-2014 by Marius Gavrilescu
 210
 211 This library is free software; you can redistribute it and/or modify
 212 it under the same terms as Perl itself, either Perl version 5.14.2 or,
 213 at your option, any later version of Perl 5 you may have available.