lib/Gruntmaster/Daemon.pm

   1 package Gruntmaster::Daemon;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '5999.000_005';
   8
   9 use Gruntmaster::Daemon::Constants qw/ERR/;
  10 use Gruntmaster::Daemon::Format qw/prepare_files copy_from_vm stopvms/;
  11 use Gruntmaster::SendResults qw/send_results_request/;
  12
  13 use File::Slurp qw/read_file/;
  14 use File::Temp qw/tempdir/;
  15 use JSON qw/decode_json encode_json/;
  16 use Sys::Hostname qw/hostname/;
  17 use Try::Tiny;
  18 use Log::Log4perl qw/get_logger/;
  19
  20 use constant FORMAT_EXTENSION => {
  21         BRAINFUCK => 'bf',
  22         C => 'c',
  23         CPP => 'cpp',
  24         D => 'd',
  25         GCCGO => 'go',
  26         GOLANG => 'go',
  27         GOLFSCRIPT => 'gs',
  28         HASKELL => 'hs',
  29         JAVA => 'java',
  30         JAVASCRIPT => 'js',
  31         JULIA => 'jl',
  32         MONO => 'cs',
  33         OBERON => 'm',
  34         OCAML => 'ml',
  35         PASCAL => 'pas',
  36         PERL => 'pl',
  37         PHP => 'php',
  38         PYTHON => 'py',
  39         PYTHON3 => 'py',
  40         RUBY => 'rb',
  41         RUST => 'rs',
  42         SBCL => 'l',
  43 };
  44
  45 ##################################################
  46
  47 sub safe_can {
  48         my ($type, $sub, $name) = @_;
  49
  50         get_logger->logdie("Invalid \l$type: '$name'") unless $name =~ /^\w+$/s;
  51         my $pkg = __PACKAGE__ . "::${type}::${name}";
  52         eval "require $pkg" or get_logger->warn("Error while requiring $pkg: $@");
  53         $pkg->can($sub) or get_logger->logdie("No such \l$type: '$name'");
  54 }
  55
  56 sub process{
  57         my ($meta) = @_;
  58
  59         my @results;
  60         my @full_results = ();
  61         our $errors = '';
  62         try {
  63                 prepare_files $meta;
  64                 chomp $errors;
  65
  66                 my ($files, $generator, $runner, $judge, $testcnt) = map { $meta->{$_} or die "Required parameter missing: $_\n"} qw/files generator runner judge testcnt/;
  67
  68                 $generator = safe_can Generator => generate => $generator;
  69                 $runner = safe_can Runner => run => $runner;
  70                 $judge = safe_can Judge => judge => $judge;
  71
  72                 for my $test (1 .. $testcnt) {
  73                         my $result;
  74                         unlink 'result';
  75                         try {
  76                                 $generator->($test, $meta);
  77                                 $result = $runner->($test, $meta);
  78                         } catch {
  79                                 $result = $_;
  80                                 unless (ref $result) {
  81                                         chomp $result;
  82                                         $result = [ERR, $result];
  83                                 }
  84                         };
  85
  86                         my $time = '?';
  87                         $time = (read_file 'time-stop-prog') - (read_file 'time-start-prog') if -f 'time-stop-prog' && -f 'time-start-prog';
  88                         unlink 'time-start-prog', 'time-stop-prog';
  89                         if (ref $result) {
  90                                 my $result_text = $result->[1];
  91                                 copy_from_vm 'result';
  92                                 $result_text .= ': ' . read_file 'result' if -s 'result';
  93                                 get_logger->trace("Test $test result is " . $result_text);
  94                                 push @full_results, {id => $test, result => $result->[0], result_text => $result_text, time => $time}
  95                         } else {
  96                                 get_logger->trace("Test $test result is $result");
  97                                 push @full_results, {id => $test, result => 0, result_text => $result, time => $time}
  98                         }
  99                         push @results, $result;
 100                         last if $meta->{judge} eq 'Absolute' && ref $result
 101                 }
 102
 103                 my %results = $judge->(@results);
 104                 $meta->{$_} = $results{$_} for keys %results;
 105                 $meta->{results} = \@full_results
 106         } catch {
 107                 s/(.*) at .*/$1/s;
 108                 chomp;
 109                 $meta->{result} = -1;
 110                 $meta->{result_text} = $_;
 111         };
 112         stopvms;
 113         $meta->{errors} = $errors;
 114
 115         get_logger->info('Job result: ' . $meta->{result_text});
 116         send_results_request($meta->{job_id}, $meta->{result}, $meta->{result_text});
 117 }
 118
 119 sub process_job {
 120         my ($job) = @_;
 121         my $pb = db()->select('problems', '*', {id => $job->{problem}})->hash;
 122         my $meta = {
 123                 problem => $job->{problem},
 124                 files => {
 125                         prog => {
 126                                 name => 'prog.' . $job->{extension},
 127                                 format => $job->{format},
 128                                 content => $job->{source},
 129                         },
 130                 },
 131                 map { $_ => $pb->{$_} } qw/generator runner judge precnt testcnt timeout olimit/
 132         };
 133         my $timeout_override = db()->query('SELECT timeout FROM limits WHERE problem=? AND format=?', $job->{problem}, $job->{format})->list;
 134         $meta->{timeout} = $timeout_override if defined $timeout_override;
 135         $meta->{tests} = decode_json $pb->{tests} if $meta->{runner} eq 'File';
 136         my $contest = $job->{contest} && contest_entry($job->{contest});
 137         delete $meta->{precnt} unless $contest && $contest->{started} && !$contest->{finished}; ## no critic (ProhibitNegativeExpressionsInUnlessAndUntilConditions)
 138         $meta->{testcnt} = $meta->{precnt} if $meta->{precnt};
 139
 140         $meta->{files}{ver} = {
 141                 name => 'ver.' . FORMAT_EXTENSION->{$pb->{verformat}},
 142                 format => $pb->{verformat},
 143                 content => $pb->{versource},
 144         } if $pb->{verformat};
 145         $meta->{job_id} = $job->{id};
 146
 147         process $meta;
 148
 149         $meta->{result_text} .= ' (pretests)' if $meta->{precnt};
 150         finish_job($job, $job->{private} || $pb->{private},
 151           result => $meta->{result},
 152           result_text => $meta->{result_text},
 153           ($meta->{results} ? (results => encode_json $meta->{results}) : ()),
 154           $meta->{errors} ? (errors => $meta->{errors}) : ());
 155 }
 156
 157 sub got_job{
 158         my $job = $_[0];
 159         my $id = $job->{id};
 160         get_logger->debug("Processing job $id...");
 161         process_job $job;
 162         get_logger->debug("Job $id done");
 163 }
 164
 165 my $daemon = hostname . ":$$";
 166
 167 sub run{
 168         require Gruntmaster::Data;
 169         Gruntmaster::Data->import;
 170         dbinit($ENV{GRUNTMASTER_DSN} // 'dbi:Pg:');
 171         Log::Log4perl->init('/etc/gruntmasterd/gruntmasterd-log.conf');
 172         get_logger->info("gruntmasterd $VERSION started ($daemon)");
 173         my $dir = tempdir 'gruntmasterd.XXXX', CLEANUP => 1, TMPDIR => 1;
 174         chmod 0711, $dir;
 175         chdir $dir;
 176         while (1) {
 177                 my $job = take_job($daemon);
 178                 got_job $job if defined $job;
 179                 sleep 2 unless defined $job;
 180         }
 181 }
 182
 183 1;
 184 __END__
 185
 186 =head1 NAME
 187
 188 Gruntmaster::Daemon - Gruntmaster 6000 Online Judge -- daemon
 189
 190 =head1 SYNOPSIS
 191
 192   use Gruntmaster::Daemon;
 193   Gruntmaster::Daemon->run;
 194
 195 =head1 DESCRIPTION
 196
 197 Gruntmaster::Daemon is the daemon component of the Gruntmaster 6000 online judge.
 198
 199 =head1 AUTHOR
 200
 201 Marius Gavrilescu E<lt>marius@ieval.roE<gt>
 202
 203 =head1 COPYRIGHT AND LICENSE
 204
 205 Copyright (C) 2014 by Marius Gavrilescu
 206
 207 This library is free software: you can redistribute it and/or modify
 208 it under the terms of the GNU Affero General Public License as published by
 209 the Free Software Foundation, either version 3 of the License, or
 210 (at your option) any later version.
 211
 212
 213 =cut