lib/Plack/App/Gruntmaster/HTML.pm

   1 package Plack::App::Gruntmaster::HTML;
   2 use v5.14;
   3 use parent qw/Exporter/;
   4 our @EXPORT = qw/render render_article/;
   5
   6 use File::Slurp qw/read_file/;
   7 use HTML::Seamstress;
   8 use POSIX qw//;
   9 use Data::Dumper qw/Dumper/;
  10
  11 sub ftime ($)   { POSIX::strftime '%c', localtime shift }
  12 sub literal ($) { HTML::Element::Library::super_literal shift // '' }
  13
  14 sub HTML::Element::edit_href {
  15         my ($self, $sub) = @_;
  16         local $_ = $self->attr('href');
  17         $sub->();
  18         $self->attr(href => $_);
  19 }
  20
  21 sub HTML::Element::iter3 {
  22         my ($self, $data, $code) = @_;
  23         my $orig = $self;
  24         my $prev = $orig;
  25         for my $el (@$data) {
  26                 my $current = $orig->clone;
  27                 $code->($el, $current);
  28                 $prev->postinsert($current);
  29                 $prev = $current;
  30         }
  31         $orig->detach;
  32 }
  33
  34 sub HTML::Element::fid    { shift->look_down(id    => shift) }
  35 sub HTML::Element::fclass { shift->look_down(class => qr/\b$_[0]\b/) }
  36
  37 sub HTML::Element::namedlink {
  38         my ($self, $id, $name) = @_;
  39         $name = $id unless $name =~ /[[:graph:]]/;
  40         $self = $self->find('a');
  41         $self->edit_href(sub {s/id/$id/});
  42         $self->replace_content($name);
  43 }
  44
  45 sub render {
  46         my ($tmpl, $lang, %args) = @_;
  47         $lang //= 'en';
  48         my $meat = _render($tmpl, $lang, %args);
  49         _render('skel', $lang, %args, meat => $meat)
  50 }
  51
  52 sub render_article {
  53         my ($art, $lang) = @_;
  54         $lang //= 'en';
  55         my $title = read_file "a/$art.$lang.title";
  56         my $meat  = read_file "a/$art.$lang";
  57         _render('skel', $lang, title => $title , meat => $meat)
  58 }
  59
  60 sub _render {
  61         my ($tmpl, $lang, %args) = @_;
  62         my $builder = HTML::Seamstress->new;
  63         $builder->ignore_unknown(0);
  64         my $tree = $builder->parse_file("tmpl/$tmpl.$lang");
  65         $tree = $tree->guts unless $tmpl eq 'skel';
  66         $tree->defmap(smap => \%args);
  67         my $process = __PACKAGE__->can("process_$tmpl");
  68         $process->($tree, %args) if $process;
  69         $tree->as_HTML;
  70 }
  71
  72 sub process_skel {
  73         my ($tree, %args) = @_;
  74         $tree->fid('logo')->replace_with(literal scalar read_file "mclogo.svg");
  75         $tree->content_handler(
  76                 title   =>         $args{title},
  77                 content => literal $args{meat});
  78 }
  79
  80 sub process_us_entry {
  81         my ($tree, %args) = @_;
  82         $tree->fid($_)->attr('href', "/$_/?owner=$args{id}") for qw/log pb/;
  83         $tree->fid('track_user')->attr('data-user', $args{id});
  84         my @solved = map { $_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  85         my @attempted = map { !$_->{solved} ? ($_->{problem}) : () } @{$args{problems}};
  86
  87         my $pbiter = sub {
  88                 my ($data, $li) = @_;
  89                 $li->find('a')->namedlink($data);
  90         };
  91         $tree->fid('solved')->find('li')->iter3(\@solved, $pbiter);
  92         $tree->fid('attempted')->find('li')->iter3(\@attempted, $pbiter);
  93         $tree->fid('solved_count')->replace_content(scalar @solved);
  94         $tree->fid('attempted_count')->replace_content(scalar @attempted);
  95
  96         my $ctiter = sub {
  97                 my ($data, $td) = @_;
  98                 $td->fclass('contest')->namedlink($data->{contest}, $data->{contest_name});
  99                 $td->fclass('score')->replace_content($data->{score});
 100                 $td->fclass('rank')->replace_content($data->{rank});
 101         };
 102         $tree->find('table')->find('tbody')->find('tr')->iter3($args{contests}, $ctiter);
 103 }
 104
 105 sub process_us {
 106         my ($tree, %args) = @_;
 107         my $iter = sub {
 108                 my ($data, $tr) = @_;
 109                 $tr->fclass('user')->namedlink($data->{id}, $data->{name});
 110                 $tr->fclass($_)->replace_content($data->{$_}) for qw/solved attempted contests/;
 111         };
 112         $tree->find('tbody')->find('tr')->iter3($args{us}, $iter);
 113 }
 114
 115 sub process_ct_entry {
 116         my ($tree, %args) = @_;
 117         $_->edit_href (sub {s/contest_id/$args{id}/}) for $tree->find('a');
 118         $tree->fid('editorial')->detach unless $args{finished};
 119         $tree->fid('links')->detach unless $args{started};
 120         my $status = ($args{time} < $args{start} ? 'starts' : 'ends');
 121         $tree->fclass('timer')->attr('data-stop', $status eq 'ends' ? $args{stop} : $args{start});
 122         $tree->content_handler(
 123                 start       => ftime   $args{start},
 124                 stop        => ftime   $args{stop},
 125                 status      => $status,
 126                 description => literal $args{description});
 127         $tree->fid('ctcountdown')->detach if $args{time} >= $args{stop};
 128 }
 129
 130 sub process_ct {
 131         my ($tree, %args) = @_;
 132         my $iter = sub {
 133                 my ($data, $tr) = @_;
 134                 $data->{$_} = ftime $data->{$_} for qw/start stop/;
 135                 $tr->hashmap(class => $data, [qw/name owner/]);
 136                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 137                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 138         };
 139         $args{$_} ? $tree->fid($_)->find('tbody')->find('tr')->iter3($args{$_}, $iter) : $tree->fid($_)->detach for qw/running pending finished/;
 140 }
 141
 142 sub process_pb_entry {
 143         my ($tree, %args) = @_;
 144         $tree->fid('owner')->edit_href(sub{s/owner_id/$args{owner}/});
 145         $tree->fid('job_log')->edit_href(sub{s/problem_id/$args{id}/});
 146         $tree->fid('solution')->edit_href(sub{s/problem_id/$args{id}/});
 147         $tree->fid('job_log')->edit_href(sub{$_ .= "&private=$args{private}"}) if $args{private};
 148         $tree->content_handler(
 149                 statement => literal $args{statement},
 150                 level     => ucfirst $args{level},
 151                 author    =>         $args{author},
 152                 owner     =>         $args{owner_name} || $args{owner});
 153         if ($args{contest_stop}) {
 154                 $tree->fid('solution')->detach;
 155                 $tree->fid('solution_modal')->detach;
 156                 my $score = $tree->fid('score');
 157                 $score->attr('data-start' => $args{open_time});
 158                 $score->attr('data-stop'  => $args{contest_stop});
 159                 $score->attr('data-value'  => $args{value});
 160                 $tree->fid('countdown')->attr('data-stop' => $args{contest_stop});
 161         } else {
 162                 $tree->fid('solution')->detach unless $args{solution};
 163                 $_->detach for $tree->fclass('rc'); # requires contest
 164                 $tree->fid('solution_modal')->fclass('modal-body')->replace_content(literal $args{solution});
 165         }
 166         if ($args{cansubmit}) {
 167                 $tree->fid('nosubmit')->detach;
 168                 $tree->look_down(name => 'problem')->attr(value => $args{id});
 169                 my $contest = $tree->look_down(name => 'contest');
 170                 $contest->attr(value => $args{contest}) if $args{contest};
 171                 $contest->detach unless $args{contest}
 172         } else {
 173                 $tree->fid('nosubmit')->find('a')->edit_href(sub{s/id/$args{id}/});
 174                 $tree->fid('submit')->detach
 175         }
 176 }
 177
 178 sub process_sol {
 179         my ($tree, %args) = @_;
 180         $tree->content_handler(solution => literal $args{solution});
 181 }
 182
 183 sub process_pb {
 184         my ($tree, %args) = @_;
 185         my $titer = sub {
 186                 my ($data, $tr) = @_;
 187                 $tr->set_child_content(class => 'author', $data->{author});
 188                 $tr->fclass('name')->namedlink($data->{id}, $data->{name});
 189                 $tr->fclass('name')->find('a')->edit_href(sub {$_ .= "?contest=$args{contest}"}) if $args{contest};
 190                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 191                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 192         };
 193         my $iter = sub {
 194                 my ($data, $div) = @_;
 195                 $div->attr(id => $data);
 196                 $div->find('h2')->replace_content(ucfirst $data);
 197                 $div->find('tbody')->find('tr')->iter3($args{$data}, $titer);
 198         };
 199         $tree->fid('beginner')->iter3([grep {$args{$_}} qw/beginner easy medium hard/], $iter);
 200         $tree->fid('open-alert')->detach unless $args{contest};
 201 }
 202
 203 sub process_log_entry {
 204         my ($tree, %args) = @_;
 205         $tree->fid('problem')->namedlink(@args{qw/problem problem_name/});
 206         $tree->fid('owner')->namedlink(@args{qw/owner owner_name/});
 207         $tree->fid('source')->namedlink("$args{id}.$args{extension}", sprintf '%.2fKB', $args{size}/1024);
 208         if ($args{contest}) {
 209                 $tree->fid('contest')->namedlink(@args{qw/contest contest_name/});
 210                 $tree->fid('problem')->find('a')->edit_href(sub {$_.="?contest=$args{contest}"});
 211         } else {
 212                 $tree->fid('contest')->left->detach;
 213                 $tree->fid('contest')->detach;
 214         }
 215
 216         $args{errors} ? $tree->fid('errors')->find('pre')->replace_content($args{errors}) : $tree->fid('errors')->detach;
 217         my $iter = sub {
 218                 my ($data, $tr) = @_;
 219                 $data->{time} = sprintf '%.4fs', $data->{time};
 220                 $tr->defmap(class => $data);
 221                 $tr->fclass('result_text')->attr(class => "r$data->{result}")
 222         };
 223         $tree->fclass('result_text')->replace_content($args{result_text});
 224         $tree->fclass('result_text')->attr(class => "r$args{result}");
 225         $args{results} ? $tree->fid('results')->find('tbody')->find('tr')->iter3($args{results}, $iter) : $tree->fid('results')->detach;
 226         $tree->fid('no_results')->detach if $tree->fid('results') || $tree->fid('errors');
 227 }
 228
 229 sub process_log {
 230         my ($tree, %args) = @_;
 231         my $iter = sub {
 232                 my ($data, $tr) = @_;
 233                 $tr->fclass('id')->namedlink($data->{id});
 234                 $tr->fclass('problem')->namedlink($data->{problem}, $data->{problem_name});
 235                 $tr->fclass('problem')->find('a')->edit_href(sub{$_ .= "?contest=$args{contest}"}) if $args{contest};
 236                 $tr->fclass('contest')->namedlink($data->{contest}, $data->{contest_name}) if $data->{contest};
 237                 $tr->fclass('contest')->replace_content('None') unless $data->{contest};
 238                 $tr->fclass('date')->replace_content(ftime $data->{date});
 239                 $tr->fclass('format')->replace_content($data->{format});
 240                 $tr->fclass('size')->namedlink("$data->{id}.$data->{extension}", sprintf "%.2fKB", $data->{size}/1024);
 241                 $tr->fclass('size')->attr('data-private', '') if $data->{private};
 242                 $tr->fclass('owner')->namedlink($data->{owner}, $data->{owner_name});
 243                 $tr->fclass('result_text')->replace_content($data->{result_text});
 244                 $tr->fclass('result_text')->attr(class => "r$data->{result}");
 245                 $tr->find('td')->attr(class => $tr->find('td')->attr('class').' warning') if $data->{private};
 246         };
 247         $tree->find('table')->find('tbody')->find('tr')->iter3($args{log}, $iter);
 248         $args{next_page} ? $tree->fclass('next')->namedlink($args{next_page}, 'Next') : $tree->fclass('next')->detach;
 249         $args{previous_page} ? $tree->fclass('previous')->namedlink($args{previous_page}, 'Previous') : $tree->fclass('previous')->detach;
 250         for my $cls (qw/next previous/) {
 251                 my $elem = $tree->fclass($cls);
 252                 next unless $elem;
 253                 delete $args{args}{page};
 254                 my $str = join '&', map { $_ . '=' . $args{args}{$_} } keys %{$args{args}};
 255                 $elem->find('a')->edit_href(sub{s/$/&$str/}) if $str;
 256         }
 257         $tree->fclass('current')->replace_content("Page $args{current_page} of $args{last_page}");
 258 }
 259
 260 sub process_st {
 261         my ($tree, %args) = @_;
 262         $args{problems} //= [];
 263         my $pbiter = sub {
 264                 my ($data, $th) = @_;
 265                 $th->attr(class => undef);
 266                 $th->namedlink(@$data);
 267                 $th->find('a')->edit_href(sub{s/$/?contest=$args{args}{contest}/});
 268         };
 269         $tree->fclass('problem')->iter3($args{problems}, $pbiter);
 270         my $iter = sub {
 271                 my ($st, $tr) = @_;
 272                 $tr->set_child_content(class => 'rank', $st->{rank});
 273                 $tr->set_child_content(class => 'score', $st->{score});
 274                 $tr->fclass('user')->namedlink($st->{user}, $st->{user_name});
 275                 my $pbscore = $tr->fclass('pbscore');
 276                 $pbscore->iter($pbscore => @{$st->{scores}});
 277         };
 278         $tree->find('tbody')->find('tr')->iter3($args{st}, $iter);
 279 }
 280
 281 sub process_ed {
 282         my ($tree, %args) = @_;
 283         $tree->content_handler(editorial => literal $args{editorial});
 284         my $iter = sub {
 285                 my ($data, $div) = @_;
 286                 $div->set_child_content(class => 'value', $data->{value});
 287                 $div->set_child_content(class => 'solution', literal $data->{solution});
 288                 $div->fclass('problem')->namedlink($data->{id}, $data->{name});
 289         };
 290         my @pb = map { @{$args{$_}} } qw/beginner easy medium hard/;
 291         $tree->fclass('well')->iter3(\@pb, $iter);
 292 }