[app-edwardng.git] / lib / App / EdwardNG.pm

package App::EdwardNG;

use 5.014000;
use strict;
use warnings;
use parent qw/Exporter/;
our $VERSION = '0.001';
our @EXPORT = qw/process_message/;

use Email::Sender::Simple qw/sendmail/;
use File::Slurp qw/read_file/;
use Getopt::Long;
use MIME::Entity;
use MIME::Parser;
use Mail::GnuPG;
use PerlX::Maybe;
use Template;
use Try::Tiny;

sub debug { say STDERR @_ if $ENV{EDWARDNG_DEBUG} }
sub stringify ($) { join '', map {; '>', $_ } @{$_[0]} }
sub mg {
	Mail::GnuPG->new(
		key                => $ENV{EDWARDNG_KEY},
		maybe always_trust => $ENV{EDWARDNG_ALWAYS_TRUST},
		maybe keydir       => $ENV{EDWARDNG_KEYDIR},
		maybe passphrase   => $ENV{EDWARDNG_PASSPHRASE},
		maybe use_agent    => $ENV{EDWARDNG_USE_AGENT},
		@_);
}

sub first_part{
	my ($ent) = @_;
	return first_part $ent->parts(0) if $ent->parts;
	$ent->bodyhandle->as_string
}

sub process_message {
	my ($msg) = @_;
	my $parser = MIME::Parser->new;
	$parser->decode_bodies(0);
	$parser->output_to_core(1);

	if (ref $msg eq 'MIME::Entity') {
		debug 'Got MIME::Entity';
	} elsif (ref $msg eq 'IO') {
		debug 'Parsing from filehandle';
		$msg = $parser->parse($msg)
	} elsif (ref $msg eq 'SCALAR') {
		debug 'Parsing from string';
		$msg = $parser->parse_data($$msg)
	} elsif (!ref $msg) {
		debug "Parsing from file $msg";
		$msg = $parser->parse_open($msg)
	} else {
		die "Don't know how to parse $msg"
	}

	if ($msg->mime_type ne 'multipart/signed' && $msg->mime_type ne 'multipart/encrypted') {
		# PGP/Inline requires decoding
		$parser->decode_bodies(1);
		$msg = $parser->parse_data($msg->stringify)
	}

	my $gpg = mg;
	if ($gpg->is_signed($msg)) {
		debug 'This mail looks signed';
		my ($code, $keyid, $email) = $gpg->verify($msg);
		return sign_error => (
			message => stringify $gpg->{last_message}) if $code;
		return sign => (
			keyid   => $keyid,
			email   => $email,
			message => stringify $gpg->{last_message});
	}

	if ($gpg->is_encrypted($msg)) {
		debug 'This mail looks encrypted';
		my ($code, $keyid, $email) = $gpg->decrypt($msg);
		return encrypt_error => (
			message   => stringify $gpg->{last_message}) if $code;
		return encrypt => (
			plaintext => stringify $gpg->{plaintext},
			decrypted => $gpg->{decrypted},
			message   => stringify $gpg->{last_message}) unless defined $keyid;
		return signencrypt => (
			keyid     => $keyid,
			email     => $email,
			plaintext => stringify $gpg->{plaintext},
			decrypted => $gpg->{decrypted},
			message   => stringify $gpg->{last_message});
	}

	debug 'This mail doesn\'t seem to be signed or encrypted';
	return 'plain'
}

sub run {
	GetOptions(
		'always-trust!' => \$ENV{EDWARDNG_ALWAYS_TRUST},
		'debug!'        => \$ENV{EDWARDNG_DEBUG},
		'from=s'        => \$ENV{EDWARDNG_FROM},
		'key=s'         => \$ENV{EDWARDNG_KEY},
		'keydir=s'      => \$ENV{EDWARDNG_KEYDIR},
		'passphrase=s'  => \$ENV{EDWARDNG_PASSPHRASE},
		'use-agent!'    => \$ENV{EDWARDNG_USE_AGENT},
	);

	my $parser = MIME::Parser->new;
	$parser->decode_bodies(0);
	$parser->output_to_core(1);
	my $in = $parser->parse(\*STDIN);

	my ($tmpl, %params);
	try {
		($tmpl, %params) = process_message $in
	} catch {
		($tmpl, %params) = (error => message => $_)
	};

	$params{plaintext} = first_part $params{decrypted} if $params{decrypted};

	my $tt = Template->new(INCLUDE_PATH => 'tmpl/en');
	my $data;
	$tt->process($tmpl, \%params, \$data);
	my $email = MIME::Entity->build(
		From    => $ENV{EDWARDNG_FROM},
		To      => $in->get('From'),
		Subject => 'Re: ' . $in->get('Subject'),
		Data    => $data);

	my $email_unencrypted = $email->dup;
	my $mg = mg always_trust => 1;
	my $encrypt_failed = $mg->mime_signencrypt($email, $in->get('From') =~ /<(.*)>/);
	debug 'Could not encrypt message, sending unencrypted. GnuPG said ', stringify $mg->{last_message} if $encrypt_failed;
	sendmail $encrypt_failed ? $email_unencrypted : $email
}

1;
__END__

=encoding utf-8

=head1 NAME

App::EdwardNG - GnuPG email sign/encrypt testing bot

=head1 SYNOPSIS

  use App::EdwardNG;
  my ($status, %params) = process_message '/path/to/message';
  if ($status eq 'signencrypt') {
    say 'This message is encrypted and signed with key ', $params{keyid}, ' from ', $params{email};
    say 'Its contents are: ', $params{plaintext};
  } elsif ($status eq 'encrypt') {
    say 'This message is encrypted but not signed';
    say 'Its contents are: ', $params{plaintext};
  } elsif ($status eq 'encrypt_error') {
    say 'This message is encrypted but I was unable to decrypt it. GnuPG output: ', $params{message};
  } elsif ($status eq 'sign') {
    say 'This message is signed with key ', $params{keyid}, ' from ', $params{email};
  } elsif ($status eq 'sign_error') {
    say 'This message is signed but I was unable to verify the signature. GnuPG output: ', $params{message};
  } elsif ($status eq 'plain') {
    say 'This message is neither signed nor encrypted';
  } elsif ($status eq 'error') {
    say 'There was an error processing the message: ', $params{message};
  }

=head1 DESCRIPTION

EdwardNG is a reimplementation of the Edward reply bot referenced in L<https://emailselfdefense.fsf.org/>.

It takes mail messages, checks them for PGP signatures and encryption, then replies appropriately.

This module exports a single function, B<process_message>, which takes a single parameter representing the message. This parameter can be:

=over

=item A filehandle reference, e.g. C<\*STDIN>.

=item A reference to a scalar which holds the message contents.

=item A scalar which represents a path to a message.

=item A L<MIME::Entity> object

=back

The function returns a status followed by a hash. Possible results:

=over

=item plain

The message is neither signed nor encrypted.

=item sign_error, message => $message

The message is signed but the signature could not be verified. GnuPG output is $message.

=item sign, keyid => $keyid, email => $email, message => $message

The message is signed with key $keyid from $email. GnuPG output is $message.

=item encrypt_error, message => $message

The message is encrypted and unable to be decrypted. GnuPG output is $message.

=item encrypt, plaintext => $plaintext, decrypted => $decrypted, message => $message

The message is encrypted and unsigned. $plaintext is the decrypted message as plain text, while $decrypted is a MIME::Entity representing the decrypted message. GnuPG output is $message.

=item signencrypt, plaintext => $plaintext, decrypted => $decrypted, keyid => $keyid, email => $email, message => $message

The message is encrypted and signed with key $keyid from $email. $plaintext is the decrypted message as plain text, while $decrypted is a MIME::Entity representing the decrypted message. GnuPG output is $message.

=item error, message => $message

There was an error while processing the message. The error can be found in $message.

=back

=head1 ENVIRONMENT

This module is configured via the %ENV hash. See the L<edwardng(1)> manpage for more information.

=head1 SEE ALSO

L<edwardng(1)>

=head1 AUTHOR

Marius Gavrilescu, E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Fundația Ceata

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.18.2 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
2f9e679a MG	1	package App::EdwardNG;
	2
	3	use 5.014000;
	4	use strict;
	5	use warnings;
	6	use parent qw/Exporter/;
	7	our $VERSION = '0.001';
	8	our @EXPORT = qw/process_message/;
	9
	10	use Email::Sender::Simple qw/sendmail/;
	11	use File::Slurp qw/read_file/;
	12	use Getopt::Long;
	13	use MIME::Entity;
	14	use MIME::Parser;
	15	use Mail::GnuPG;
	16	use PerlX::Maybe;
	17	use Template;
	18	use Try::Tiny;
	19
	20	sub debug { say STDERR @_ if $ENV{EDWARDNG_DEBUG} }
	21	sub stringify ($) { join '', map {; '>', $_ } @{$_[0]} }
	22	sub mg {
	23	Mail::GnuPG->new(
	24	key => $ENV{EDWARDNG_KEY},
	25	maybe always_trust => $ENV{EDWARDNG_ALWAYS_TRUST},
	26	maybe keydir => $ENV{EDWARDNG_KEYDIR},
	27	maybe passphrase => $ENV{EDWARDNG_PASSPHRASE},
	28	maybe use_agent => $ENV{EDWARDNG_USE_AGENT},
	29	@_);
	30	}
	31
	32	sub first_part{
	33	my ($ent) = @_;
	34	return first_part $ent->parts(0) if $ent->parts;
	35	$ent->bodyhandle->as_string
	36	}
	37
	38	sub process_message {
	39	my ($msg) = @_;
	40	my $parser = MIME::Parser->new;
	41	$parser->decode_bodies(0);
	42	$parser->output_to_core(1);
	43
	44	if (ref $msg eq 'MIME::Entity') {
	45	debug 'Got MIME::Entity';
	46	} elsif (ref $msg eq 'IO') {
	47	debug 'Parsing from filehandle';
	48	$msg = $parser->parse($msg)
	49	} elsif (ref $msg eq 'SCALAR') {
	50	debug 'Parsing from string';
	51	$msg = $parser->parse_data($$msg)
	52	} elsif (!ref $msg) {
	53	debug "Parsing from file $msg";
	54	$msg = $parser->parse_open($msg)
	55	} else {
	56	die "Don't know how to parse $msg"
	57	}
	58
	59	if ($msg->mime_type ne 'multipart/signed' && $msg->mime_type ne 'multipart/encrypted') {
	60	# PGP/Inline requires decoding
	61	$parser->decode_bodies(1);
	62	$msg = $parser->parse_data($msg->stringify)
	63	}
	64
65	my $gpg = mg;
66	if ($gpg->is_signed($msg)) {
67	debug 'This mail looks signed';
68	my ($code, $keyid, $email) = $gpg->verify($msg);
69	return sign_error => (
70	message => stringify $gpg->{last_message}) if $code;
71	return sign => (
72	keyid => $keyid,
73	email => $email,
74	message => stringify $gpg->{last_message});
75	}
76
77	if ($gpg->is_encrypted($msg)) {
78	debug 'This mail looks encrypted';
79	my ($code, $keyid, $email) = $gpg->decrypt($msg);
80	return encrypt_error => (
81	message => stringify $gpg->{last_message}) if $code;
82	return encrypt => (
83	plaintext => stringify $gpg->{plaintext},
84	decrypted => $gpg->{decrypted},
85	message => stringify $gpg->{last_message}) unless defined $keyid;
86	return signencrypt => (
87	keyid => $keyid,
88	email => $email,
89	plaintext => stringify $gpg->{plaintext},
90	decrypted => $gpg->{decrypted},
91	message => stringify $gpg->{last_message});
92	}
93
94	debug 'This mail doesn\'t seem to be signed or encrypted';
95	return 'plain'
96	}
97
98	sub run {
99	GetOptions(
100	'always-trust!' => \$ENV{EDWARDNG_ALWAYS_TRUST},
101	'debug!' => \$ENV{EDWARDNG_DEBUG},
102	'from=s' => \$ENV{EDWARDNG_FROM},
103	'key=s' => \$ENV{EDWARDNG_KEY},
104	'keydir=s' => \$ENV{EDWARDNG_KEYDIR},
105	'passphrase=s' => \$ENV{EDWARDNG_PASSPHRASE},
106	'use-agent!' => \$ENV{EDWARDNG_USE_AGENT},
107	);
108
109	my $parser = MIME::Parser->new;
110	$parser->decode_bodies(0);
111	$parser->output_to_core(1);
112	my $in = $parser->parse(\*STDIN);
113
114	my ($tmpl, %params);
115	try {
116	($tmpl, %params) = process_message $in
117	} catch {
118	($tmpl, %params) = (error => message => $_)
119	};
120
121	$params{plaintext} = first_part $params{decrypted} if $params{decrypted};
122
123	my $tt = Template->new(INCLUDE_PATH => 'tmpl/en');
c3455a5b	124	my $data;
2f9e679a	125	$tt->process($tmpl, \%params, \$data);
2f9e679a MG	126	my $email = MIME::Entity->build(
	127	From => $ENV{EDWARDNG_FROM},
	128	To => $in->get('From'),
c3455a5b	129	Subject => 'Re: ' . $in->get('Subject'),
2f9e679a MG	130	Data => $data);
2f9e679a MG	131
70f9c37d	132	my $email_unencrypted = $email->dup;
2f9e679a	133	my $mg = mg always_trust => 1;
70f9c37d MG	134	my $encrypt_failed = $mg->mime_signencrypt($email, $in->get('From') =~ /<(.*)>/);
	135	debug 'Could not encrypt message, sending unencrypted. GnuPG said ', stringify $mg->{last_message} if $encrypt_failed;
	136	sendmail $encrypt_failed ? $email_unencrypted : $email
2f9e679a MG	137	}
	138
	139	1;
	140	__END__
	141
	142	=encoding utf-8
	143
	144	=head1 NAME
	145
	146	App::EdwardNG - GnuPG email sign/encrypt testing bot
	147
	148	=head1 SYNOPSIS
	149
	150	use App::EdwardNG;
	151	my ($status, %params) = process_message '/path/to/message';
	152	if ($status eq 'signencrypt') {
	153	say 'This message is encrypted and signed with key ', $params{keyid}, ' from ', $params{email};
	154	say 'Its contents are: ', $params{plaintext};
	155	} elsif ($status eq 'encrypt') {
	156	say 'This message is encrypted but not signed';
	157	say 'Its contents are: ', $params{plaintext};
	158	} elsif ($status eq 'encrypt_error') {
	159	say 'This message is encrypted but I was unable to decrypt it. GnuPG output: ', $params{message};
	160	} elsif ($status eq 'sign') {
	161	say 'This message is signed with key ', $params{keyid}, ' from ', $params{email};
	162	} elsif ($status eq 'sign_error') {
	163	say 'This message is signed but I was unable to verify the signature. GnuPG output: ', $params{message};
	164	} elsif ($status eq 'plain') {
	165	say 'This message is neither signed nor encrypted';
	166	} elsif ($status eq 'error') {
	167	say 'There was an error processing the message: ', $params{message};
	168	}
	169
	170	=head1 DESCRIPTION
	171
	172	EdwardNG is a reimplementation of the Edward reply bot referenced in L<https://emailselfdefense.fsf.org/>.
	173
	174	It takes mail messages, checks them for PGP signatures and encryption, then replies appropriately.
	175
	176	This module exports a single function, B<process_message>, which takes a single parameter representing the message. This parameter can be:
	177
	178	=over
	179
	180	=item A filehandle reference, e.g. C<\*STDIN>.
	181
	182	=item A reference to a scalar which holds the message contents.
	183
	184	=item A scalar which represents a path to a message.
	185
	186	=item A L<MIME::Entity> object
	187
	188	=back
	189
	190	The function returns a status followed by a hash. Possible results:
	191
	192	=over
	193
	194	=item plain
	195
	196	The message is neither signed nor encrypted.
	197
	198	=item sign_error, message => $message
	199
	200	The message is signed but the signature could not be verified. GnuPG output is $message.
201
202	=item sign, keyid => $keyid, email => $email, message => $message
203
204	The message is signed with key $keyid from $email. GnuPG output is $message.
205
206	=item encrypt_error, message => $message
207
208	The message is encrypted and unable to be decrypted. GnuPG output is $message.
209
210	=item encrypt, plaintext => $plaintext, decrypted => $decrypted, message => $message
211
212	The message is encrypted and unsigned. $plaintext is the decrypted message as plain text, while $decrypted is a MIME::Entity representing the decrypted message. GnuPG output is $message.
213
214	=item signencrypt, plaintext => $plaintext, decrypted => $decrypted, keyid => $keyid, email => $email, message => $message
215
216	The message is encrypted and signed with key $keyid from $email. $plaintext is the decrypted message as plain text, while $decrypted is a MIME::Entity representing the decrypted message. GnuPG output is $message.
217
218	=item error, message => $message
219
220	There was an error while processing the message. The error can be found in $message.
221
222	=back
223
224	=head1 ENVIRONMENT
225
226	This module is configured via the %ENV hash. See the L<edwardng(1)> manpage for more information.
227
228	=head1 SEE ALSO
229
230	L<edwardng(1)>
231
232	=head1 AUTHOR
233
234	Marius Gavrilescu, E<lt>marius@ieval.roE<gt>
235
236	=head1 COPYRIGHT AND LICENSE
237
1f08c352	238	Copyright (C) 2014 by Fundația Ceata
2f9e679a MG	239
	240	This library is free software; you can redistribute it and/or modify
	241	it under the same terms as Perl itself, either Perl version 5.18.2 or,
	242	at your option, any later version of Perl 5 you may have available.
	243
	244
	245	=cut