Replace MP3::Tag with MP3::Info

[app-musicexpo.git] / lib / App / MusicExpo.pm

package App::MusicExpo;
use v5.14;
use strict;
use warnings;

our $VERSION = '0.005';

use Audio::FLAC::Header qw//;
use HTML::Template::Compiled qw//;
use Memoize qw/memoize/;
use MP3::Info qw/get_mp3tag/;
use Ogg::Vorbis::Header::PurePerl;
use MP4::Info qw/get_mp4tag get_mp4info/;

use DB_File qw//;
use Encode qw/encode/;
use File::Basename qw/fileparse/;
use Fcntl qw/O_RDWR O_CREAT/;
use Getopt::Long;
use Storable qw/thaw freeze/;

##################################################

my $default_template;

our $prefix='/music/';
our $cache='';
our $template='';

GetOptions (
	"template:s" => \$template,
	"prefix:s" => \$prefix,
	"cache:s" => \$cache,
);

sub flacinfo{
	my $file=$_[0];
	my $flac=Audio::FLAC::Header->new($file);

	freeze +{
		format => 'FLAC',
		title => $flac->tags('TITLE') // '?',
		artist => $flac->tags('ARTIST') // '?',
		year => $flac->tags('DATE') // '?',
		album => $flac->tags('ALBUM') // '?',
		tracknumber => $flac->tags('TRACKNUMBER') // '?',
		tracktotal => $flac->tags('TRACKTOTAL') // '?',
		genre => $flac->tags('GENRE') // '?',
		file => scalar fileparse $file,
	}
}

sub mp3info{
	my $file=$_[0];
	my %tag = map { encode 'UTF-8', $_ } %{get_mp3tag $file};
	my @trkn = split '/', $tag{TRACKNUM} // '';

	freeze +{
		format => 'MP3',
		title => $tag{TITLE} || '?',
		artist => $tag{ARTIST} || '?',
		year => $tag{YEAR} || '?',
		album => $tag{ALBUM} || '?',
		tracknumber => $trkn[0] || '?',
		tracktotal => $trkn[1] || '?',
		genre => $tag{GENRE} || '?',
		file => scalar fileparse $file,
	}
}

sub vorbisinfo{
	my $file=$_[0];
	my $ogg=Ogg::Vorbis::Header::PurePerl->new($file);

	freeze +{
		format => 'Vorbis',
		title => $ogg->comment('TITLE') || '?',
		artist => $ogg->comment('artist') || '?',
		year => $ogg->comment('DATE') || '?',
		album => $ogg->comment('ALBUM') || '?',
		tracknumber => $ogg->comment('TRACKNUMBER') || '?',
		tracktotal => $ogg->comment('TRACKTOTAL') || '?',
		genre => $ogg->comment('GENRE') || '?',
		file => scalar fileparse $file,
	}
}

sub mp4_format ($){
	my $encoding = $_[0];
	return 'AAC' if $encoding eq 'mp4a';
	return 'ALAC' if $encoding eq 'alac';
	"MP4-$encoding"
}

sub mp4info{
	my $file=$_[0];
	my %tag = map { ref() ? $_ : encode 'UTF-8', $_ } %{get_mp4tag $file};
	my %info = %{get_mp4info $file};

	freeze +{
		format => mp4_format $info{ENCODING},
		title => $tag{TITLE} || '?',
		artist => $tag{ARTIST} || '?',
		year => $tag{YEAR} || '?',
		album => $tag{ALBUM} || '?',
		tracknumber => $tag{TRACKNUM} || '?',
		tracktotal => ($tag{TRKN} ? $tag{TRKN}->[1] : undef) || '?',
		genre => $tag{GENRE} || '?',
		file => scalar fileparse $file,
	};
}

my %info = (
	'.flac' => \&flacinfo,
	'.mp3' => \&mp3info,
	'.ogg' => \&vorbisinfo,
	'.oga' => \&vorbisinfo,
	'.mp4' => \&mp4info,
	'.aac' => \&mp4info,
	'.m4a' => \&mp4info,
);

sub normalizer{
	"$_[0]|".(stat $_[0])[9]
}

sub make_fragment{ join '-', map { lc =~ y/a-z0-9/_/csr } @_ }

sub run {
	my %info = %info;
	if ($cache) {
		tie my %cache, 'DB_File', $cache, O_RDWR|O_CREAT, 0644;
		$info{$_} = memoize $info{$_}, INSTALL => undef, NORMALIZER => \&normalizer, LIST_CACHE => 'FAULT', SCALAR_CACHE => [HASH => \%cache] for keys %info;
	}

	my %files;
	for my $file (@ARGV) {
		my ($basename, undef, $suffix) = fileparse $file, keys %info;
		$files{$basename} //= [];
		push @{$files{$basename}}, thaw scalar $info{$suffix}->($file);
	}

	my $ht=HTML::Template::Compiled->new(
		default_escape => 'HTML',
		global_vars => 2,
		$template eq '' ? (scalarref => \$default_template) : (filename => $template),
	);

	my @files;
	for (values %files) {
		my @versions = @$_;
		my %entry = (%{$versions[0]}, formats => []);
		for my $ver (@versions) {
			push @{$entry{formats}}, {format => $ver->{format}, file => $ver->{file}};
			for my $key (keys %$ver) {
				$entry{$key} = $ver->{$key} if $ver->{$key} ne '?';
			}
		}
		delete $entry{$_} for qw/format file/;
		$entry{fragment} = make_fragment @entry{qw/artist title/};
		push @files, \%entry
	}

	@files = sort { $a->{title} cmp $b->{title} } @files;
	$ht->param(files => \@files, prefix => $prefix);
	print $ht->output;
}

$default_template = <<'HTML';
<!DOCTYPE html>
<title>Music</title>
<meta charset="utf-8">
<link rel="stylesheet" href="musicexpo.css">
<script async defer type="application/javascript" src="player.js"></script>

<div id="player"></div>

<table border>
<thead>
<tr><th>Title<th>Artist<th>Album<th>Genre<th>Track<th>Year<th>Type
<tbody><tmpl_loop files>
<tr><td class="title"><a href="#<tmpl_var fragment>" data-hash="#<tmpl_var fragment>"><tmpl_var title></a><td class="artist"><tmpl_var artist><td class="album"><tmpl_var album><td class="genre"><tmpl_var genre><td class="track"><tmpl_var tracknumber>/<tmpl_var tracktotal><td class="year"><tmpl_var year><td class="formats"><tmpl_loop formats><a href="<tmpl_var ...prefix><tmpl_var ESCAPE=URL file>"><tmpl_var format></a> </tmpl_loop></tmpl_loop>
</table>
HTML

1;

__END__

=encoding utf-8

=head1 NAME

App::MusicExpo - script which generates a HTML table of music tags

=head1 SYNOPSIS

  use App::MusicExpo;
  App::MusicExpo->run;

=head1 DESCRIPTION

App::MusicExpo creates a HTML table from a list of songs.

The default template looks like:

    | Title   | Artist  | Album           | Genre   | Track | Year | Type |
    |---------+---------+-----------------+---------+-------+------+------|
    | Cellule | Silence | L'autre endroit | Electro | 01/09 | 2005 | FLAC |

where the type is a download link. If you have multiple files with the same
basename (such as C<cellule.flac> and C<cellule.ogg>), they will be treated
as two versions of the same file, so a row will be created with two download
links, one for each format.

=head1 OPTIONS

=over

=item B<--template> I<template>

Path to the HTML::Template::Compiled template used for generating the music table. If '' (empty), uses the default format. Is empty by default.

=item B<--prefix> I<prefix>

Prefix for download links. Defaults to '/music/'.

=item B<--cache> I<filename>

Path to the cache file. Created if it does not exist. If '' (empty), disables caching. Is empty by default.

=back

=head1 AUTHOR

Marius Gavrilescu, E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2013-2015 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.14.2 or,
at your option, any later version of Perl 5 you may have available.