lib/App/Scheme79asm.pm

   1 package App::Scheme79asm;
   2
   3 use 5.014000;
   4 use strict;
   5 use warnings;
   6
   7 use Data::Dumper qw/Dumper/;
   8 use Data::SExpression qw/consp scalarp/;
   9 use Scalar::Util qw/looks_like_number/;
  10
  11 our $VERSION = '0.002';
  12
  13 our %TYPES = (
  14         LIST => 0,
  15         SYMBOL => 1,
  16         NUMBER => 1,
  17         VAR => 2,
  18         VARIABLE => 2,
  19         CLOSURE => 3,
  20         PROC => 4,
  21         PROCEDURE => 4,
  22         IF => 5,
  23         COND => 5,
  24         CONDITIONAL => 5,
  25         CALL => 6,
  26         QUOTE => 7,
  27         QUOTED => 7,
  28
  29         MORE => 0,
  30         CAR => 1,
  31         CDR => 2,
  32         CONS => 3,
  33         ATOM => 4,
  34         PROGN => 5,
  35         'REVERSE-LIST' => 6,
  36         FUNCALL => 7,
  37 );
  38
  39 *consp = *Data::SExpression::consp;
  40 *scalarp = *Data::SExpression::scalarp;
  41
  42 sub process {
  43         my ($self, $sexp, $location) = @_;
  44         die 'Toplevel is not a list: ', Dumper($sexp), "\n" unless ref $sexp eq 'ARRAY';
  45         my ($type, @addrs) = @$sexp;
  46         my $addr;
  47
  48         die 'Type of toplevel is not atom: '. Dumper($type), "\n" unless scalarp($type);
  49
  50         if (@addrs > 1) {
  51                 $addr = $self->{freeptr} + 1;
  52                 $self->{freeptr} += @addrs;
  53                 $self->process($addrs[$_], $addr + $_) for 0 .. $#addrs;
  54         } else {
  55                 $addr = $addrs[0];
  56         }
  57
  58         $addr = $self->process($addr) if ref $addr eq 'ARRAY';
  59         die 'Addr of toplevel is not atom: ', Dumper($addr), "\n" unless scalarp($addr);
  60
  61         my ($comment_type, $comment_addr) = ($type, $addr);
  62
  63         unless (looks_like_number $addr) { # is symbol
  64                 unless (exists $self->{symbols}{$addr}) {
  65                         $self->{symbols}{$addr} = $self->{nsymbols};
  66                         $self->{nsymbols}++;
  67                 }
  68                 $addr = $self->{symbols}{$addr}
  69         }
  70
  71         die 'Computed addr is not a number: ', Dumper($addr), "\n" unless looks_like_number $addr;
  72
  73         if (ref $type eq 'Data::SExpression::Symbol') {
  74                 die "No such type: $type\n" unless exists $TYPES{$type};
  75                 $type = $TYPES{$type};
  76         } elsif (!looks_like_number $type) {
  77                 die "Type is not a number or symbol: $type\n"
  78         }
  79
  80         $addr += (1 << $self->{addr_bits}) if $addr < 0;
  81         die "Type too large: $type\n" unless $type < (1 << $self->{type_bits});
  82         die "Addr too large: $addr\n" unless $addr < (1 << $self->{addr_bits});
  83         my $result = ($type << $self->{addr_bits}) + $addr;
  84         unless ($location) {
  85                 $self->{freeptr}++;
  86                 $location = $self->{freeptr}
  87         }
  88         $self->{memory}[$location] = $result;
  89         $self->{comment}[$location] = "$comment_type $comment_addr";
  90         $location
  91 }
  92
  93 sub parse {
  94         my ($self, $string) = @_;
  95         my $ds = Data::SExpression->new({symbol_case => 'up', use_symbol_class => 1, fold_lists => 1});
  96
  97         my $sexp;
  98         while () {
  99                 last if $string =~ /^\s*$/;
 100                 ($sexp, $string) = $ds->read($string);
 101                 $self->process($sexp)
 102         }
 103 }
 104
 105 sub finish {
 106         my ($self) = @_;
 107         $self->{memory}[5] = $self->{memory}[$self->{freeptr}];
 108         $self->{comment}[5] = $self->{comment}[$self->{freeptr}];
 109         $self->{memory}[4] = $self->{freeptr};
 110         delete $self->{memory}[$self->{freeptr}]
 111 }
 112
 113 sub new {
 114         my ($class, %args) = @_;
 115         $args{type_bits} //= 3;
 116         $args{addr_bits} //= 8;
 117         $args{freeptr} //= 6;
 118         $args{memory} //= [0, 0, (1<<$args{addr_bits}), (1<<$args{addr_bits}), 0, 0, 0];
 119         $args{symbols}{T} = 2;
 120         $args{nsymbols} = 3;
 121         $args{comment} = ['(cdr part of NIL)', '(car part of NIL)', '(cdr part of T)', '(car part of T)', '(free storage pointer)', '', '(result of computation)'];
 122         bless \%args, $class
 123 }
 124
 125 sub print_binary16 {
 126         my ($self, $fh) = @_;
 127         $fh //= \*STDOUT;
 128
 129         my $length = @{$self->{memory}};
 130         print $fh pack('n', $length);
 131         for (@{$self->{memory}}) {
 132                 print $fh pack('n', $_)
 133         }
 134 }
 135
 136 sub print_verilog {
 137         my ($self, $fh) = @_;
 138         $fh //= \*STDOUT;
 139
 140         my $bits = $self->{type_bits} + $self->{addr_bits};
 141         my $index_length = length $#{$self->{memory}};
 142         my $index_format = '%' . $index_length . 'd';
 143         for my $index (0 .. $#{$self->{memory}}) {
 144                 my $val = $self->{memory}[$index];
 145                 my $comment = $self->{comment}[$index];
 146                 if ($index == 4) {
 147                         $val = "${bits}'d$val"
 148                 } else {
 149                         $val = $val ? sprintf "%d'b%0${bits}b", $bits, $val : '0';
 150                 }
 151                 my $spaces = ' ' x ($bits + 5 - (length $val));
 152                 $index = sprintf $index_format, $index;
 153                 say $fh "mem[$index] <= $val;$spaces // $comment"
 154         }
 155
 156 }
 157 sub parse_and_print_binary16 {
 158         my ($self, $string, $fh) = @_;
 159         $self->parse($string);
 160         $self->finish;
 161         $self->print_binary16($fh);
 162 }
 163
 164 sub parse_and_print_verilog {
 165         my ($self, $string, $fh) = @_;
 166         $self->parse($string);
 167         $self->finish;
 168         $self->print_verilog($fh);
 169 }
 170
 171 1;
 172 __END__
 173
 174 =encoding utf-8
 175
 176 =head1 NAME
 177
 178 App::Scheme79asm - assemble sexp to Verilog ROM for SIMPLE processor
 179
 180 =head1 SYNOPSIS
 181
 182   use App::Scheme79asm;
 183   my $asm = App::Scheme79asm->new(type_bits => 3, addr_bits => 5);
 184   $asm->parse_and_print_verilog('(number 70)');
 185
 186 =head1 DESCRIPTION
 187
 188 SIMPLE is a LISP processor defined in the 1979
 189 B<Design of LISP-Based Processors> paper by Steele and Sussman.
 190
 191 The SIMPLE processor expects input in a particular tagged-pointer
 192 format. This module takes a string containing a sequence of
 193 S-expressions. Each S-expression is a list of one of three types:
 194
 195 C<(tag value)>, for example C<(symbol nil)>, represents a value to be
 196 put in memory (for example a number, or a symbol, or a variable
 197 reference).
 198
 199 C<(tag list)>, where C<list> is of one of these three types,
 200 represents a tagged pointer. In this case, C<list> is (recursively)
 201 laid out in memory as per these rules, and a pointer to that location
 202 (and tagged C<tag>) is put somewhere in memory.
 203
 204 C<(tag list1 list2)>, where C<list1> and C<list2> are of one of these
 205 three types (not necessarily the same type). In this case, C<list1>
 206 and C<list2> are (recursively) laid out in memory such that C<list1>
 207 is at position X and C<list2> is at position X+1, and a pointer of
 208 type tag and value X is put somewhere in memory.
 209
 210 After this process the very last pointer placed in memory is moved to
 211 the special location 5 (which is where SIMPLE expects to find the
 212 expression to be evaluated).
 213
 214 In normal use a single S-expression will be supplied, representing an
 215 entire program.
 216
 217 The C<tag> is either a number, a type, or a primitive.
 218 The available types are:
 219
 220 =over
 221
 222 =item LIST
 223
 224 =item SYMBOL (syn. NUMBER)
 225
 226 =item VAR (syn. VARIABLE)
 227
 228 =item CLOSURE
 229
 230 =item PROC (syn. PROCEDURE)
 231
 232 =item IF (syn. COND, CONDITIONAL)
 233
 234 =item CALL
 235
 236 =item QUOTE (syn. QUOTED)
 237
 238 =back
 239
 240 The available primitives are:
 241
 242 =over
 243
 244 =item MORE
 245
 246 =item CAR
 247
 248 =item CDR
 249
 250 =item CONS
 251
 252 =item ATOM
 253
 254 =item PROGN
 255
 256 =item REVERSE-LIST
 257
 258 =item FUNCALL
 259
 260 =back
 261
 262 The following methods are available:
 263
 264 =over
 265
 266 =item App::Scheme79asm->B<new>([key => value, key => value, ...])
 267
 268 Create a new assembler object. Takes a list of keys and values, here
 269 are the possible keys:
 270
 271 =over
 272
 273 =item type_bits
 274
 275 =item address_bits
 276
 277 A word is made of a type and an address, with the type occupying the
 278 most significant C<type_bits> (default 3) bits, and the address
 279 occupying the least significant C<address_bits> (default 8) bits.
 280 Therefore the word size is C<type_bits + address_bits> (default 13).
 281
 282 =item freeptr
 283
 284 A pointer to the last used byte in memory (default 6). The program
 285 will be laid out starting with location C<freeptr + 1>.
 286
 287 =item memory
 288
 289 The initial contents of the memory. Note that locations 4, 5, 6 will
 290 be overwritten, as will every location larger than the value of
 291 C<freeptr>.
 292
 293 =item comment
 294
 295 The initial comments for memory entries. C<< $comment->[$i] >> is the
 296 comment for C<< $memory->[$i] >>.
 297
 298 =item symbols
 299
 300 The initial symbol map, as a hashref from symbol name to the index of
 301 that symbol. Defaults to C<< {T => 2} >>.
 302
 303 =item nsymbols
 304
 305 The number to give to the "next" symbol (default 3, because T is
 306 defined to be 2).
 307
 308 =back
 309
 310 =item $asm->B<parse>(I<$string>)
 311
 312 Parse a sequence of S-expressions and lay it out in memory.
 313 Can be called multiple times to lay out multiple sequences of
 314 S-expressions one after another.
 315
 316 =item $asm->B<finish>
 317
 318 Move the last pointer to position 5, and put the free pointer at
 319 position 4. After all sequences of S-expressions have been given to
 320 B<parse>, this method should be called.
 321
 322 =item $asm->B<print_binary16>([I<$fh>])
 323
 324 Print the length of the memory (as a big-endian 16-bit value),
 325 followed by the memory contents as a sequence of big-endian 16-bit
 326 values to the given filehandle (default STDOUT). Dies if
 327 C<addr_bits + type_bits> is more than 16.
 328
 329 Big-endian 16-bit values can be decoded with C<unpack 'n', $value>.
 330
 331 =item $asm->B<print_verilog>([I<$fh>])
 332
 333 Print a block of Verilog code assigning the memory contents to an
 334 array named C<mem> to the given filehandle (default STDOUT).
 335
 336 =item $asm->B<parse_and_print_binary16>(I<$string>[, I<$fh>])
 337
 338 Convenience method that calls B<parse>($string), B<finish>, and then
 339 B<print_binary16>($fh).
 340
 341 =item $asm->B<parse_and_print_verilog>(I<$string>[, I<$fh>])
 342
 343 Convenience method that calls B<parse>($string), B<finish>, and then
 344 B<print_verilog>($fh).
 345
 346 =back
 347
 348 =head1 SEE ALSO
 349
 350 L<http://repository.readscheme.org/ftp/papers/ai-lab-pubs/AIM-514.pdf>
 351
 352 =head1 AUTHOR
 353
 354 Marius Gavrilescu, E<lt>marius@ieval.roE<gt>
 355
 356 =head1 COPYRIGHT AND LICENSE
 357
 358 Copyright (C) 2018 by Marius Gavrilescu
 359
 360 This library is free software; you can redistribute it and/or modify
 361 it under the same terms as Perl itself, either Perl version 5.24.3 or,
 362 at your option, any later version of Perl 5 you may have available.
 363
 364
 365 =cut