Use Data::Dump::Sexp instead of pretty_print
[app-scheme79asm.git] / t / Compiler.t
1 #!/usr/bin/perl
2 use strict;
3 use warnings;
4
5 use Data::Dump::Sexp;
6 use Test::More tests => 31;
7
8 BEGIN { use_ok('App::Scheme79asm::Compiler') };
9
10 sub is_sexp {
11 my ($expr, $expected, $name) = @_;
12 is dump_sexp($expr), $expected, $name;
13 }
14
15 sub to_sexp {
16 my ($string) = @_;
17 scalar Data::SExpression->new({fold_lists => 0, use_symbol_class => 1})->read($string)
18 }
19
20 sub new {
21 App::Scheme79asm::Compiler->new;
22 }
23
24 sub is_toplevel {
25 my ($string, $expected) = @_;
26 is_sexp new->process_toplevel(to_sexp $string), $expected, "process_toplevel $string";
27 is_sexp new->compile_string($string), $expected, "compile_string $string";
28 }
29
30 is_sexp new->process_quoted(to_sexp '5'), '(SYMBOL 3)', 'process_quoted 5';
31 is_sexp new->process_quoted(to_sexp '()'), '(LIST 0)', 'process_quoted ()';
32 is_sexp new->process_quoted(to_sexp '(5 foo)'), '(LIST (LIST (LIST 0) (SYMBOL 3)) (SYMBOL 4))', 'process_quoted (5 foo)';
33 is_sexp new->process_quoted(to_sexp '(((5)))'), '(LIST (LIST 0) (LIST (LIST 0) (LIST (LIST 0) (SYMBOL 3))))', 'process_quoted (((5)))';
34
35 is_toplevel '()', '(LIST 0)';
36 is_toplevel 'NIL', '(LIST 0)';
37 is_toplevel 'T', '(SYMBOL 2)';
38 is_toplevel '(quote 5)', '(SYMBOL 3)';
39 is_toplevel '(reverse-list \'a \'a \'b)', '(CALL (MORE (MORE (REVERSE-LIST 0) (SYMBOL 4)) (SYMBOL 3)) (SYMBOL 3))';
40 is_toplevel '(if t \'(2 3) \'x)', '(IF (LIST (SYMBOL 5) (LIST (LIST (LIST 0) (SYMBOL 3)) (SYMBOL 4))) (SYMBOL 2))';
41 is_toplevel '(car \'(1 2))', '(CALL (CAR 0) (LIST (LIST (LIST 0) (SYMBOL 3)) (SYMBOL 4)))';
42 is_toplevel '(lambda id (x) x)', '(PROC (VAR -2))';
43 is_toplevel '((lambda id (x) x) 5)', '(CALL (MORE (FUNCALL 0) (PROC (VAR -2))) (SYMBOL 3))';
44 is_toplevel '(lambda append (x y) (if (atom x) y (cons (car x) (append (cdr x) y))))', '(PROC (IF (LIST (CALL (MORE (CONS 0) (CALL (MORE (MORE (FUNCALL 0) (VAR -1)) (VAR -2)) (CALL (CDR 0) (VAR -3)))) (CALL (CAR 0) (VAR -3))) (VAR -2)) (CALL (ATOM 0) (VAR -3))))';
45
46 sub pp_roundtrip {
47 my ($string) = @_;
48 my $pp = uc dump_sexp(to_sexp $string);
49 is $pp, uc($string), "dump_sexp roundtrip $string";
50 }
51
52 pp_roundtrip '()';
53 pp_roundtrip 't';
54 pp_roundtrip '(lambda append (x y) (if (atom x) y (cons (car x) (append (cdr x) y))))';
55
56 sub expect_error_like (&$) {
57 my ($block, $error_re) = @_;
58 my $name = "test error like /$error_re/";
59 my $result = eval { $block->(); 1 };
60 if ($result) {
61 note 'Block did not throw an exception, failing test';
62 fail $name;
63 } else {
64 like $@, qr/$error_re/, $name;
65 }
66 }
67
68 expect_error_like { new->process_quoted([]) } 'argument to process_quoted is not a scalar, cons, or nil';
69 expect_error_like { is_toplevel 'x' } 'Variable x not in environment';
70 expect_error_like { is_toplevel '(car)' } 'Cannot call primitive car with no arguments';
This page took 0.029052 seconds and 4 git commands to generate.