t/01-jobs.t

   1 #!/usr/bin/perl -w
   2 use v5.14;
   3 use strict;
   4 use warnings;
   5
   6 use t::FakeData;
   7 BEGIN { Gruntmaster::Data->import }
   8 use Gruntmaster::Daemon;
   9
  10 use Cwd qw/cwd/;
  11 use File::Basename qw/fileparse/;
  12 use File::Slurp qw/read_file/;
  13 use File::Temp qw/tempdir/;
  14 use Hash::Merge qw/merge/;
  15 use List::Util qw/sum/;
  16 use Log::Log4perl;
  17 use Test::More;
  18 use YAML::Any qw/LoadFile/;
  19
  20 ##################################################
  21
  22 my $loglevel = $ENV{TEST_LOG_LEVEL} // 'OFF';
  23 my $log_conf = <<CONF;
  24 log4perl.category.Gruntmaster.Daemon = $loglevel, stderr
  25
  26 log4perl.appender.stderr                          = Log::Log4perl::Appender::Screen
  27 log4perl.appender.stderr.layout                   = Log::Log4perl::Layout::PatternLayout
  28 log4perl.appender.stderr.layout.ConversionPattern = [\%d] [\%F{1}:\%M{1}:\%L] [\%p] \%m\%n
  29 CONF
  30 Log::Log4perl->init(\$log_conf);
  31
  32 $ENV{PATH}.=':' . cwd;
  33
  34 sub check_job{
  35         my $meta = shift;
  36         if (defined $meta->{results}) {
  37                 delete $meta->{results}[$_]{time} for keys $meta->{results};
  38         }
  39         is $meta->{result}, $meta->{expected_result}, "Result is correct";
  40         is $meta->{result_text}, $meta->{expected_result_text}, "Result text is correct";
  41         is_deeply $meta->{results}, $meta->{expected_results}, "Results are correct";
  42 }
  43
  44 my @problems = exists $ENV{TEST_PROBLEMS} ? map {"t/problems/$_"} split ' ', $ENV{TEST_PROBLEMS} : <t/problems/*>;
  45 plan tests => 3 * sum map { my @temp = <$_/tests/*>; scalar @temp } @problems;
  46 note "Problems to be tested: " . join ', ', @problems;
  47
  48 my $tempdir = tempdir CLEANUP => 1;
  49
  50 my $job = 0;
  51
  52 for my $problem (@problems) {
  53         my $pbmeta = LoadFile "$problem/meta.yml";
  54         for (1 .. $pbmeta->{testcnt}) {
  55                 $pbmeta->{infile}[$_ - 1] = read_file "$problem/$_.in" if $pbmeta->{generator} eq 'File';
  56                 $pbmeta->{okfile}[$_ - 1] = read_file "$problem/$_.ok" if $pbmeta->{runner} eq 'File';
  57         }
  58         if (exists $pbmeta->{files}) {
  59                 $_->{content} = read_file "$problem/$_->{name}" for values $pbmeta->{files}
  60         }
  61
  62   TODO: {
  63                 local $TODO = $pbmeta->{todo} if exists $pbmeta->{todo};
  64                 note "Now testing problem $pbmeta->{name} ($pbmeta->{description})";
  65
  66                 for my $source (<$problem/tests/*>) {
  67                         my $meta = LoadFile "$source/meta.yml";
  68                         $meta->{files}{prog}{content} = read_file "$source/$meta->{files}{prog}{name}";
  69                         $meta = merge $meta, $pbmeta;
  70                         note "Running $meta->{test_name} ($meta->{test_description})...";
  71                         my $savedcwd = cwd;
  72                         chdir $tempdir;
  73                         Gruntmaster::Daemon::process $meta;
  74                         chdir $savedcwd;
  75                         check_job $meta;
  76                 }
  77         }
  78 }