[gruntmaster-data.git] / lib / Gruntmaster / Data.pm

use utf8;
package Gruntmaster::Data;

# Created by DBIx::Class::Schema::Loader
# DO NOT MODIFY THE FIRST PART OF THIS FILE

use strict;
use warnings;

use base 'DBIx::Class::Schema';

__PACKAGE__->load_namespaces;


# Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg

use parent qw/Exporter/;
our $VERSION = '5999.000_013';
our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)

use Lingua::EN::Inflect qw/PL_N/;
use JSON::MaybeXS qw/decode_json/;
use HTTP::Tiny;
use PerlX::Maybe qw/maybe/;
use Sub::Name qw/subname/;

use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private statement timeout olimit value/];
use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
use constant JOBS_PER_PAGE => 10;

sub dynsub{
	our ($name, $sub) = @_;
	no strict 'refs'; ## no critic (Strict)
	*$name = subname $name => $sub
}

BEGIN {
	for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
		my $rsname = ucfirst $rs;
		$rsname =~ s/_([a-z])/\u$1/gs;
		dynsub PL_N($rs) => sub { $_[0]->resultset($rsname)              };
		dynsub      $rs  => sub { $_[0]->resultset($rsname)->find($_[1]) };
	}
}

sub user_list {
	my ($self) = @_;
	my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
	my (%solved, %attempted, %contests);

	for my $row ($self->problem_statuses->all) {
		$solved   {$row->rawowner}++ if     $row->solved;
		$attempted{$row->rawowner}++ unless $row->solved;
	}
	$contests{$_->rawowner}++ for $self->contest_statuses->all;

	[ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } map { ## no critic (ProhibitReverseSort)
		my $id = $_->id;
		+{ $_->get_columns,
		   solved => ($solved{$id} // 0),
		   attempted => ($attempted{$id} // 0),
		   contests => ($contests{$id} // 0) }
	} $rs->all ]
}

sub user_entry {
	my ($self, $id) = @_;
	my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
	my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
	my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
	+{ $user->get_columns, problems => \@problems, contests => \@contests }
}

sub problem_list {
	my ($self, %args) = @_;
	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
	$rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest} || $args{private};
	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	my %params;
	$params{contest} = $args{contest} if $args{contest};
	for ($rs->all) {
		$params{$_->level} //= [];
		push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
	}
	\%params
}

sub problem_entry {
	my ($self, $id, $contest, $user) = @_;
	my $running = $contest && $self->contest($contest)->is_running;
	my $columns = PROBLEM_PUBLIC_COLUMNS;
	push @$columns, 'solution' unless $running;
	my $pb = $self->problems->find($id, {columns => $columns, prefetch => 'owner'});
	my $open;
	$open = $self->opens->find_or_create({
		contest => $contest,
		problem => $id,
		owner => $user,
		time => time,
	}) if $running;
	$contest &&= $self->contest($contest);
	+{
		$pb->get_columns,
		owner_name => $pb->owner->name,
		cansubmit => !$contest || !$contest->is_finished,
		$running ? (
			contest_start => $contest->start,
			contest_stop => $contest->stop,
			open_time => $open->time
		) : (),
	}
}

sub contest_list {
	my ($self, %args) = @_;
	my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
	my %params;
	for ($rs->all) {
		my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
		$params{$state} //= [];
		push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
	}
	\%params
}

sub contest_entry {
	my ($self, $id) = @_;
	my $ct = $self->contest($id);
	+{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
}

sub job_list {
	my ($self, %args) = @_;
	$args{page} //= 1;
	my $rs = $self->jobs->search({contest => $args{contest}}, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
	$rs = $rs->search({'me.private'=> 0})          unless $args{private};
	$rs = $rs->search({'me.owner'  => $args{owner}})   if $args{owner};
	$rs = $rs->search({problem     => $args{problem}}) if $args{problem};
	return {
		log => [map {
			my %params = $_->get_columns;
			$params{owner_name}   = $_->owner->name;
			$params{problem_name} = $_->problem->name;
			$params{results} &&= decode_json $params{results};
			$params{size}      = length $params{source};
			delete $params{source};
			\%params
		} $rs->all],
		current_page => $rs->pager->current_page,
		maybe previous_page => $rs->pager->previous_page,
		maybe next_page => $rs->pager->next_page,
		maybe last_page => $rs->pager->last_page,
	}
}

sub job_entry {
	my ($self, $id) = @_;
	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
	my %params = $job->get_columns;
	$params{owner_name}   = $job->owner->name;
	$params{problem_name} = $job->problem->name;
	$params{contest_name} = $job->contest->name if $params{contest};
	$params{results} &&= decode_json $params{results};
	$params{size}      = length $params{source};
	delete $params{source};
	\%params
}

sub update_status {
	my ($self) = @_;
	my @jobs = $self->jobs->search(undef, {cache => 1})->all;

	my %hash;
	$hash{$_->get_column('problem'), $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1] for @jobs;
	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;

	my @contest_statuses = map {
		my $contest = $_->id;
		map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
	} $self->contests->all;

	my $txn = sub {
		$self->problem_statuses->delete;
		$self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
		$self->contest_statuses->delete;
		$self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
	};

	$self->txn_do($txn);
}

my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
my $ht = HTTP::Tiny->new;

sub purge {
	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
}

1;

__END__

=encoding utf-8

=head1 NAME

Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools

=head1 SYNOPSIS

  my $db = Gruntmaster::Data->connect('dbi:Pg:');

  my $problem = $db->problem('my_problem');
  $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
  $problem->rerun; # And rerun all jobs for this problem

  # ...

  my $contest = $db->contests->create({ # Create a new contest
    id => 'my_contest',
    name => 'My Awesome Contest',
    start => time + 100,
    end => time + 1900,
  });
  $db->contest_problems->create({ # Add a problem to the contest
    contest => 'my_contest',
    problem => 'my_problem',
  });

  say 'The contest has not started yet' if $contest->is_pending;

  # ...

  my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
  $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest

=head1 DESCRIPTION

Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.

In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:

=over

=item contests

Equivalent to C<< $schema->resultset('Contest') >>

=item contest_problems

Equivalent to C<< $schema->resultset('ContestProblem') >>

=item jobs

Equivalent to C<< $schema->resultset('Job') >>

=item problems

Equivalent to C<< $schema->resultset('Problem') >>

=item users

Equivalent to C<< $schema->resultset('User') >>

=item contest($id)

Equivalent to C<< $schema->resultset('Contest')->find($id) >>

=item job($id)

Equivalent to C<< $schema->resultset('Job')->find($id) >>

=item problem($id)

Equivalent to C<< $schema->resultset('Problem')->find($id) >>

=item user($id)

Equivalent to C<< $schema->resultset('User')->find($id) >>

=item user_list

Returns a list of users as an arrayref containing hashrefs.

=item user_entry($id)

Returns a hashref with information about the user $id.

=item problem_list([%args])

Returns a list of problems grouped by level. A hashref with levels as keys.

Takes the following arguments:

=over

=item owner

Only show problems owned by this user

=item contest

Only show problems in this contest

=back

=item problem_entry($id, [$contest, $user])

Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.

=item contest_list([%args])

Returns a list of contests grouped by state. A hashref with the following keys:

=over

=item pending

An arrayref of hashrefs representing pending contests

=item running

An arrayref of hashrefs representing running contests

=item finished

An arrayref of hashrefs representing finished contests

=back

Takes the following arguments:

=over

=item owner

Only show contests owned by this user.

=back

=item contest_entry($id)

Returns a hashref with information about the contest $id.

=item job_list([%args])

Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:

=over

=item owner

Only show jobs submitted by this user.

=item contest

Only show jobs submitted in this contest.

=item problem

Only show jobs submitted for this problem.

=item page

Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.

=back

=item job_entry($id)

Returns a hashref with information about the job $id.

=back

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.18.1 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
4ed3f8e7	1	use utf8;
bbf8209c	2	package Gruntmaster::Data;
4ed3f8e7 MG	3
	4	# Created by DBIx::Class::Schema::Loader
	5	# DO NOT MODIFY THE FIRST PART OF THIS FILE
	6
	7	use strict;
bbf8209c	8	use warnings;
014ee8a6	9
4ed3f8e7 MG	10	use base 'DBIx::Class::Schema';
	11
	12	__PACKAGE__->load_namespaces;
014ee8a6	13
f7386aab	14
4ed3f8e7 MG	15	# Created by DBIx::Class::Schema::Loader v0.07039 @ 2014-03-05 13:11:39
	16	# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:dAEmtAexvUaNXLgYz2rNEg
	17
edfc5928	18	use parent qw/Exporter/;
9e130d3b	19	our $VERSION = '5999.000_013';
de7226ca	20	our @EXPORT = qw/purge/; ## no critic (ProhibitAutomaticExportation)
4ed3f8e7 MG	21
4ed3f8e7 MG	22	use Lingua::EN::Inflect qw/PL_N/;
91203bd5	23	use JSON::MaybeXS qw/decode_json/;
edfc5928	24	use HTTP::Tiny;
3473324b	25	use PerlX::Maybe qw/maybe/;
4ed3f8e7	26	use Sub::Name qw/subname/;
014ee8a6	27
de625c9b MG	28	use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private statement timeout olimit value/];
	29	use constant USER_PUBLIC_COLUMNS => [qw/id admin name town university level/];
	30	use constant JOBS_PER_PAGE => 10;
	31
014ee8a6	32	sub dynsub{
fb6a4e3d	33	our ($name, $sub) = @_;
dcd72991	34	no strict 'refs'; ## no critic (Strict)
fb6a4e3d	35	*$name = subname $name => $sub
014ee8a6 MG	36	}
	37
	38	BEGIN {
adb42d4d	39	for my $rs (qw/contest contest_problem job open problem user problem_status contest_status/) {
4ed3f8e7	40	my $rsname = ucfirst $rs;
dcd72991	41	$rsname =~ s/_([a-z])/\u$1/gs;
4ed3f8e7 MG	42	dynsub PL_N($rs) => sub { $_[0]->resultset($rsname) };
4ed3f8e7 MG	43	dynsub $rs => sub { $_[0]->resultset($rsname)->find($_[1]) };
014ee8a6 MG	44	}
	45	}
	46
de625c9b	47	sub user_list {
c9311d50 MG	48	my ($self) = @_;
	49	my $rs = $self->users->search(undef, {columns => USER_PUBLIC_COLUMNS} );
	50	my (%solved, %attempted, %contests);
	51
	52	for my $row ($self->problem_statuses->all) {
	53	$solved {$row->rawowner}++ if $row->solved;
	54	$attempted{$row->rawowner}++ unless $row->solved;
	55	}
	56	$contests{$_->rawowner}++ for $self->contest_statuses->all;
	57
1db27a21	58	[ sort { $b->{solved} <=> $a->{solved} or $b->{attempted} <=> $a->{attempted} } map { ## no critic (ProhibitReverseSort)
c9311d50 MG	59	my $id = $_->id;
	60	+{ $_->get_columns,
	61	solved => ($solved{$id} // 0),
	62	attempted => ($attempted{$id} // 0),
	63	contests => ($contests{$id} // 0) }
281c3952	64	} $rs->all ]
de625c9b MG	65	}
	66
	67	sub user_entry {
	68	my ($self, $id) = @_;
adb42d4d	69	my $user = $self->users->find($id, {columns => USER_PUBLIC_COLUMNS, prefetch => [qw/problem_statuses contest_statuses/]});
197d1959 MG	70	my @problems = map { {problem => $_->get_column('problem'), solved => $_->solved} } $user->problem_statuses->search(undef, {order_by => 'problem'});
197d1959 MG	71	my @contests = map { {contest => $_->contest->id, contest_name => $_->contest->name, rank => $_->rank, score => $_->score} } $user->contest_statuses->search(undef, {prefetch => 'contest', order_by => 'contest.start DESC'});
adb42d4d	72	+{ $user->get_columns, problems => \@problems, contests => \@contests }
de625c9b MG	73	}
	74
	75	sub problem_list {
	76	my ($self, %args) = @_;
	77	my $rs = $self->problems->search(undef, {order_by => 'me.name', columns => PROBLEM_PUBLIC_COLUMNS, prefetch => 'owner'});
d4c5bf27	78	$rs = $rs->search({-or => ['contest_problems.contest' => undef, 'contest.stop' => {'<=', time}], 'me.private' => 0}, {join => {'contest_problems' => 'contest'}, distinct => 1}) unless $args{contest} \|\| $args{private};
de625c9b MG	79	$rs = $rs->search({'contest_problems.contest' => $args{contest}}, {join => 'contest_problems'}) if $args{contest};
	80	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
	81	my %params;
	82	$params{contest} = $args{contest} if $args{contest};
	83	for ($rs->all) {
	84	$params{$_->level} //= [];
35596ea8	85	push @{$params{$_->level}}, {$_->get_columns, owner_name => $_->owner->name} ;
de625c9b MG	86	}
	87	\%params
	88	}
	89
	90	sub problem_entry {
	91	my ($self, $id, $contest, $user) = @_;
de625c9b	92	my $running = $contest && $self->contest($contest)->is_running;
8bd66733 MG	93	my $columns = PROBLEM_PUBLIC_COLUMNS;
	94	push @$columns, 'solution' unless $running;
	95	my $pb = $self->problems->find($id, {columns => $columns, prefetch => 'owner'});
9396be04 MG	96	my $open;
	97	$open = $self->opens->find_or_create({
	98	contest => $contest,
	99	problem => $id,
	100	owner => $user,
	101	time => time,
	102	}) if $running;
2431260b	103	$contest &&= $self->contest($contest);
9396be04 MG	104	+{
	105	$pb->get_columns,
	106	owner_name => $pb->owner->name,
1ecf0766	107	cansubmit => !$contest \|\| !$contest->is_finished,
9396be04 MG	108	$running ? (
	109	contest_start => $contest->start,
	110	contest_stop => $contest->stop,
	111	open_time => $open->time
	112	) : (),
	113	}
de625c9b MG	114	}
	115
	116	sub contest_list {
	117	my ($self, %args) = @_;
	118	my $rs = $self->contests->search(undef, {order_by => {-desc => 'start'}, prefetch => 'owner'});
	119	$rs = $rs->search({owner => $args{owner}}) if $args{owner};
	120	my %params;
	121	for ($rs->all) {
	122	my $state = $_->is_pending ? 'pending' : $_->is_running ? 'running' : 'finished';
	123	$params{$state} //= [];
35596ea8	124	push @{$params{$state}}, { $_->get_columns, started => !$_->is_pending, owner_name => $_->owner->name };
de625c9b MG	125	}
	126	\%params
	127	}
	128
	129	sub contest_entry {
	130	my ($self, $id) = @_;
	131	my $ct = $self->contest($id);
	132	+{ $ct->get_columns, started => !$ct->is_pending, owner_name => $ct->owner->name }
	133	}
	134
	135	sub job_list {
	136	my ($self, %args) = @_;
	137	$args{page} //= 1;
17d49281	138	my $rs = $self->jobs->search({contest => $args{contest}}, {order_by => {-desc => 'me.id'}, prefetch => ['problem', 'owner'], rows => JOBS_PER_PAGE, page => $args{page}});
d4c5bf27 MG	139	$rs = $rs->search({'me.private'=> 0}) unless $args{private};
d4c5bf27 MG	140	$rs = $rs->search({'me.owner' => $args{owner}}) if $args{owner};
d4c5bf27	141	$rs = $rs->search({problem => $args{problem}}) if $args{problem};
3473324b MG	142	return {
	143	log => [map {
	144	my %params = $_->get_columns;
	145	$params{owner_name} = $_->owner->name;
	146	$params{problem_name} = $_->problem->name;
	147	$params{results} &&= decode_json $params{results};
	148	$params{size} = length $params{source};
	149	delete $params{source};
	150	\%params
	151	} $rs->all],
	152	current_page => $rs->pager->current_page,
	153	maybe previous_page => $rs->pager->previous_page,
	154	maybe next_page => $rs->pager->next_page,
	155	maybe last_page => $rs->pager->last_page,
	156	}
de625c9b MG	157	}
	158
	159	sub job_entry {
	160	my ($self, $id) = @_;
7d499cdd	161	my $job = $self->jobs->find($id, {prefetch => ['problem', 'owner', 'contest']});
de625c9b MG	162	my %params = $job->get_columns;
	163	$params{owner_name} = $job->owner->name;
	164	$params{problem_name} = $job->problem->name;
7d499cdd	165	$params{contest_name} = $job->contest->name if $params{contest};
de625c9b MG	166	$params{results} &&= decode_json $params{results};
	167	$params{size} = length $params{source};
	168	delete $params{source};
	169	\%params
	170	}
	171
adb42d4d MG	172	sub update_status {
	173	my ($self) = @_;
	174	my @jobs = $self->jobs->search(undef, {cache => 1})->all;
a2aa46e6	175
adb42d4d	176	my %hash;
9bfb38e0	177	$hash{$_->get_column('problem'), $_->get_column('owner')} = [$_->id, $_->result ? 0 : 1] for @jobs;
adb42d4d MG	178	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
	179
	180	my @contest_statuses = map {
	181	my $contest = $_->id;
751c70b5	182	map { [$contest, $_->{user}, $_->{score}, $_->{rank}] } $_->standings
adb42d4d MG	183	} $self->contests->all;
	184
	185	my $txn = sub {
	186	$self->problem_statuses->delete;
	187	$self->problem_statuses->populate([[qw/problem owner job solved/], @problem_statuses]);
	188	$self->contest_statuses->delete;
	189	$self->contest_statuses->populate([[qw/contest owner score rank/], @contest_statuses]);
	190	};
	191
	192	$self->txn_do($txn);
	193	}
	194
edfc5928 MG	195	my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
	196	my $ht = HTTP::Tiny->new;
	197
de7226ca MG	198	sub purge {
	199	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
	200	}
edfc5928	201
f7386aab	202	1;
4a8747ef MG	203
	204	__END__
	205
	206	=encoding utf-8
	207
	208	=head1 NAME
	209
	210	Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
	211
	212	=head1 SYNOPSIS
	213
	214	my $db = Gruntmaster::Data->connect('dbi:Pg:');
cbb36c78 MG	215
	216	my $problem = $db->problem('my_problem');
	217	$problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
	218	$problem->rerun; # And rerun all jobs for this problem
	219
	220	# ...
	221
	222	my $contest = $db->contests->create({ # Create a new contest
	223	id => 'my_contest',
	224	name => 'My Awesome Contest',
	225	start => time + 100,
	226	end => time + 1900,
	227	});
	228	$db->contest_problems->create({ # Add a problem to the contest
	229	contest => 'my_contest',
	230	problem => 'my_problem',
	231	});
	232
	233	say 'The contest has not started yet' if $contest->is_pending;
	234
	235	# ...
	236
	237	my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
	238	$_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
4a8747ef MG	239
	240	=head1 DESCRIPTION
	241
cbb36c78 MG	242	Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
	243
	244	In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
	245
	246	=over
	247
	248	=item contests
	249
	250	Equivalent to C<< $schema->resultset('Contest') >>
	251
	252	=item contest_problems
	253
	254	Equivalent to C<< $schema->resultset('ContestProblem') >>
	255
	256	=item jobs
	257
	258	Equivalent to C<< $schema->resultset('Job') >>
	259
	260	=item problems
	261
	262	Equivalent to C<< $schema->resultset('Problem') >>
	263
	264	=item users
	265
	266	Equivalent to C<< $schema->resultset('User') >>
	267
	268	=item contest($id)
	269
	270	Equivalent to C<< $schema->resultset('Contest')->find($id) >>
	271
	272	=item job($id)
	273
	274	Equivalent to C<< $schema->resultset('Job')->find($id) >>
	275
	276	=item problem($id)
	277
	278	Equivalent to C<< $schema->resultset('Problem')->find($id) >>
	279
	280	=item user($id)
	281
	282	Equivalent to C<< $schema->resultset('User')->find($id) >>
	283
de625c9b MG	284	=item user_list
	285
	286	Returns a list of users as an arrayref containing hashrefs.
	287
	288	=item user_entry($id)
	289
	290	Returns a hashref with information about the user $id.
	291
	292	=item problem_list([%args])
	293
	294	Returns a list of problems grouped by level. A hashref with levels as keys.
	295
	296	Takes the following arguments:
	297
	298	=over
	299
	300	=item owner
	301
	302	Only show problems owned by this user
	303
	304	=item contest
	305
	306	Only show problems in this contest
	307
	308	=back
	309
	310	=item problem_entry($id, [$contest, $user])
	311
	312	Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
	313
	314	=item contest_list([%args])
	315
	316	Returns a list of contests grouped by state. A hashref with the following keys:
	317
	318	=over
	319
	320	=item pending
	321
	322	An arrayref of hashrefs representing pending contests
	323
	324	=item running
	325
	326	An arrayref of hashrefs representing running contests
	327
	328	=item finished
	329
	330	An arrayref of hashrefs representing finished contests
	331
	332	=back
	333
	334	Takes the following arguments:
	335
	336	=over
	337
	338	=item owner
	339
	340	Only show contests owned by this user.
	341
	342	=back
	343
	344	=item contest_entry($id)
	345
	346	Returns a hashref with information about the contest $id.
	347
348	=item job_list([%args])
349
350	Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
351
352	=over
353
354	=item owner
355
356	Only show jobs submitted by this user.
357
358	=item contest
359
360	Only show jobs submitted in this contest.
361
362	=item problem
363
364	Only show jobs submitted for this problem.
365
366	=item page
367
368	Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
369
370	=back
371
372	=item job_entry($id)
373
374	Returns a hashref with information about the job $id.
375
cbb36c78	376	=back
4a8747ef MG	377
	378	=head1 AUTHOR
	379
	380	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	381
	382	=head1 COPYRIGHT AND LICENSE
	383
	384	Copyright (C) 2014 by Marius Gavrilescu
	385
9d2e740e MG	386	This library is free software; you can redistribute it and/or modify
	387	it under the same terms as Perl itself, either Perl version 5.18.1 or,
	388	at your option, any later version of Perl 5 you may have available.
4a8747ef MG	389
	390
	391	=cut