[gruntmaster-data.git] / lib / Gruntmaster / Data.pm

package Gruntmaster::Data;
use 5.014;
use warnings;

use parent qw/Exporter/;
our $VERSION = '5999.000_013';
our @EXPORT = qw/dbinit purge db user_list user_entry problem_list problem_entry contest_list contest_entry contest_has_problem job_list job_entry create_job standings update_status rerun_job take_job finish_job/; ## no critic (ProhibitAutomaticExportation)

use JSON::MaybeXS qw/decode_json/;
use HTTP::Tiny;
use PerlX::Maybe qw/maybe/;

use DBI;
use DBIx::Simple;
use List::Util qw/sum/;
use SQL::Abstract;

use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
use constant JOBS_PER_PAGE => 50;

my %statements = (
	user_list_sth => 'SELECT * FROM user_list LIMIT 200',
	user_entry_sth => 'SELECT * FROM user_data WHERE id = ?',

	problem_status_sth => 'SELECT problem,solved FROM problem_status WHERE owner = ?',
	contest_status_sth => 'SELECT contest,score,rank FROM contest_status WHERE owner = ?',

	contest_list_sth => 'SELECT * FROM contest_entry',
	contest_entry_sth => 'SELECT * FROM contest_entry WHERE id = ?',
	contest_has_problem_sth => 'SELECT EXISTS(SELECT 1 FROM contest_problems WHERE contest = ? AND problem = ?)',
	opens_sth => 'SELECT problem,owner,time FROM opens WHERE contest = ?',

	problem_entry_sth => 'SELECT ' . (join ',', @{PROBLEM_PUBLIC_COLUMNS()}, 'statement', 'solution') . ' FROM problems WHERE id = ?',
	limits_sth => 'SELECT format,timeout FROM limits WHERE problem = ?',

	job_entry_sth => 'SELECT * FROM job_entry WHERE id = ?',

	rerun_job_sth => 'UPDATE jobs SET daemon=NULL,result=-2,result_text=NULL,results=NULL,errors=NULL WHERE id = ?',
	take_job_sth => 'UPDATE jobs SET daemon=? WHERE id = (SELECT id FROM jobs WHERE daemon IS NULL LIMIT 1 FOR UPDATE) RETURNING id',
);

our $db;
sub db () { $db }

sub dbinit {
	$db = DBIx::Simple->new(@_);
	$db->keep_statements = 100;
};

sub purge;

sub query {
	my ($stat, @extra) = @_;
	$db->query($statements{$stat}, @extra)
}

my (%name_cache, %name_cache_time);
use constant NAME_CACHE_MAX_AGE => 5;

sub object_name {
	my ($table, $id) = @_;
	$name_cache_time{$table} //= 0;
	if (time - $name_cache_time{$table} > NAME_CACHE_MAX_AGE) {
		$name_cache_time{$table} = time;
		$name_cache{$table} = {};
		$name_cache{$table} = $db->select($table, 'id,name')->map;
	}

	$name_cache{$table}{$id}
}


sub add_names ($) { ## no critic (ProhibitSubroutinePrototypes)
	my ($el) = @_;
	return unless defined $el;
	if (ref $el eq 'ARRAY') {
		&add_names ($_) for @$el ## no critic (ProhibitAmpersandSigils)
	} else {
		for my $object (qw/contest owner problem/) {
			my $table = $object eq 'owner' ? 'users' : "${object}s";
			$el->{"${object}_name"} = object_name $table, $el->{$object} if defined $el->{$object}
		}
	}

	$el
}

sub user_list { scalar query('user_list_sth')->hashes }

sub user_entry {
	my ($id) = @_;
	my $ret = query('user_entry_sth', $id)->hash;
	$ret->{problems} = add_names query('problem_status_sth', $id)->hashes;
	$ret->{contests} = add_names query('contest_status_sth', $id)->hashes;

	$ret;
}

sub problem_list {
	my (%args) = @_;
	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	push @columns, 'solution' if $args{solution};
	my %where;
	$where{private} = 0 unless $args{contest} || $args{private};
	$where{'cp.contest'} = $args{contest} if $args{contest};
	$where{owner} = $args{owner} if $args{owner};

	my $table = $args{contest} ? 'problems JOIN contest_problems cp ON cp.problem = id' : 'problems';
	add_names $db->select(\$table, \@columns, \%where, 'name')->hashes
}

sub problem_entry {
	my ($id, $contest) = @_;
	$contest = contest_entry ($contest) if $contest;
	my $ret = add_names query(problem_entry_sth => $id)->hash;
	my $limits = query(limits_sth => $id)->hashes;
	$ret->{limits} = $limits if @$limits;

	if ($contest) {
		$ret->{contest_start} = $contest->{start};
		$ret->{contest_stop}  = $contest->{stop};
		delete $ret->{solution}
	}

	$ret
}

sub contest_list { add_names query('contest_list_sth')->hashes }

sub contest_entry { add_names query(contest_entry_sth => $_[0])->hash }

sub contest_has_problem { query('contest_has_problem_sth', @_[0, 1])->flat }

sub job_list {
	my (%args) = @_;
	$args{page} = int ($args{page} // 1);
	my %where = (
		maybe contest => $args{contest},
		maybe owner => $args{owner},
		maybe problem => $args{problem},
		maybe result => $args{result},
	);
	$where{private} = 0 unless $args{private};

	my $rows = $db->select('job_entry', 'COUNT(*)', \%where)->list;
	my $pages = int (($rows + JOBS_PER_PAGE - 1) / JOBS_PER_PAGE);
	my ($stmt, @bind) = $db->abstract->select('job_entry', '*', \%where, {-desc => 'id'});
	my $jobs = add_names $db->query("$stmt LIMIT " . JOBS_PER_PAGE . ' OFFSET ' . ($args{page} - 1) * JOBS_PER_PAGE, @bind)->hashes;
	my $pageinfo = {
		current_page => $args{page},
		last_page    => $pages,
		($args{page} - 1) ? (previous_page => $args{page} - 1) : (),
		($args{page} < $pages) ? (next_page => $args{page} + 1) : (),
	};
	wantarray ? ($jobs, $pageinfo) : $jobs;
}

sub job_entry {
	my $ret = add_names query(job_entry_sth => $_[0])->hash;
	$ret->{results} = decode_json $ret->{results} if $ret->{results};
	$ret
}

sub create_job {
	my (%args) = @_;
	$db->update('users', {lastjob => time}, {id => $args{owner}});
	purge '/log/';
	scalar $db->insert('jobs', \%args, {returning => 'id'})->list
}

sub _calc_score {
	my ($mxscore, $time, $tries, $totaltime) = @_;
	my $score = $mxscore;
	$time = 300 if $time > $totaltime; # uncoverable branch true does not happen anymore (only possible if opens are broken)
	$score = ($totaltime - $time) / $totaltime * $score;
	$score -= $tries / 10 * $mxscore;
	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
	int $score + 0.5
}

sub standings {
	my ($ct) = @_;
	my @problems = sort { $a->{value} <=> $b->{value} } @{problem_list contest => $ct};
	my %values = map { $_->{id} => $_->{value} } @problems;
	$ct = contest_entry $ct;

	my (%scores, %tries, %opens);
	my $opens = query(opens_sth => $ct->{id});
	while ($opens->into(my ($problem, $owner, $time))) {
		$opens{$problem, $owner} = $time;
	}

	my $jobs = $db->select('job_entry', '*', {contest => $ct->{id}}, 'id');

	while (my $job = $jobs->hash) {
		my $open = $opens{$job->{problem}, $job->{owner}} // $ct->{start};
		my $time = $job->{date} - $open;
		next if $time < 0; # uncoverable branch true job sent before contest is deprecated
		my $value = $values{$job->{problem}};
		my $factor = $job->{result} ? 0 : 1;
		$factor = $1 / 100 if $job->{result_text} =~ /^(\d+ )/s;
		$scores{$job->{owner}}{$job->{problem}} = int ($factor * _calc_score ($value, $time, $tries{$job->{owner}}{$job->{problem}}++, $ct->{stop} - $ct->{start}));
	}

	my @st = sort { $b->{score} <=> $a->{score} or $a->{user} cmp $b->{user} } map { ## no critic (ProhibitReverseSortBlock)
		my $user = $_;
		+{
			user => $user,
			user_name => object_name(users => $user),
			score => sum (values %{$scores{$user}}),
			scores => [map { $scores{$user}{$_->{id}} // '-'} @problems],
		}
	} keys %scores;

	$st[0]->{rank} = 1 if @st;
	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;

	\@st
}

sub update_status {
	my $jobs = $db->select('jobs', 'id,owner,problem,result', {-not_bool => 'private'}, 'id');

	my %hash;
	while ($jobs->into(my ($id, $owner, $problem, $result))) {
		$hash{$problem, $owner} = [$id, $result ? 0 : 1];
	}

	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;

	my @contest_statuses = map {
		my $ct = $_;
		map { [$ct, $_->{user}, $_->{score}, $_->{rank}] } @{standings $ct}
	} $db->select('contests', 'id')->flat;

	$db->begin;
	$db->delete('problem_status');
	$db->query('INSERT INTO problem_status (problem,owner,job,solved) VALUES (??)', @$_) for @problem_statuses;
	$db->delete('contest_status');
	$db->query('INSERT INTO contest_status (contest,owner,score,rank) VALUES (??)', @$_) for @contest_statuses;
	$db->commit
}

sub rerun_job {
	my ($id) = @_;
	query rerun_job_sth => $id;
	purge '/log/';
	purge "/log/$id";
}

sub take_job {
	my ($daemon) = @_;
	my $id = query(take_job_sth => $daemon)->list;
	return $id ? db->select(jobs => '*', {id => $id})->hash : undef;
}

sub finish_job {
	my ($job, $private, %args) = @_;
	db->update(jobs => \%args, {id => $job->{id}});
	return if $private;
	my $status = {
		problem => $job->{problem},
		owner   => $job->{owner},
		job     => $job->{id},
		solved  => ($args{result} ? 0 : 1),
	};
	eval {
		db->insert(problem_status => $status)
	} or db->update(problem_status => $status, {owner => $job->{owner}, problem => $job->{problem}});
}

my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
my $ht = HTTP::Tiny->new;

sub purge {
	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
}

1;

__END__

=encoding utf-8

=head1 NAME

Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools

=head1 SYNOPSIS

  my $db = Gruntmaster::Data->connect('dbi:Pg:');

  my $problem = $db->problem('my_problem');
  $problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
  $problem->rerun; # And rerun all jobs for this problem

  # ...

  my $contest = $db->contests->create({ # Create a new contest
    id => 'my_contest',
    name => 'My Awesome Contest',
    start => time + 100,
    end => time + 1900,
  });
  $db->contest_problems->create({ # Add a problem to the contest
    contest => 'my_contest',
    problem => 'my_problem',
  });

  say 'The contest has not started yet' if $contest->is_pending;

  # ...

  my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
  $_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest

=head1 DESCRIPTION

Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.

In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:

=over

=item contests

Equivalent to C<< $schema->resultset('Contest') >>

=item contest_problems

Equivalent to C<< $schema->resultset('ContestProblem') >>

=item jobs

Equivalent to C<< $schema->resultset('Job') >>

=item problems

Equivalent to C<< $schema->resultset('Problem') >>

=item users

Equivalent to C<< $schema->resultset('User') >>

=item contest($id)

Equivalent to C<< $schema->resultset('Contest')->find($id) >>

=item job($id)

Equivalent to C<< $schema->resultset('Job')->find($id) >>

=item problem($id)

Equivalent to C<< $schema->resultset('Problem')->find($id) >>

=item user($id)

Equivalent to C<< $schema->resultset('User')->find($id) >>

=item user_list

Returns a list of users as an arrayref containing hashrefs.

=item user_entry($id)

Returns a hashref with information about the user $id.

=item problem_list([%args])

Returns a list of problems grouped by level. A hashref with levels as keys.

Takes the following arguments:

=over

=item owner

Only show problems owned by this user

=item contest

Only show problems in this contest

=back

=item problem_entry($id, [$contest, $user])

Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.

=item contest_list([%args])

Returns a list of contests grouped by state. A hashref with the following keys:

=over

=item pending

An arrayref of hashrefs representing pending contests

=item running

An arrayref of hashrefs representing running contests

=item finished

An arrayref of hashrefs representing finished contests

=back

Takes the following arguments:

=over

=item owner

Only show contests owned by this user.

=back

=item contest_entry($id)

Returns a hashref with information about the contest $id.

=item job_list([%args])

Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:

=over

=item owner

Only show jobs submitted by this user.

=item contest

Only show jobs submitted in this contest.

=item problem

Only show jobs submitted for this problem.

=item page

Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.

=back

=item job_entry($id)

Returns a hashref with information about the job $id.

=back

=head1 AUTHOR

Marius Gavrilescu E<lt>marius@ieval.roE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2014 by Marius Gavrilescu

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.18.1 or,
at your option, any later version of Perl 5 you may have available.


=cut
Commit	Line	Data
bbf8209c	1	package Gruntmaster::Data;
6c0423f4	2	use 5.014;
bbf8209c	3	use warnings;
014ee8a6	4
edfc5928	5	use parent qw/Exporter/;
9e130d3b	6	our $VERSION = '5999.000_013';
6fb81f9a	7	our @EXPORT = qw/dbinit purge db user_list user_entry problem_list problem_entry contest_list contest_entry contest_has_problem job_list job_entry create_job standings update_status rerun_job take_job finish_job/; ## no critic (ProhibitAutomaticExportation)
4ed3f8e7	8
91203bd5	9	use JSON::MaybeXS qw/decode_json/;
edfc5928	10	use HTTP::Tiny;
3473324b	11	use PerlX::Maybe qw/maybe/;
52172a1a MG	12
	13	use DBI;
	14	use DBIx::Simple;
	15	use List::Util qw/sum/;
	16	use SQL::Abstract;
014ee8a6	17
e890b3ae	18	use constant PROBLEM_PUBLIC_COLUMNS => [qw/id author writer level name owner private timeout olimit value/];
e1250e20	19	use constant JOBS_PER_PAGE => 50;
de625c9b	20
52172a1a MG	21	my %statements = (
	22	user_list_sth => 'SELECT * FROM user_list LIMIT 200',
	23	user_entry_sth => 'SELECT * FROM user_data WHERE id = ?',
	24
	25	problem_status_sth => 'SELECT problem,solved FROM problem_status WHERE owner = ?',
	26	contest_status_sth => 'SELECT contest,score,rank FROM contest_status WHERE owner = ?',
	27
	28	contest_list_sth => 'SELECT * FROM contest_entry',
	29	contest_entry_sth => 'SELECT * FROM contest_entry WHERE id = ?',
52172a1a MG	30	contest_has_problem_sth => 'SELECT EXISTS(SELECT 1 FROM contest_problems WHERE contest = ? AND problem = ?)',
	31	opens_sth => 'SELECT problem,owner,time FROM opens WHERE contest = ?',
	32
	33	problem_entry_sth => 'SELECT ' . (join ',', @{PROBLEM_PUBLIC_COLUMNS()}, 'statement', 'solution') . ' FROM problems WHERE id = ?',
	34	limits_sth => 'SELECT format,timeout FROM limits WHERE problem = ?',
52172a1a MG	35
52172a1a MG	36	job_entry_sth => 'SELECT * FROM job_entry WHERE id = ?',
341fb893 MG	37
341fb893 MG	38	rerun_job_sth => 'UPDATE jobs SET daemon=NULL,result=-2,result_text=NULL,results=NULL,errors=NULL WHERE id = ?',
9dc335bd	39	take_job_sth => 'UPDATE jobs SET daemon=? WHERE id = (SELECT id FROM jobs WHERE daemon IS NULL LIMIT 1 FOR UPDATE) RETURNING id',
52172a1a MG	40	);
52172a1a MG	41
50b165c3	42	our $db;
341fb893	43	sub db () { $db }
23aa7eca	44
6fb81f9a	45	sub dbinit {
62a58bf3 MG	46	$db = DBIx::Simple->new(@_);
62a58bf3 MG	47	$db->keep_statements = 100;
52172a1a MG	48	};
	49
	50	sub purge;
	51
	52	sub query {
62a58bf3	53	my ($stat, @extra) = @_;
4623c9f2	54	$db->query($statements{$stat}, @extra)
52172a1a MG	55	}
	56
	57	my (%name_cache, %name_cache_time);
	58	use constant NAME_CACHE_MAX_AGE => 5;
	59
	60	sub object_name {
62a58bf3	61	my ($table, $id) = @_;
52172a1a MG	62	$name_cache_time{$table} //= 0;
	63	if (time - $name_cache_time{$table} > NAME_CACHE_MAX_AGE) {
	64	$name_cache_time{$table} = time;
	65	$name_cache{$table} = {};
62a58bf3	66	$name_cache{$table} = $db->select($table, 'id,name')->map;
52172a1a MG	67	}
	68
	69	$name_cache{$table}{$id}
	70	}
	71
	72
6c0423f4	73	sub add_names ($) { ## no critic (ProhibitSubroutinePrototypes)
62a58bf3	74	my ($el) = @_;
ee00be0c	75	return unless defined $el;
52172a1a	76	if (ref $el eq 'ARRAY') {
6c0423f4	77	&add_names ($_) for @$el ## no critic (ProhibitAmpersandSigils)
52172a1a MG	78	} else {
	79	for my $object (qw/contest owner problem/) {
	80	my $table = $object eq 'owner' ? 'users' : "${object}s";
62a58bf3	81	$el->{"${object}_name"} = object_name $table, $el->{$object} if defined $el->{$object}
52172a1a MG	82	}
	83	}
	84
	85	$el
	86	}
	87
b69781c1	88	sub user_list { scalar query('user_list_sth')->hashes }
52172a1a MG	89
52172a1a MG	90	sub user_entry {
62a58bf3 MG	91	my ($id) = @_;
	92	my $ret = query('user_entry_sth', $id)->hash;
	93	$ret->{problems} = add_names query('problem_status_sth', $id)->hashes;
	94	$ret->{contests} = add_names query('contest_status_sth', $id)->hashes;
52172a1a	95
52172a1a MG	96	$ret;
	97	}
	98
52172a1a	99	sub problem_list {
62a58bf3	100	my (%args) = @_;
52172a1a MG	101	my @columns = @{PROBLEM_PUBLIC_COLUMNS()};
	102	push @columns, 'solution' if $args{solution};
	103	my %where;
	104	$where{private} = 0 unless $args{contest} \|\| $args{private};
	105	$where{'cp.contest'} = $args{contest} if $args{contest};
	106	$where{owner} = $args{owner} if $args{owner};
	107
	108	my $table = $args{contest} ? 'problems JOIN contest_problems cp ON cp.problem = id' : 'problems';
b69781c1	109	add_names $db->select(\$table, \@columns, \%where, 'name')->hashes
52172a1a MG	110	}
52172a1a MG	111
52172a1a	112	sub problem_entry {
a1a4325a	113	my ($id, $contest) = @_;
4623c9f2	114	$contest = contest_entry ($contest) if $contest;
62a58bf3 MG	115	my $ret = add_names query(problem_entry_sth => $id)->hash;
62a58bf3 MG	116	my $limits = query(limits_sth => $id)->hashes;
52172a1a MG	117	$ret->{limits} = $limits if @$limits;
	118
	119	if ($contest) {
	120	$ret->{contest_start} = $contest->{start};
	121	$ret->{contest_stop} = $contest->{stop};
d33e87f2	122	delete $ret->{solution}
52172a1a MG	123	}
	124
	125	$ret
	126	}
	127
b69781c1	128	sub contest_list { add_names query('contest_list_sth')->hashes }
52172a1a	129
b69781c1	130	sub contest_entry { add_names query(contest_entry_sth => $_[0])->hash }
52172a1a	131
b69781c1	132	sub contest_has_problem { query('contest_has_problem_sth', @_[0, 1])->flat }
52172a1a	133
52172a1a	134	sub job_list {
62a58bf3	135	my (%args) = @_;
b69781c1	136	$args{page} = int ($args{page} // 1);
52172a1a MG	137	my %where = (
	138	maybe contest => $args{contest},
	139	maybe owner => $args{owner},
	140	maybe problem => $args{problem},
	141	maybe result => $args{result},
	142	);
	143	$where{private} = 0 unless $args{private};
	144
62a58bf3	145	my $rows = $db->select('job_entry', 'COUNT(*)', \%where)->list;
52172a1a	146	my $pages = int (($rows + JOBS_PER_PAGE - 1) / JOBS_PER_PAGE);
62a58bf3	147	my ($stmt, @bind) = $db->abstract->select('job_entry', '*', \%where, {-desc => 'id'});
b69781c1 MG	148	my $jobs = add_names $db->query("$stmt LIMIT " . JOBS_PER_PAGE . ' OFFSET ' . ($args{page} - 1) * JOBS_PER_PAGE, @bind)->hashes;
b69781c1 MG	149	my $pageinfo = {
52172a1a MG	150	current_page => $args{page},
52172a1a MG	151	last_page => $pages,
b69781c1 MG	152	($args{page} - 1) ? (previous_page => $args{page} - 1) : (),
	153	($args{page} < $pages) ? (next_page => $args{page} + 1) : (),
	154	};
	155	wantarray ? ($jobs, $pageinfo) : $jobs;
52172a1a MG	156	}
	157
	158	sub job_entry {
b69781c1	159	my $ret = add_names query(job_entry_sth => $_[0])->hash;
4623c9f2	160	$ret->{results} = decode_json $ret->{results} if $ret->{results};
62a58bf3	161	$ret
52172a1a MG	162	}
52172a1a MG	163
52172a1a	164	sub create_job {
62a58bf3	165	my (%args) = @_;
5e77eeae	166	$db->update('users', {lastjob => time}, {id => $args{owner}});
52172a1a	167	purge '/log/';
62a58bf3	168	scalar $db->insert('jobs', \%args, {returning => 'id'})->list
52172a1a MG	169	}
52172a1a MG	170
01fcdebe	171	sub _calc_score {
52172a1a MG	172	my ($mxscore, $time, $tries, $totaltime) = @_;
52172a1a MG	173	my $score = $mxscore;
4623c9f2	174	$time = 300 if $time > $totaltime; # uncoverable branch true does not happen anymore (only possible if opens are broken)
52172a1a MG	175	$score = ($totaltime - $time) / $totaltime * $score;
	176	$score -= $tries / 10 * $mxscore;
	177	$score = $mxscore * 3 / 10 if $score < $mxscore * 3 / 10;
	178	int $score + 0.5
	179	}
	180
	181	sub standings {
62a58bf3	182	my ($ct) = @_;
01fcdebe MG	183	my @problems = sort { $a->{value} <=> $b->{value} } @{problem_list contest => $ct};
01fcdebe MG	184	my %values = map { $_->{id} => $_->{value} } @problems;
62a58bf3	185	$ct = contest_entry $ct;
52172a1a	186
52172a1a	187	my (%scores, %tries, %opens);
62a58bf3	188	my $opens = query(opens_sth => $ct->{id});
52172a1a MG	189	while ($opens->into(my ($problem, $owner, $time))) {
	190	$opens{$problem, $owner} = $time;
	191	}
	192
62a58bf3	193	my $jobs = $db->select('job_entry', '*', {contest => $ct->{id}}, 'id');
52172a1a MG	194
	195	while (my $job = $jobs->hash) {
	196	my $open = $opens{$job->{problem}, $job->{owner}} // $ct->{start};
	197	my $time = $job->{date} - $open;
4623c9f2	198	next if $time < 0; # uncoverable branch true job sent before contest is deprecated
52172a1a MG	199	my $value = $values{$job->{problem}};
	200	my $factor = $job->{result} ? 0 : 1;
	201	$factor = $1 / 100 if $job->{result_text} =~ /^(\d+ )/s;
01fcdebe	202	$scores{$job->{owner}}{$job->{problem}} = int ($factor * _calc_score ($value, $time, $tries{$job->{owner}}{$job->{problem}}++, $ct->{stop} - $ct->{start}));
52172a1a MG	203	}
	204
	205	my @st = sort { $b->{score} <=> $a->{score} or $a->{user} cmp $b->{user} } map { ## no critic (ProhibitReverseSortBlock)
	206	my $user = $_;
	207	+{
	208	user => $user,
62a58bf3	209	user_name => object_name(users => $user),
52172a1a	210	score => sum (values %{$scores{$user}}),
01fcdebe	211	scores => [map { $scores{$user}{$_->{id}} // '-'} @problems],
52172a1a MG	212	}
	213	} keys %scores;
	214
	215	$st[0]->{rank} = 1 if @st;
	216	$st[$_]->{rank} = $st[$_ - 1]->{rank} + ($st[$_]->{score} < $st[$_ - 1]->{score}) for 1 .. $#st;
01fcdebe MG	217
01fcdebe MG	218	\@st
52172a1a MG	219	}
52172a1a MG	220
52172a1a	221	sub update_status {
1761e170	222	my $jobs = $db->select('jobs', 'id,owner,problem,result', {-not_bool => 'private'}, 'id');
52172a1a MG	223
	224	my %hash;
	225	while ($jobs->into(my ($id, $owner, $problem, $result))) {
	226	$hash{$problem, $owner} = [$id, $result ? 0 : 1];
	227	}
	228
	229	my @problem_statuses = map { [split ($;), @{$hash{$_}} ] } keys %hash;
	230
	231	my @contest_statuses = map {
	232	my $ct = $_;
01fcdebe	233	map { [$ct, $_->{user}, $_->{score}, $_->{rank}] } @{standings $ct}
62a58bf3 MG	234	} $db->select('contests', 'id')->flat;
	235
	236	$db->begin;
	237	$db->delete('problem_status');
	238	$db->query('INSERT INTO problem_status (problem,owner,job,solved) VALUES (??)', @$_) for @problem_statuses;
	239	$db->delete('contest_status');
	240	$db->query('INSERT INTO contest_status (contest,owner,score,rank) VALUES (??)', @$_) for @contest_statuses;
	241	$db->commit
52172a1a MG	242	}
52172a1a MG	243
341fb893 MG	244	sub rerun_job {
341fb893 MG	245	my ($id) = @_;
686bacca	246	query rerun_job_sth => $id;
341fb893 MG	247	purge '/log/';
	248	purge "/log/$id";
	249	}
	250
9dc335bd MG	251	sub take_job {
	252	my ($daemon) = @_;
	253	my $id = query(take_job_sth => $daemon)->list;
cab36bc4	254	return $id ? db->select(jobs => '*', {id => $id})->hash : undef;
9dc335bd MG	255	}
	256
	257	sub finish_job {
	258	my ($job, $private, %args) = @_;
	259	db->update(jobs => \%args, {id => $job->{id}});
	260	return if $private;
	261	my $status = {
	262	problem => $job->{problem},
	263	owner => $job->{owner},
	264	job => $job->{id},
	265	solved => ($args{result} ? 0 : 1),
	266	};
	267	eval {
	268	db->insert(problem_status => $status)
	269	} or db->update(problem_status => $status, {owner => $job->{owner}, problem => $job->{problem}});
	270	}
	271
edfc5928 MG	272	my @PURGE_HOSTS = exists $ENV{PURGE_HOSTS} ? split ' ', $ENV{PURGE_HOSTS} : ();
	273	my $ht = HTTP::Tiny->new;
	274
de7226ca MG	275	sub purge {
	276	$ht->request(PURGE => "http://$_$_[0]") for @PURGE_HOSTS;
	277	}
edfc5928	278
f7386aab	279	1;
4a8747ef MG	280
	281	__END__
	282
	283	=encoding utf-8
	284
	285	=head1 NAME
	286
	287	Gruntmaster::Data - Gruntmaster 6000 Online Judge -- database interface and tools
	288
	289	=head1 SYNOPSIS
	290
	291	my $db = Gruntmaster::Data->connect('dbi:Pg:');
cbb36c78 MG	292
	293	my $problem = $db->problem('my_problem');
	294	$problem->update({timeout => 2.5}); # Set time limit to 2.5 seconds
	295	$problem->rerun; # And rerun all jobs for this problem
	296
	297	# ...
	298
	299	my $contest = $db->contests->create({ # Create a new contest
	300	id => 'my_contest',
	301	name => 'My Awesome Contest',
	302	start => time + 100,
	303	end => time + 1900,
	304	});
	305	$db->contest_problems->create({ # Add a problem to the contest
	306	contest => 'my_contest',
	307	problem => 'my_problem',
	308	});
	309
	310	say 'The contest has not started yet' if $contest->is_pending;
	311
	312	# ...
	313
	314	my @jobs = $db->jobs->search({contest => 'my_contest', owner => 'MGV'})->all;
	315	$_->rerun for @jobs; # Rerun all jobs sent by MGV in my_contest
4a8747ef MG	316
	317	=head1 DESCRIPTION
	318
cbb36c78 MG	319	Gruntmaster::Data is the interface to the Gruntmaster 6000 database. Read the L<DBIx::Class> documentation for usage information.
	320
	321	In addition to the typical DBIx::Class::Schema methods, this module contains several convenience methods:
	322
	323	=over
	324
	325	=item contests
	326
	327	Equivalent to C<< $schema->resultset('Contest') >>
	328
	329	=item contest_problems
	330
	331	Equivalent to C<< $schema->resultset('ContestProblem') >>
	332
	333	=item jobs
	334
	335	Equivalent to C<< $schema->resultset('Job') >>
	336
	337	=item problems
	338
	339	Equivalent to C<< $schema->resultset('Problem') >>
	340
	341	=item users
	342
	343	Equivalent to C<< $schema->resultset('User') >>
	344
	345	=item contest($id)
	346
	347	Equivalent to C<< $schema->resultset('Contest')->find($id) >>
	348
	349	=item job($id)
	350
	351	Equivalent to C<< $schema->resultset('Job')->find($id) >>
	352
	353	=item problem($id)
	354
	355	Equivalent to C<< $schema->resultset('Problem')->find($id) >>
	356
	357	=item user($id)
	358
	359	Equivalent to C<< $schema->resultset('User')->find($id) >>
	360
de625c9b MG	361	=item user_list
	362
	363	Returns a list of users as an arrayref containing hashrefs.
	364
	365	=item user_entry($id)
	366
	367	Returns a hashref with information about the user $id.
	368
	369	=item problem_list([%args])
	370
	371	Returns a list of problems grouped by level. A hashref with levels as keys.
	372
	373	Takes the following arguments:
	374
	375	=over
	376
	377	=item owner
	378
	379	Only show problems owned by this user
	380
	381	=item contest
	382
	383	Only show problems in this contest
	384
	385	=back
	386
	387	=item problem_entry($id, [$contest, $user])
	388
	389	Returns a hashref with information about the problem $id. If $contest and $user are present, problem open data is updated.
	390
	391	=item contest_list([%args])
	392
	393	Returns a list of contests grouped by state. A hashref with the following keys:
	394
	395	=over
	396
	397	=item pending
	398
	399	An arrayref of hashrefs representing pending contests
	400
	401	=item running
	402
	403	An arrayref of hashrefs representing running contests
	404
	405	=item finished
	406
	407	An arrayref of hashrefs representing finished contests
	408
	409	=back
	410
	411	Takes the following arguments:
	412
	413	=over
	414
	415	=item owner
	416
	417	Only show contests owned by this user.
	418
	419	=back
	420
	421	=item contest_entry($id)
	422
	423	Returns a hashref with information about the contest $id.
	424
425	=item job_list([%args])
426
427	Returns a list of jobs as an arrayref containing hashrefs. Takes the following arguments:
428
429	=over
430
431	=item owner
432
433	Only show jobs submitted by this user.
434
435	=item contest
436
437	Only show jobs submitted in this contest.
438
439	=item problem
440
441	Only show jobs submitted for this problem.
442
443	=item page
444
445	Show this page of results. Defaults to 1. Pages have 10 entries, and the first page has the most recent jobs.
446
447	=back
448
449	=item job_entry($id)
450
451	Returns a hashref with information about the job $id.
452
cbb36c78	453	=back
4a8747ef MG	454
	455	=head1 AUTHOR
	456
	457	Marius Gavrilescu E<lt>marius@ieval.roE<gt>
	458
	459	=head1 COPYRIGHT AND LICENSE
	460
	461	Copyright (C) 2014 by Marius Gavrilescu
	462
9d2e740e MG	463	This library is free software; you can redistribute it and/or modify
	464	it under the same terms as Perl itself, either Perl version 5.18.1 or,
	465	at your option, any later version of Perl 5 you may have available.
4a8747ef MG	466
	467
	468	=cut